Some helpful commands and batch files (mostly ffmpeg)

[htmlcodepreview]

I am using roop, especially this fork for a very long time now, and I want to give back to the community, even tho all I can contribute isjust a few cheap commands.

In order to use below commands you need to have ffmpeg installed. If you are using roop-unleashed you probably already have this. But you may still need to add ffmpeg to your PATH variable.

Commands

All commands should be used by opening terminal on the folder with files to be processed, and all commands apply to all corresponding files in that folder unless stated otherwise. None of them applies to any sub-folders. These commands are created for windows in mind, but it should be easy to convert them if you are using a linux distro. Just ask chatgpt to convert it.

Convert Webms to MP4 (folder bulk) ---- CLICK HERE TO SHOW/HIDE

Converts all *.webm files to *.mp4 files, keeps the webm files as well. This also fixes ´height is not divisible by 2´ errors and works with almost all webms.

for %i in (*.webm) do ffmpeg -fflags +genpts -i "%i" -vf "pad=ceil(iw/2)*2:ceil(ih/2)*2" -r 24 "%~ni.mp4"

There is a much faster method: for %i in (*.webm) do ffmpeg -i "%i" -c copy "%~ni.mp4" but this won't work for odd height or some webms with vp8 codec.

Resize all mp4 files to a maximum width&height ---- CLICK HERE TO SHOW/HIDE

Below command will resize all mp4 files from current folder so their dimensions are not more than 800. You can replace both occurrences of "800" with any even number and it should work just fine:

for %i in (*.mp4) do ffmpeg -i "%i" -vf "scale='if(gt(iw,ih),min(800,iw),-2)':'if(gt(iw,ih),-2,min(800,ih))'" -c:a copy "resized_%i"

New files will start with prefix "resized_".

Lower FPS for fast processing ---- CLICK HERE TO SHOW/HIDE

Below command will create an output folder and change fps of all mp4 files to 12. This usually means your files will be processed in, for example, 5 minutes instead of 15 or 25 minutes. You can change 12 to a better quality fps like 24 or 30.

if not exist "output" mkdir output & for %I in (*.mp4) do ffmpeg -y -i "%I" -vf "fps=12" "output\%~nI_f.mp4"

See frame counts and fps of your video files ---- CLICK HERE TO SHOW/HIDE

This command will try to count frame numbers(actually it counts something else that is usually equal to the frame count) AND detects the fps of each video, file, and prints them out. It is helpful when you want to know how much time you will need to spend for each video, or if your videos can benefit from fps reduction.

for %f in (*.mp4 *.webm) do @echo File: %f && ffprobe -v error -select_streams v:0 -count_packets -show_entries stream=nb_read_packets -of csv=p=0 "%f" && ffprobe -v error -select_streams v:0 -show_entries stream=r_frame_rate -of csv=p=0 "%f"

Batch Files

There were some slightly more complex operations I solved using bat files. You can create .bat files for each one, place them in a folder called, idk, "myutils", and include that folder's path in your PATH environment variable. This will allow you to run them using only the file name on your terminal.

Quickly merge mp4 files ---- CLICK HERE TO SHOW/HIDE

If you end up using the Set as Start / End functionality of roop unleashed, you will probably need to merge those multiple sections into one video file. Just put your videos in a folder and run below command. It will create a list of file names(txt) and use it to run ffmpeg's concat (merge) feature:

@echo off
setlocal EnableDelayedExpansion

echo Creating file list...

:: Delete mylist.txt if it already exists
if exist mylist.txt del mylist.txt

:: Create new mylist.txt with all mp4 files in the current directory
for %%f in (*.mp4) do (
    :: Use >> to append to file
    echo file '%%f' >> mylist.txt
)

:: Check if any MP4 files were found
findstr /m "file" mylist.txt >nul
if %errorlevel% neq 0 (
    echo No MP4 files found in the current directory.
    if exist mylist.txt del mylist.txt
    exit /b 1
)

echo Found the following MP4 files to merge:
type mylist.txt

echo.
echo Starting merge process...

:: Run ffmpeg to merge the files
ffmpeg -f concat -safe 0 -i mylist.txt -c copy merged_output.mp4

:: Check if ffmpeg was successful
if %errorlevel% equ 0 (
    echo.
    echo Merge completed successfully!
    echo Output file: merged_output.mp4
    
    :: Clean up the temporary file
    del mylist.txt
) else (
    echo.
    echo An error occurred during the merge process.
    echo Please make sure ffmpeg is installed and in your system PATH.
    
    :: Keep mylist.txt in case of error for debugging
    echo The file list has been preserved in mylist.txt for debugging.
)

echo.
pause

Recursively resize video files ---- CLICK HERE TO SHOW/HIDE

This is very similar to the resize command I shared above, but it walks through sub-folders and runs the command for any mp4 or webm files it can read.

@echo off
setlocal enabledelayedexpansion

REM Loop through all .mp4 files in current folder and subfolders
for /r %%f in (*.mp4) do (
    REM Rename the original file by appending "original_"
    ren "%%f" "original_%%~nxf"

    REM Get the new file name
    set "newfile=%%~dpforiginal_%%~nxf"
    set "origfile=%%f"

    REM Perform the ffmpeg conversion
    ffmpeg -i "!newfile!" -vf "scale='if(gt(iw,ih),min(800,iw),-2)':'if(gt(iw,ih),-2,min(800,ih))'" -c:a copy "%%f"

    REM Delete the "original_" file
    del "!newfile!"
)

endlocal
pause

ROOPIFY - v1 ---- CLICK HERE TO HIDE/SHOW

This is a long batch file I am very proud of. Even tho it mostly fits my own requirements, you can still modify it a bit and use it for your own needs, if you find them to be similar.

Imagine you have a folder of lots of video files (mp4, m4s, m4k, webm).

This script first converts m4s and m4k files to mp4, then detects fps and frame count for each file.

if frame count is bigger than 1000, it decreases the fps value:
... if fps>58 ->change fps to 30.
... If fps>29, change it to 22.
... if fps>21, change it to 12
if frame count is bigger than 2000, it decreases fps even more aggressively:
... if fps>58 ->change fps to 22.
... If fps>29, change it to 12.
if the frame count is less than 1000, it doesn't change the fps value.

And finally, it renames all these files so that they are sorted by final frame count.

Example initial folder list:

18216519.m4s

educational_elephant.mp4

final_final_last_rev_7.m4s
...

Example end result:

1-192-f22--done.mp4 # (frame count is 192, fps is 22)

2-219-f30--done.mp4

3-264-f24--done.mp4
...

roopify bat file content:

@echo off
setlocal enabledelayedexpansion

:: Convert m4s, m4k, and m4v files to mp4
for %%E in (m4s m4k m4v) do (
    for %%I in (*.%%E) do (
        ffmpeg -i "%%I" -c copy "%%~nI.mp4"
        if !errorlevel! equ 0 (
            del "%%I"
            echo Converted and deleted: %%I
        ) else (
            echo Failed to convert: %%I
        )
    )
)

:: Create a temporary file to store file information
set "tempfile=%temp%\videoinfo.txt"
if exist "%tempfile%" del "%tempfile%"

:: Process mp4 and webm files
for %%F in (*.mp4 *.webm) do (
    :: Check if the file doesn't end with "--done"
    if not "%%~nF" == "%%~nF--done" (
        :: Get frame count
        for /f %%C in ('ffprobe -v error -select_streams v:0 -count_packets -show_entries stream^=nb_read_packets -of csv^=p^=0 "%%F"') do (
            set "frames=%%C"
        )

        echo "File: %%F"
        echo "Frame count: !frames!"


        :: Get frame rate
        for /f %%R in ('ffprobe -v error -select_streams v -of default^=noprint_wrappers^=1:nokey^=1 -show_entries stream^=r_frame_rate "%%F"') do (
            set "fps=%%R"
            set "fps_num=0"
            set "fps_den=1"  :: Default to prevent division by zero

            :: Split the frame rate and calculate FPS
            for /f "tokens=1,2 delims=/" %%N in ("!fps!") do (
                set "fps_num=%%N"
                set "fps_den=%%O"
            )

            if !fps_den! neq 0 (
                set /a "fps_value=fps_num/fps_den"
            ) else (
                set "fps_value=0" :: Handle divide by zero
            )

            set "filetempname=%%F"

            echo "Frame rate: !fps_value!"

            if !frames! lss 1000 (
                            :: pass
                echo "..."
            ) else (
                if !frames! lss 2000 (
                    if !fps_value! gtr 58 (
                        ffmpeg -y -i "!filetempname!" -vf "fps=30" "!filetempname!-f.mp4"
                        del "!filetempname!"
                        set "filetempname=!filetempname!-f.mp4"
                        set "fps_value=30"
                        for /f %%T in ('ffprobe -v error -select_streams v:0 -count_packets -show_entries stream^=nb_read_packets -of csv^=p^=0 "!filetempname!"') do (
                            set "frames=%%T"
                        )
                    ) else if !fps_value! gtr 29 (
                        ffmpeg -y -i "!filetempname!" -vf "fps=22" "!filetempname!-f.mp4"
                        del "!filetempname!"
                        set "filetempname=!filetempname!-f.mp4"
                        set "fps_value=22"
                        for /f %%T in ('ffprobe -v error -select_streams v:0 -count_packets -show_entries stream^=nb_read_packets -of csv^=p^=0 "!filetempname!"') do (
                            set "frames=%%T"
                        )
                    ) else if !fps_value! gtr 21 (
                        ffmpeg -y -i "!filetempname!" -vf "fps=12" "!filetempname!-f.mp4"
                        del "!filetempname!"
                        set "filetempname=!filetempname!-f.mp4"
                        set "fps_value=12"
                        for /f %%T in ('ffprobe -v error -select_streams v:0 -count_packets -show_entries stream^=nb_read_packets -of csv^=p^=0 "!filetempname!"') do (
                            set "frames=%%T"
                        )
                    )
                ) else (
                    if !fps_value! gtr 58 (
                        ffmpeg -y -i "!filetempname!" -vf "fps=22" "!filetempname!-f.mp4"
                        del "!filetempname!"
                        set "filetempname=!filetempname!-f.mp4"
                        set "fps_value=22"
                        for /f %%T in ('ffprobe -v error -select_streams v:0 -count_packets -show_entries stream^=nb_read_packets -of csv^=p^=0 "!filetempname!"') do (
                            set "frames=%%T"
                        )
                    ) else if !fps_value! gtr 29 (
                        ffmpeg -y -i "!filetempname!" -vf "fps=12" "!filetempname!-f.mp4"
                        del "!filetempname!"
                        set "filetempname=!filetempname!-f.mp4"
                        set "fps_value=12"
                        for /f %%T in ('ffprobe -v error -select_streams v:0 -count_packets -show_entries stream^=nb_read_packets -of csv^=p^=0 "!filetempname!"') do (
                            set "frames=%%T"
                        )
                    )
                )
            )

            echo !frames!,!filetempname!,!fps_value!
            echo !frames!,!filetempname!,!fps_value!>> "%tempfile%"
        )

    )
)

:: Sort the temp file by frame count
powershell -Command "Get-Content '%tempfile%' | Sort-Object {[int]($_ -split ',')[0]} | Set-Content '%tempfile%.sorted'"

:: Rename files based on sorted list and convert as necessary
set "counter=1"
for /f "tokens=1,2,3 delims=," %%A in (%tempfile%.sorted) do (
    set "frames=%%A"
    set "filename=%%B"
    set "fps_value=%%C"

    ren "!filename!" "!counter!-!frames!-f!fps_value!--done%%~xB"
    set /a "counter+=1"
)

:: Clean up
del "%tempfile%"
del "%tempfile%.sorted"

echo Processing complete.

You can also create context menu items using these ones. I am using Shell, and have a video bulk process submenu like this one:

	menu(mode="multiple" title="Videos Bulk" image=image.fluent(\uE714))
	{
	item(title='Merge *.mp4' image=[\uE7C4] cmd-line='cmd.exe start cmd /k "ffmerge"')
	item(title='Webm to mp4' image=[\uE835] cmd-line='cmd.exe start cmd /k for %i in (*.webm) do ffmpeg -i "%i" -c:v libx264 -c:a aac -strict experimental "%~ni.mp4"')
	item(title='Webm to mp4 \\w height fix' image=[\uE835] cmd-line='cmd.exe start cmd /k for %i in (*.webm) do ffmpeg -fflags +genpts -i "%i" -vf "pad=ceil(iw/2)*2:ceil(ih/2)*2" -r 24 "%~ni.mp4"')
	item(title='Roopify' image=[\uE835] cmd-line='cmd.exe start cmd /k "roopify"')
	}

[Elise96nl]

thanks for your contribution. I had some 60 fps video's and was thinking about making them 30fps to double the speed. but i would delete every other frame.

When you roop 12 fps on a 30 fps video. It will slow down the video, but instead of a 1800 frame 1 min video, wont you get a 2,7 min video with the same 1800 frames? so why would it be faster?

[htmlcodepreview]

If I understood your question correctly, the command I provided, when used as -vf "fps=30" on a video with 60fps, will practically do just that, removing every other frame while keeping the video length same, and keeping the audio in sync. Total number of frames becomes half of the initial video's frame count, which makes processing the video much faster. Because now roop only needs to replace face from, for example 350 frames instead of 700. Frame count isn't the only parameter, yes, But my understanding is that, frame count has linear relationship with how long it takes for roop to process your video. When you see the "Processing: " line on your terminal, you can also see the processing speed, in frames per second (eg: "11.7 frames/s").

To be honest I didn't ever use the "Video FPS" input field from the roop-unleashed ui, if you are asking about that one. I just leave it at zero. Above commands are just for pre processing your videos, before using roop.

[Elise96nl]

_@htmlcodepreview

you seem to have some or a lot of ffmpeg knowledge. I've been rendering a big video for 48 hours. And when it was at 91% somehow i closed the terminal window where roop unleashed was processeing. (i run a malwarebytes scan) i think that closed the terminal somehow. 

[mov,mp4,m4a,3gp,3g2,mj2 @ 000001732a73edc0] moov atom not found
[in#0 @ 000001732a7429c0] Error opening input: Invalid data found when processing input
Error opening input file test.mp4.
Error opening input files: Invalid data found when processing input_

*** i fixed the initial question i had. Will write a small tutorial for this on another topic**

[tinkbh]

Thank you very much. Very useful for me. Especially the merge and the resize tool.