-
Notifications
You must be signed in to change notification settings - Fork 4
/
MLJDecisionTreeInterface.jl
443 lines (338 loc) · 14.6 KB
/
MLJDecisionTreeInterface.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
module MLJDecisionTreeInterface
import MLJModelInterface
import MLJModelInterface: @mlj_model, metadata_pkg, metadata_model,
Table, Continuous, Count, Finite, OrderedFactor,
Multiclass
import DecisionTree
using Random
import Random.GLOBAL_RNG
const MMI = MLJModelInterface
const DT = DecisionTree
const PKG = "MLJDecisionTreeInterface"
struct TreePrinter{T}
tree::T
end
(c::TreePrinter)(depth) = DT.print_tree(c.tree, depth)
(c::TreePrinter)() = DT.print_tree(c.tree, 5)
Base.show(stream::IO, c::TreePrinter) =
print(stream, "TreePrinter object (call with display depth)")
const DTC_DESCR = "CART decision tree classifier."
const DTR_DESCR = "CART decision tree regressor."
const RFC_DESCR = "Random forest classifier."
const RFR_DESCR = "Random forest regressor."
const ABS_DESCR = "Ada-boosted stump classifier."
"""
DecisionTreeClassifer(; kwargs...)
$DTC_DESCR
Inputs are tables with ordinal columns. That is, the element scitype
of each column can be `Continuous`, `Count` or `OrderedFactor`.
Predictions are probabilistic, but uncalibrated.
Instead of predicting the mode class at each leaf, a `UnivariateFinite`
distribution is fit to the leaf training classes, with smoothing
controlled by an additional hyperparameter `pdf_smoothing`: If `n` is
the number of observed classes, then each class probability is
replaced by `pdf_smoothing/n`, if it falls below that ratio, and the
resulting vector of probabilities is renormalized. Smoothing is only
applied to classes actually observed in training. Unseen classes
retain zero-probability predictions.
To visualize the fitted tree in the REPL, set `verbosity=2` when
fitting, or call `report(mach).print_tree(display_depth)` where `mach`
is the fitted machine, and `display_depth` the desired
depth. Interpretting the results will require a knowledge of the
internal integer encodings of classes, which are given in
`fitted_params(mach)` (which also stores the raw learned tree object
from the DecisionTree.jl algorithm).
## Hyperparameters
- `max_depth=-1`: max depth of the decision tree (-1=any)
- `min_samples_leaf=1`: max number of samples each leaf needs to have
- `min_samples_split=2`: min number of samples needed for a split
- `min_purity_increase=0`: min purity needed for a split
- `n_subfeatures=0`: number of features to select at random (0 for all,
-1 for square root of number of features)
- `post_prune=false`: set to `true` for post-fit pruning
- `merge_purity_threshold=1.0`: (post-pruning) merge leaves having `>=thresh`
combined purity
- `display_depth=5`: max depth to show when displaying the tree
- `rng=Random.GLOBAL_RNG`: random number generator or seed
- `pdf_smoothing=0.0`: threshold for smoothing the predicted scores
"""
@mlj_model mutable struct DecisionTreeClassifier <: MMI.Probabilistic
max_depth::Int = (-)(1)::(_ ≥ -1)
min_samples_leaf::Int = 1::(_ ≥ 0)
min_samples_split::Int = 2::(_ ≥ 2)
min_purity_increase::Float64 = 0.0::(_ ≥ 0)
n_subfeatures::Int = 0::(_ ≥ -1)
post_prune::Bool = false
merge_purity_threshold::Float64 = 1.0::(_ ≤ 1)
pdf_smoothing::Float64 = 0.0::(0 ≤ _ ≤ 1)
display_depth::Int = 5::(_ ≥ 1)
rng::Union{AbstractRNG,Integer} = GLOBAL_RNG
end
function MMI.fit(m::DecisionTreeClassifier, verbosity::Int, X, y)
Xmatrix = MMI.matrix(X)
yplain = MMI.int(y)
classes_seen = filter(in(unique(y)), MMI.classes(y[1]))
integers_seen = MMI.int(classes_seen)
tree = DT.build_tree(yplain, Xmatrix,
m.n_subfeatures,
m.max_depth,
m.min_samples_leaf,
m.min_samples_split,
m.min_purity_increase,
rng=m.rng)
if m.post_prune
tree = DT.prune_tree(tree, m.merge_purity_threshold)
end
verbosity < 2 || DT.print_tree(tree, m.display_depth)
fitresult = (tree, classes_seen, integers_seen)
cache = nothing
report = (classes_seen=classes_seen,
print_tree=TreePrinter(tree))
return fitresult, cache, report
end
function get_encoding(classes_seen)
a_cat_element = classes_seen[1]
return Dict(c => MMI.int(c) for c in MMI.classes(a_cat_element))
end
MMI.fitted_params(::DecisionTreeClassifier, fitresult) =
(tree=fitresult[1], encoding=get_encoding(fitresult[2]))
function smooth(scores, smoothing)
iszero(smoothing) && return scores
threshold = smoothing / size(scores, 2)
# clip low values
scores[scores .< threshold] .= threshold
# normalize
return scores ./ sum(scores, dims=2)
end
function MMI.predict(m::DecisionTreeClassifier, fitresult, Xnew)
Xmatrix = MMI.matrix(Xnew)
tree, classes_seen, integers_seen = fitresult
# retrieve the predicted scores
scores = DT.apply_tree_proba(tree, Xmatrix, integers_seen)
# smooth if required
sm_scores = smooth(scores, m.pdf_smoothing)
# return vector of UF
return MMI.UnivariateFinite(classes_seen, sm_scores)
end
"""
RandomForestClassifier(; kwargs...)
$RFC_DESCR
## Hyperparameters
- `max_depth=-1`: max depth of the decision tree (-1=any)
- `min_samples_leaf=1`: min number of samples each leaf needs to have
- `min_samples_split=2`: min number of samples needed for a split
- `min_purity_increase=0`: min purity needed for a split
- `n_subfeatures=-1`: number of features to select at random (0 for all,
-1 for square root of number of features)
- `n_trees=10`: number of trees to train
- `sampling_fraction=0.7` fraction of samples to train each tree on
- `rng=Random.GLOBAL_RNG`: random number generator or seed
- `pdf_smoothing=0.0`: threshold for smoothing the predicted scores
"""
@mlj_model mutable struct RandomForestClassifier <: MMI.Probabilistic
max_depth::Int = (-)(1)::(_ ≥ -1)
min_samples_leaf::Int = 1::(_ ≥ 0)
min_samples_split::Int = 2::(_ ≥ 2)
min_purity_increase::Float64 = 0.0::(_ ≥ 0)
n_subfeatures::Int = (-)(1)::(_ ≥ -1)
n_trees::Int = 10::(_ ≥ 2)
sampling_fraction::Float64 = 0.7::(0 < _ ≤ 1)
pdf_smoothing::Float64 = 0.0::(0 ≤ _ ≤ 1)
rng::Union{AbstractRNG,Integer} = GLOBAL_RNG
end
function MMI.fit(m::RandomForestClassifier, verbosity::Int, X, y)
Xmatrix = MMI.matrix(X)
yplain = MMI.int(y)
classes_seen = filter(in(unique(y)), MMI.classes(y[1]))
integers_seen = MMI.int(classes_seen)
forest = DT.build_forest(yplain, Xmatrix,
m.n_subfeatures,
m.n_trees,
m.sampling_fraction,
m.max_depth,
m.min_samples_leaf,
m.min_samples_split,
m.min_purity_increase;
rng=m.rng)
cache = nothing
report = NamedTuple()
return (forest, classes_seen, integers_seen), cache, report
end
MMI.fitted_params(::RandomForestClassifier, (forest,_)) = (forest=forest,)
function MMI.predict(m::RandomForestClassifier, fitresult, Xnew)
Xmatrix = MMI.matrix(Xnew)
forest, classes_seen, integers_seen = fitresult
scores = DT.apply_forest_proba(forest, Xmatrix, integers_seen)
sm_scores = smooth(scores, m.pdf_smoothing)
return MMI.UnivariateFinite(classes_seen, sm_scores)
end
"""
AdaBoostStumpClassifer(; kwargs...)
$RFC_DESCR
## Hyperparameters
- `n_iter=10`: number of iterations of AdaBoost
- `pdf_smoothing=0.0`: threshold for smoothing the predicted scores
"""
@mlj_model mutable struct AdaBoostStumpClassifier <: MMI.Probabilistic
n_iter::Int = 10::(_ ≥ 1)
pdf_smoothing::Float64 = 0.0::(0 ≤ _ ≤ 1)
end
function MMI.fit(m::AdaBoostStumpClassifier, verbosity::Int, X, y)
Xmatrix = MMI.matrix(X)
yplain = MMI.int(y)
classes_seen = filter(in(unique(y)), MMI.classes(y[1]))
integers_seen = MMI.int(classes_seen)
stumps, coefs = DT.build_adaboost_stumps(yplain, Xmatrix,
m.n_iter)
cache = nothing
report = NamedTuple()
return (stumps, coefs, classes_seen, integers_seen), cache, report
end
MMI.fitted_params(::AdaBoostStumpClassifier, (stumps,coefs,_)) =
(stumps=stumps,coefs=coefs)
function MMI.predict(m::AdaBoostStumpClassifier, fitresult, Xnew)
Xmatrix = MMI.matrix(Xnew)
stumps, coefs, classes_seen, integers_seen = fitresult
scores = DT.apply_adaboost_stumps_proba(stumps, coefs,
Xmatrix, integers_seen)
sm_scores = smooth(scores, m.pdf_smoothing)
return MMI.UnivariateFinite(classes_seen, sm_scores)
end
## REGRESSION
"""
DecisionTreeRegressor(; kwargs...)
$DTC_DESCR
Inputs are tables with ordinal columns. That is, the element scitype
of each column can be `Continuous`, `Count` or `OrderedFactor`. Predictions
are Deterministic.
## Hyperparameters
- `max_depth=-1`: max depth of the decision tree (-1=any)
- `min_samples_leaf=1`: max number of samples each leaf needs to have
- `min_samples_split=2`: min number of samples needed for a split
- `min_purity_increase=0`: min purity needed for a split
- `n_subfeatures=0`: number of features to select at random (0 for all,
-1 for square root of number of features)
- `post_prune=false`: set to `true` for post-fit pruning
- `merge_purity_threshold=1.0`: (post-pruning) merge leaves having `>=thresh`
combined purity
- `rng=Random.GLOBAL_RNG`: random number generator or seed
"""
@mlj_model mutable struct DecisionTreeRegressor <: MMI.Deterministic
max_depth::Int = (-)(1)::(_ ≥ -1)
min_samples_leaf::Int = 5::(_ ≥ 0)
min_samples_split::Int = 2::(_ ≥ 2)
min_purity_increase::Float64 = 0.0::(_ ≥ 0)
n_subfeatures::Int = 0::(_ ≥ -1)
post_prune::Bool = false
merge_purity_threshold::Float64 = 1.0::(0 ≤ _ ≤ 1)
rng::Union{AbstractRNG,Integer} = GLOBAL_RNG
end
function MMI.fit(m::DecisionTreeRegressor, verbosity::Int, X, y)
Xmatrix = MMI.matrix(X)
tree = DT.build_tree(float(y), Xmatrix,
m.n_subfeatures,
m.max_depth,
m.min_samples_leaf,
m.min_samples_split,
m.min_purity_increase;
rng=m.rng)
if m.post_prune
tree = DT.prune_tree(tree, m.merge_purity_threshold)
end
cache = nothing
report = nothing
return tree, cache, report
end
MMI.fitted_params(::DecisionTreeRegressor, tree) = (tree=tree,)
function MMI.predict(::DecisionTreeRegressor, tree, Xnew)
Xmatrix = MMI.matrix(Xnew)
return DT.apply_tree(tree, Xmatrix)
end
"""
RandomForestRegressor(; kwargs...)
$RFC_DESCR
## Hyperparameters
- `max_depth=-1`: max depth of the decision tree (-1=any)
- `min_samples_leaf=1`: min number of samples each leaf needs to have
- `min_samples_split=2`: min number of samples needed for a split
- `min_purity_increase=0`: min purity needed for a split
- `n_subfeatures=-1`: number of features to select at random (0 for all,
-1 for square root of number of features)
- `n_trees=10`: number of trees to train
- `sampling_fraction=0.7` fraction of samples to train each tree on
- `rng=Random.GLOBAL_RNG`: random number generator or seed
- `pdf_smoothing=0.0`: threshold for smoothing the predicted scores
"""
@mlj_model mutable struct RandomForestRegressor <: MMI.Deterministic
max_depth::Int = (-)(1)::(_ ≥ -1)
min_samples_leaf::Int = 1::(_ ≥ 0)
min_samples_split::Int = 2::(_ ≥ 2)
min_purity_increase::Float64 = 0.0::(_ ≥ 0)
n_subfeatures::Int = (-)(1)::(_ ≥ -1)
n_trees::Int = 10::(_ ≥ 2)
sampling_fraction::Float64 = 0.7::(0 < _ ≤ 1)
pdf_smoothing::Float64 = 0.0::(0 ≤ _ ≤ 1)
rng::Union{AbstractRNG,Integer} = GLOBAL_RNG
end
function MMI.fit(m::RandomForestRegressor, verbosity::Int, X, y)
Xmatrix = MMI.matrix(X)
forest = DT.build_forest(float(y), Xmatrix,
m.n_subfeatures,
m.n_trees,
m.sampling_fraction,
m.max_depth,
m.min_samples_leaf,
m.min_samples_split,
m.min_purity_increase,
rng=m.rng)
cache = nothing
report = NamedTuple()
return forest, cache, report
end
MMI.fitted_params(::RandomForestRegressor, forest) = (forest=forest,)
function MMI.predict(::RandomForestRegressor, forest, Xnew)
Xmatrix = MMI.matrix(Xnew)
return DT.apply_forest(forest, Xmatrix)
end
# ===
metadata_pkg.(
(DecisionTreeClassifier, DecisionTreeRegressor,
RandomForestClassifier, RandomForestRegressor,
AdaBoostStumpClassifier),
name = "DecisionTree",
uuid = "7806a523-6efd-50cb-b5f6-3fa6f1930dbb",
url = "https://github.com/bensadeghi/DecisionTree.jl",
julia = true,
license = "MIT",
is_wrapper = false)
metadata_model(DecisionTreeClassifier,
input = Table(Continuous, Count, OrderedFactor),
target = AbstractVector{<:Finite},
weights = false,
descr = DTC_DESCR,
path = "$PKG.DecisionTreeClassifier")
metadata_model(RandomForestClassifier,
input = Table(Continuous, Count, OrderedFactor),
target = AbstractVector{<:Finite},
weights = false,
descr = RFC_DESCR,
path = "$PKG.RandomForestClassifier")
metadata_model(AdaBoostStumpClassifier,
input = Table(Continuous, Count, OrderedFactor),
target = AbstractVector{<:Finite},
weights = false,
descr = ABS_DESCR,
path = "$PKG.AdaBoostStumpClassifier")
metadata_model(DecisionTreeRegressor,
input = Table(Continuous, Count, OrderedFactor),
target = AbstractVector{Continuous},
weights = false,
descr = DTR_DESCR,
path = "$PKG.DecisionTreeRegressor")
metadata_model(RandomForestRegressor,
input = Table(Continuous, Count, OrderedFactor),
target = AbstractVector{Continuous},
weights = false,
descr = RFR_DESCR,
path = "$PKG.RandomForestRegressor")
end # module