build.gradle

import com.vanniktech.maven.publish.JavaLibrary
import com.vanniktech.maven.publish.JavadocJar
import com.vanniktech.maven.publish.SonatypeHost

plugins {
    id "java-library"
    id "com.vanniktech.maven.publish" version "0.29.0"
    id "me.qoomon.git-versioning" version "6.4.3"
}

repositories {
    mavenCentral()
}

group = "io.consensys.protocols"

version = "UNKNOWN"

gitVersioning.apply {
    refs {
        tag(".+") {
            version = "\${ref}"
        }
        branch("master") {
            version = "develop"
        }
        branch(".+") {
            version = "\${ref}"
        }
    }
    rev {
        version = "UNKNOWN"
    }
}

java {
    sourceCompatibility = 17
    targetCompatibility = 17
}

mavenPublishing {
    configure(new JavaLibrary(new JavadocJar.Javadoc(), true))

    pom {
        name = "${project.name}"
        url = "http://github.com/Consensys/jc-kzg-4844"
        description = "Java wrapper around C-KZG-4844"
        licenses {
            license {
                name = "The Apache License, Version 2.0"
                url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
            }
        }
        developers {
            developer {
                id = "consensys"
                name = "Protocols Team"
                email = "devops@consensys.net"
            }
        }
        scm {
            connection = "scm:git:git://github.com/Consensys/jc-kzg-4844.git"
            developerConnection = "scm:git:ssh://github.com/Consensys/jc-kzg-4844.git"
            url = "https://github.com/Consensys/jc-kzg-4844"
        }
    }  

    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)

    signAllPublications()
}

// https://github.com/vanniktech/gradle-maven-publish-plugin/issues/821
mavenPlainJavadocJar.archiveBaseName.set("${project.name}")

tasks.register("checkJarContents") {
    doLast {
        exec {
            executable project.file("src/test/bash/checkResources.sh")
            args "${project.jar.outputs.files.getFiles()[0]}"
        }
    }
}