build.gradle

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath "org.junit.platform:junit-platform-gradle-plugin:1.2.0"
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4"
    }
}

apply plugin: "java"
apply plugin: "groovy"
apply plugin: "org.junit.platform.gradle.plugin"
apply plugin: "maven-publish"
apply plugin: 'com.jfrog.bintray'


group 'io.ankburov'
version '1.0.10'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

dependencies {
    compileOnly "org.projectlombok:lombok:1.18.4",
            "org.springframework.boot:spring-boot-configuration-processor:1.5.17.RELEASE"

    compile "org.springframework.boot:spring-boot-starter-jdbc:1.5.17.RELEASE",
            "org.springframework.boot:spring-boot-actuator:1.5.17.RELEASE",
            "com.zaxxer:HikariCP:3.2.0",
            "org.apache.commons:commons-lang3:3.8"

    testCompile "org.projectlombok:lombok:1.18.4",
                "org.springframework.boot:spring-boot-starter-test:1.5.17.RELEASE",
                "org.springframework.boot:spring-boot-starter-web:1.5.17.RELEASE",
                "org.codehaus.groovy:groovy-all:2.5.4",
                "org.testcontainers:mariadb:1.10.1",
                "org.mariadb.jdbc:mariadb-java-client:2.3.0",
                "org.junit.jupiter:junit-jupiter-api:5.3.1",
                "org.junit.jupiter:junit-jupiter-engine:5.3.1",
                "com.github.sbrannen:spring-test-junit5:1.3.1"
}

compileJava.dependsOn(processResources)

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
}

jar.dependsOn(sourcesJar)

publishing {
    publications {
        toMaven(MavenPublication) {
            groupId project.group
            artifactId project.name
            version project.version
            from components.java

            artifact sourcesJar {
                classifier "sources"
            }
        }
    }
}

bintray {
    user = project.hasProperty("user") ? project.property("user") : "fake"
    key = project.hasProperty("key") ? project.property("key") : "fake"

    publications = ['toMaven']
    publish = true

    pkg {
        repo = 'maven'
        name = rootProject.name
        licenses = ['Apache-2.0']
        vcsUrl = 'https://github.com/AnkBurov/spring-balancing-datasource.git'
    }
}