build.gradle

import java.time.Duration

/*
 *
 *  * Copyright (c) Crio.Do 2019. All rights reserved
 *
 */

//////////////////////////////// DO NOT CHANGE THIS FILE //////////////////////////////////

plugins {
    id 'io.spring.dependency-management' version '1.0.8.RELEASE'
    id 'jacoco'
    id 'java'
    id 'com.github.spotbugs' version '4.5.0'
}


ext {
    buildId = System.currentTimeMillis()
    springBootVersion = "2.1.4.RELEASE"
    springCoreVersion = "5.0.9.RELEASE"
    junitVersion = "5.3.1"
    junitPlatformLauncherVersion = "1.3.1"
    mockitoVersion = "2.22.0"
    swaggerVersion = "2.9.2"
    lombokVersion = "1.18.4"
    modelMapperVersion = "2.3.2"
}


apply plugin: "idea"
apply plugin: "checkstyle"


version '1.0-SNAPSHOT'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

task installGitHooks(type: Copy) {
    from new File(rootProject.rootDir, "__CRIO__/pre-push")
    into { new File(rootProject.rootDir, ".git/hooks") }
    fileMode 0777
}

configurations {
    all {
        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-logging'
    }
}

allprojects {
    buildDir = '/tmp/external_build'
}

subprojects {
    apply plugin: "java-library"
    apply plugin: "idea"
    apply plugin: "checkstyle"
    apply plugin: "pmd"
    apply plugin: "jacoco"

    checkstyleTest.enabled = false

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    repositories {
        mavenCentral()
    }

    test {
        reports {
            junitXml.enabled = true
            def destinationDirectory = System.getProperty("user.home") + "/.gradle/daemon/${buildId}/test-results"
            junitXml.destination = file(destinationDirectory)
            html.enabled = true
        }
        
        testLogging.events ("STANDARD_ERROR")
        testLogging.events ("STANDARD_OUT")
        afterSuite { desc, result ->
            if (!desc.parent) {
                println "\nTEST RESULT: ${result.resultType}"
                println "TEST SUMMARY: RAN ${result.testCount} TESTS, " +
                        "${result.successfulTestCount} SUCCEEDED, " +
                        "${result.failedTestCount} FAILED, " +
                        "${result.skippedTestCount} SKIPPED"
            }
        }
        timeout = Duration.ofMinutes(15)
    }

    checkstyle {
        ignoreFailures = true
        toolVersion "7.8.1"
        configFile file("${rootProject.projectDir}/__CRIO__/checkstyle.xml")
    }

    pmd {
        ignoreFailures = true
        toolVersion = "6.10.0"
        sourceSets = [sourceSets.main]
        ruleSetFiles = files("${rootProject.projectDir}/__CRIO__/ruleset.xml")
        ignoreFailures = true
    }

    spotbugsMain {
        ignoreFailures = true
        reports {
            xml.enabled = false
            html.enabled = true
        }
    }
    spotbugsTest.enabled = false

    jacoco {
        toolVersion = "0.8.5"
        reportsDir = file("$buildDir/customJacocoReportDir")
    }

    task installGitHooks(type: Copy) {
        from new File(rootProject.rootDir, '__CRIO__/pre-push')
        into { new File(rootProject.rootDir, '.git/hooks') }
        fileMode 0777
    }

    build.dependsOn installGitHooks
}

compileJava.dependsOn clean

//////////////////////////////// DO NOT CHANGE THIS FILE //////////////////////////////////