build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.7-SNAPSHOT" apply false
}

architectury {
    minecraft = minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${minecraft_version}"

        modCompileOnlyApi "mezz.jei:jei-${minecraft_version}.1-common-api:${jei_version}"

        mappings loom.layered() {
            officialMojangMappings()
            parchment("org.parchmentmc.data:parchment-${mapping_version}@zip")
        }
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    version = mod_version
    group = maven_group

    repositories {
        maven {
            name "ParchmentMC"
            url "https://maven.parchmentmc.org"
        }
        maven {
            name "CurseMaven"
            url "https://cursemaven.com"
            content {
                includeGroup "curse.maven"
            }
        }
        maven {
            name "NeoForge"
            url "https://maven.neoforged.net/releases/"
        }
        maven {
            name "Jared's maven" // JEI
            url "https://maven.blamejared.com/"
        }
        maven {
            name "ModMaven" // JEI
            url "https://modmaven.dev"
        }
        maven {
            name "ModMenu"
            url "https://maven.terraformersmc.com/"
        }
        maven {
            name "Ladysnake Mods" // Cardinal Components
            url "https://maven.ladysnake.org/releases"
        }
        maven {
            name 'GeckoLib'
            url 'https://dl.cloudsmith.io/public/geckolib3/geckolib/maven/'
            content {
                includeGroupByRegex("software\\.bernie.*")
                includeGroup("com.eliotlash.mclib")
            }
        }
        maven {
            name 'ClothConfig'
            url "https://maven.shedaniel.me/"
        }
        flatDir {
            dir "libs"
        }
    }

    tasks.withType(JavaCompile) {
        options.encoding "UTF-8"
        options.release.set(21)
    }

    java {
        withSourcesJar()
    }
}

tasks.register("publishAllCurseforgeAndModrinth", Task) {
    dependsOn ":forge:publishCurseForgeAndModrinth"
    dependsOn ":neoforge:publishCurseForgeAndModrinth"
}