-
Notifications
You must be signed in to change notification settings - Fork 88
/
mmapio.jl
299 lines (266 loc) · 9.57 KB
/
mmapio.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
#
# MmapIO
#
# An IO built on top of mmap to avoid the overhead of ordinary disk IO
if Sys.iswindows()
const MMAP_GROW_SIZE = 2^19
const FILE_GROW_SIZE = 2^19
else
const MMAP_GROW_SIZE = 2^24
const FILE_GROW_SIZE = 2^18
end
const Plain = Union{Int16,Int32,Int64,Int128,UInt16,UInt32,UInt64,UInt128,Float16,Float32,
Float64}
const PlainType = Union{Type{Int16},Type{Int32},Type{Int64},Type{Int128},Type{UInt16},
Type{UInt32},Type{UInt64},Type{UInt128},Type{Float16},
Type{Float32},Type{Float64}}
mutable struct MmapIO <: IO
f::IOStream
write::Bool
n::Int
startptr::Ptr{Cvoid}
curptr::Ptr{Cvoid}
endptr::Ptr{Cvoid}
@static if Sys.iswindows()
mapping::Ptr{Cvoid}
end
end
if Sys.isunix()
function mmap!(io::MmapIO, n::Int)
oldptr = io.startptr
newptr = ccall(:jl_mmap, Ptr{Cvoid}, (Ptr{Cvoid}, Csize_t, Cint, Cint, Cint, Int64),
C_NULL, n, Mmap.PROT_READ | (io.write*Mmap.PROT_WRITE),
Mmap.MAP_SHARED, fd(io.f), 0)
io.n = n
io.curptr += newptr - oldptr
io.startptr = newptr
end
munmap(io::MmapIO) =
systemerror("munmap",
ccall(:munmap, Cint, (Ptr{Cvoid}, Int), io.startptr, io.n) != 0)
function msync(io::MmapIO, offset::Integer=0, len::Integer=UInt(io.endptr - io.startptr),
invalidate::Bool=false)
# shift `offset` to start of page boundary
offset_page::Int64 = div(offset, Mmap.PAGESIZE) * Mmap.PAGESIZE
# add (offset - offset_page) to `len` to get total length of memory-mapped region
mmaplen::Int64 = (offset - offset_page) + len
systemerror("msync",
ccall(:msync, Cint, (Ptr{Cvoid}, Csize_t, Cint),
io.startptr + offset_page, mmaplen,
invalidate ? Mmap.MS_INVALIDATE : Mmap.MS_SYNC) != 0)
end
elseif Sys.iswindows()
const DWORD = Culong
function mmap!(io::MmapIO, n::Int)
oldptr = io.startptr
mapping = ccall(:CreateFileMappingW, stdcall, Ptr{Cvoid},
(Base.Libc.WindowsRawSocket, Ptr{Cvoid}, DWORD, DWORD, DWORD, Ptr{Cvoid}),
Mmap.gethandle(io.f), C_NULL,
io.write ? Mmap.PAGE_READWRITE : Mmap.PAGE_READONLY, n >> 32,
n % UInt32, C_NULL)
systemerror("CreateFileMappingW", mapping == C_NULL)
newptr = ccall(:MapViewOfFile, stdcall, Ptr{Cvoid},
(Ptr{Cvoid}, DWORD, DWORD, DWORD, Csize_t),
mapping, io.write ? Mmap.FILE_MAP_WRITE : Mmap.FILE_MAP_READ, 0, 0,
n)
systemerror("MapViewOfFile", newptr == C_NULL)
io.n = n
io.curptr += newptr - oldptr
io.mapping = mapping
io.startptr = newptr
end
function munmap(io::MmapIO)
systemerror("UnmapViewOfFile",
ccall(:UnmapViewOfFile, stdcall, Cint, (Ptr{Cvoid},), io.startptr) == 0)
systemerror("CloseHandle",
ccall(:CloseHandle, stdcall, Cint, (Ptr{Cvoid},), io.mapping) == 0)
end
function msync(io::MmapIO, offset::Integer=0, len::Integer=UInt(io.endptr - io.startptr),
invalidate::Bool=false)
# shift `offset` to start of page boundary
offset_page::Int64 = div(offset, Mmap.PAGESIZE) * Mmap.PAGESIZE
# add (offset - offset_page) to `len` to get total length of memory-mapped region
mmaplen::Int64 = (offset - offset_page) + len
systemerror("FlushViewOfFile",
ccall(:FlushViewOfFile, stdcall, Cint,
(Ptr{Cvoid}, Csize_t), io.startptr + offset_page, mmaplen) == 0)
end
end
function MmapIO(fname::AbstractString, write::Bool, create::Bool, truncate::Bool)
truncate && !write && throw(ArgumentError("cannot truncate file that is not writable"))
f = open(fname, read = true, write = write,
create = create, truncate = truncate, append = false)
initialsz = truncate ? Int64(0) : filesize(fname)
@static if Int == Int32
initialsz > typemax(Int) && error("cannot read a file greater than 2GB on a 32-bit system")
end
n = (initialsz % Int) + (write ? MMAP_GROW_SIZE : 0)
n < 0 && (n = typemax(Int))
@static if Sys.iswindows()
io = MmapIO(f, write, 0, C_NULL, C_NULL, C_NULL, C_NULL)
else
io = MmapIO(f, write, 0, C_NULL, C_NULL, C_NULL)
end
mmap!(io, n)
io.endptr = io.startptr + (initialsz % Int)
io
end
Base.show(io::IO, ::MmapIO) = print(io, "MmapIO")
if Sys.islinux()
# This is substantially faster than truncate on Linux, but slower on OS X.
# TODO: Benchmark on Windows
grow(io::IOStream, sz::Integer) =
systemerror("pwrite", ccall(:jl_pwrite, Cssize_t,
(Cint, Ref{UInt8}, UInt, Int64),
fd(io), UInt8(0), 1, sz - 1) < 1)
else
grow(io::IOStream, sz::Integer) = truncate(io, sz)
end
function Base.resize!(io::MmapIO, newend::Ptr{Cvoid})
io.write || throw(EOFError())
# Resize file
ptr = io.startptr
newsz = Int(max(newend - ptr, io.curptr - ptr + FILE_GROW_SIZE))
@static if !Sys.iswindows()
grow(io.f, newsz)
end
if newsz > io.n
# If we have not mapped enough memory, map more
munmap(io)
ptr = mmap!(io, max(newsz, io.n + MMAP_GROW_SIZE))
end
# Set new end
io.endptr = ptr + newsz
io
end
@inline function ensureroom(io::MmapIO, n::Int)
ep = io.curptr + n
if ep > io.endptr
resize!(io, ep)
end
nothing
end
function truncate_and_close(io::MmapIO, endpos::Integer)
io.write && msync(io)
munmap(io)
truncate(io.f, endpos)
close(io.f)
end
function Base.close(io::MmapIO)
io.write && msync(io)
munmap(io)
close(io.f)
end
@inline function _write(io::MmapIO, x)
cp = io.curptr
ep = cp + sizeof(x)
if ep > io.endptr
resize!(io, ep)
cp = io.curptr
ep = cp + sizeof(x)
end
unsafe_store!(Ptr{typeof(x)}(cp), x)
io.curptr = ep
return sizeof(x)
end
@inline Base.write(io::MmapIO, x::UInt8) = _write(io, x)
@inline Base.write(io::MmapIO, x::Int8) = _write(io, x)
@inline Base.write(io::MmapIO, x::Plain) = _write(io, x)
function Base.unsafe_write(io::MmapIO, x::Ptr{UInt8}, n::UInt)
cp = io.curptr
ep = cp + n
if ep > io.endptr
resize!(io, ep)
cp = io.curptr
ep = cp + n
end
unsafe_copyto!(Ptr{UInt8}(cp), x, n)
io.curptr = ep
return n
end
@inline function _read(io::MmapIO, T::DataType)
cp = io.curptr
ep = cp + sizeof(T)
ep > io.endptr && throw(EOFError())
v = unsafe_load(Ptr{T}(cp))
io.curptr = ep
v
end
@inline Base.read(io::MmapIO, T::Type{UInt8}) = _read(io, T)
@inline Base.read(io::MmapIO, T::Type{Int8}) = _read(io, T)
@inline Base.read(io::MmapIO, T::PlainType) = _read(io, T)
function Base.read(io::MmapIO, ::Type{T}, n::Int) where T
cp = io.curptr
ep = cp + sizeof(T)*n
ep > io.endptr && throw(EOFError())
arr = Vector{T}(undef, n)
unsafe_copyto!(pointer(arr), Ptr{T}(cp), n)
io.curptr = ep
arr
end
Base.read(io::MmapIO, ::Type{T}, n::Integer) where {T} =
read(io, T, Int(n))
# Read a null-terminated string
function read_bytestring(io::MmapIO)
# TODO do not try to read outside the buffer
cp = io.curptr
str = unsafe_string(convert(Ptr{UInt8}, cp))
io.curptr = cp + sizeof(str) + 1
str
end
@inline function Base.seek(io::MmapIO, offset::Integer)
if io.startptr + offset > io.endptr
resize!(io, io.startptr + offset)
end
io.curptr = io.startptr + offset
nothing
end
@inline function Base.skip(io::MmapIO, offset::Integer)
if io.curptr + offset > io.endptr
resize!(io, io.curptr + offset)
end
io.curptr += offset
nothing
end
Base.position(io::MmapIO) = Int64(io.curptr - io.startptr)
"""
IndirectPointer
When writing data, we may need to enlarge the memory mapping, which would invalidate any
memory addresses arising from the old `mmap` pointer. `IndirectPointer` holds a pointer to
the `startptr` field of an MmapIO, and the offset relative to that pointer. It defers
computing a memory address until converted to a Ptr{T}, so the memory mapping can be
enlarged and addresses will remain valid.
"""
struct IndirectPointer
ptr::Ptr{Ptr{Cvoid}}
offset::Int
end
function IndirectPointer(io::MmapIO, offset::Integer=position(io))
IndirectPointer(pointer_from_objref(io) + fieldoffset(MmapIO, 4), offset)
end
Base.:+(x::IndirectPointer, y::Integer) = IndirectPointer(x.ptr, x.offset+y)
Base.convert(::Type{Ptr{T}}, x::IndirectPointer) where {T} = Ptr{T}(unsafe_load(x.ptr) + x.offset)
# We sometimes need to compute checksums. We do this by first calling begin_checksum when
# starting to handle whatever needs checksumming, and calling end_checksum afterwards. Note
# that we never compute nested checksums, but we may compute multiple checksums
# simultaneously. This strategy is not thread-safe.
const CHECKSUM_POS = Int64[]
const NCHECKSUM = Ref{Int}(0)
function begin_checksum_read(io::MmapIO)
idx = NCHECKSUM[] += 1
if idx > length(CHECKSUM_POS)
push!(CHECKSUM_POS, position(io))
else
@inbounds CHECKSUM_POS[idx] = position(io)
end
io
end
function begin_checksum_write(io::MmapIO, sz::Integer)
ensureroom(io, sz)
begin_checksum_read(io)
end
function end_checksum(io::MmapIO)
@inbounds v = CHECKSUM_POS[NCHECKSUM[]]
NCHECKSUM[] -= 1
Lookup3.hash(Ptr{UInt8}(io.startptr + v), position(io) - v)
end