-
Notifications
You must be signed in to change notification settings - Fork 0
/
algoritmosProcura.pl
314 lines (252 loc) · 12.7 KB
/
algoritmosProcura.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
%--------------------------------------------------------------------------------------------------------
% PESQUISA EM PROFUNDIDADE
% Algoritmo de Pesquisa em profundidade básico
pesquisaProfundidade(Origem, Destino, Caminho, TempoViagem) :-
findall(
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
ListaParagens
),
profundidade_func(Origem, Destino, [(Origem, 'Inicio')], Caminho, TempoViagem, ListaParagens).
profundidade_func(Destino, Destino, His, Caminho, T, _) :-
inverso(His, Caminho),
T is 0.
profundidade_func(Origem, Destino, His, Caminho, TempoViagem, ListaParagens) :-
adjacente(Origem, Prox, Carreira, T1, ListaParagens),
\+ member((Prox, Carreira), His),
((T1 == 'N/A') -> TLimpo is 0.0 ; TLimpo is T1),
profundidade_func(Prox, Destino, [(Prox, Carreira)|His], Caminho, T, ListaParagens),
TempoViagem is T + TLimpo + 2. % Adiciona 2 min entre paragens de autocarros
adjacente(Paragem, ProxParagem, Carreira, TempoViagem, ListaParagens) :-
member(
paragem(Paragem, _, _, _, _, _, _, _, _, _),
ListaParagens
),
member(
paragem(ProxParagem, _, _, _, _, _, _, _, _, _),
ListaParagens
),
viagem(Carreira, Paragem, ProxParagem, TempoViagem).
% pesquisaProfundidade(183, 608, Caminho, Tempo).
% pesquisaProfundidade(183, 595, Caminho, Tempo).
% Função de pesquisa em profundidade geral
% Este algoritmo difere do anterior, pois permite saber todos os diferentes caminhos possíveis
pesquisaProfundidade_varios(Origem, Destino, [(Origem, 'Inicio')|Caminho], TempoViagem) :-
findall(
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
ListaParagens
),
profundidade_func_varios(Origem, Destino, Caminho, TempoViagem, ListaParagens).
% Função de pesquisa para a Query 2 e 3
pesquisaProfundidade_varios(Origem, Destino, [(Origem, 'Inicio')|Caminho], TempoViagem, Operadoras) :-
paragensComOperadoras(Operadoras, [], NovaListaParagens),
profundidade_func_varios(Origem, Destino, Caminho, TempoViagem, NovaListaParagens).
% Função de pesquisa para a Query 7
pesquisaProfundidade_varios(Origem, Destino, [(Origem, 'Inicio')|Caminho], TempoViagem, 'Flag7') :-
findall(
paragem(G, L, Lo, E, T, 'Yes', Op, C, N, F),
paragem(G, L, Lo, E, T, 'Yes', Op, C, N, F),
ListaParagens
),
profundidade_func_varios(Origem, Destino, Caminho, TempoViagem, ListaParagens).
% Função de pesquisa para a Query 10
pesquisaProfundidade_varios(Origem, Destino, [(Origem, 'Inicio')|Caminho], TempoViagem, 'Flag10') :-
findall(
paragem(G, L, Lo, 'Bom', T, Pub, Op, C, N, F),
paragem(G, L, Lo, 'Bom', T, Pub, Op, C, N, F),
ListaParagens
),
profundidade_func_varios(Origem, Destino, Caminho, TempoViagem, ListaParagens).
% Função de pesquisa para a Query 8
pesquisaProfundidade_varios(Origem, Destino, [(Origem, 'Inicio')|Caminho], TempoViagem, AbrigosPossiveis, 'Flag8') :-
paragensComAbrigo(AbrigosPossiveis, [], NovaListaParagens),
profundidade_func_varios(Origem, Destino, Caminho, TempoViagem, NovaListaParagens).
profundidade_func_varios(Destino, Destino, [], T, _) :-
!,
T is 0.
profundidade_func_varios(Paragem, Destino, [(ProxParagem, Carreira)|Caminho], TempoViagem, ListaParagens) :-
adjacente(Paragem, ProxParagem, Carreira, T1, ListaParagens),
((T1 == 'N/A') -> TLimpo is 0.0 ; TLimpo is T1),
profundidade_func_varios(ProxParagem, Destino, Caminho, T, ListaParagens),
TempoViagem is T + TLimpo + 2. % Adiciona 2 min entre paragens de autocarros
% pesquisaProfundidade_varios(183, 608, Caminho, Tempo).
% Lista de Paragens com as Operadoras pretendidas
paragensComOperadoras([], His, His).
paragensComOperadoras([Op|Tail], His, NovaListaParagens) :-
findall(
paragem(G, La, Lo, E, T, P, Op, C, N, F),
paragem(G, La, Lo, E, T, P, Op, C, N, F),
Lista
),
append(Lista, His, R),
paragensComOperadoras(Tail, R, NovaListaParagens).
% Lista de Paragens com Abrigo
paragensComAbrigo([], His, His).
paragensComAbrigo([Abrigo|Tail], His, NovaListaParagens) :-
findall(
paragem(G, La, Lo, E, Abrigo, P, Op, C, N, F),
paragem(G, La, Lo, E, Abrigo, P, Op, C, N, F),
Lista
),
append(Lista, His, R),
paragensComAbrigo(Tail, R, NovaListaParagens).
%--------------------------------------------------------------------------------------------------------
% PESQUISA EM LARGURA
% Algoritmo de Pesquisa em Largura
% Este algoritmo apresenta várias informações relativas à paragem
pesquisaLargura(Origem, Destino, Caminho) :-
findall(
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
ListaParagens
),
paragem(Origem, _, _, Estado, _, _, Operadora, _, NomeRua, _),
pesquisaLargura_fun([[(Origem, 'Inicio', Operadora, Estado, NomeRua)]], Destino, C, ListaParagens),
inverso(C, Caminho).
pesquisaLargura_fun([[(Destino, Carreira, _, _, _)|Tail]|_], Destino, [(Destino, Carreira, _, _, _)|Tail], _).
pesquisaLargura_fun([[(Paragem, Carreira, Operadora, Estado, NomeRua)|Path]|Caminhos], Destino, Caminho, ListaParagens) :-
bagof(
[(M, C1, Op1, E1, Nom1), (Paragem, Carreira, Operadora, Estado, NomeRua)|Path],
(
adjacente_largura(Paragem, M, C1, Op1, E1, Nom1, ListaParagens),
\+ member((M, C1, Op1, E1, Nom1),
[(Paragem, Carreira, Operadora, Estado, NomeRua) | Path])
),
NovoCaminho
),
append(Caminhos, NovoCaminho, CaminhoEsq), !,
pesquisaLargura_fun(CaminhoEsq, Destino, Caminho, ListaParagens);
pesquisaLargura_fun(Caminhos, Destino, Caminho, ListaParagens).
adjacente_largura(Paragem, ProxParagem, Carreira, Operadora, Estado, NomeRua, ListaParagens) :-
member(
paragem(Paragem, _, _, _, _, _, _, _, _, _),
ListaParagens
),
member(
paragem(ProxParagem, _, _, Estado, _, _, Operadora, _, NomeRua, _),
ListaParagens
),
viagem(Carreira, Paragem, ProxParagem, _).
% pesquisaLargura(183, 595, Caminho).
% pesquisaLargura(183, 250, Caminho).
% pesquisaLargura(354, 79, Caminho).
% Algoritmo de Pesquisa em Largura
% Este algoritmo difere do anterior, pois apresenta menos informações relativas às paragens do caminho resultante
pesquisaLarguraSimplificado(Origem, Destino, Caminho) :-
findall(
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
ListaParagens
),
pesquisaLarguraSimplificado_fun([[(Origem, 'Inicio')]], Destino, C, ListaParagens),
inverso(C, Caminho).
pesquisaLarguraSimplificado_fun([[(Destino, Carreira)|Tail]|_], Destino, [(Destino, Carreira)|Tail], _).
pesquisaLarguraSimplificado_fun([[(Paragem, Carreira)|Path]|Caminhos], Destino, Caminho, ListaParagens) :-
bagof(
[(M, C1), (Paragem, Carreira)|Path],
(
adjacente(Paragem, M, C1, _, ListaParagens),
\+ member((M, C1),
[(Paragem, Carreira) | Path])
),
NovoCaminho
),
append(Caminhos, NovoCaminho, CaminhoEsq), !,
pesquisaLarguraSimplificado_fun(CaminhoEsq, Destino, Caminho, ListaParagens);
pesquisaLarguraSimplificado_fun(Caminhos, Destino, Caminho, ListaParagens).
% pesquisaLarguraSimplificado(183, 595, Caminho).
% pesquisaLarguraSimplificado(354, 79, Caminho).
%--------------------------------------------------------------------------------------------------------
% PESQUISA ESTRELA
tempoEstimado((LatX, LongX), (LatY, LongY), Estima) :-
((LatX == 'N/A') -> LatLimpoX is 999.9; LatLimpoX is LatX),
((LongX == 'N/A') -> LongLimpoX is 999.9; LongLimpoX is LongX),
((LatY == 'N/A') -> LatLimpoY is 999.9; LatLimpoY is LatY),
((LongY == 'N/A') -> LongLimpoY is 999.9; LongLimpoY is LongY),
DeltaLat is LatLimpoX - LatLimpoY,
DeltaLong is LongLimpoX - LongLimpoY,
Estima is (sqrt(DeltaLat^2 + DeltaLong^2))/1000.
% Algoritmo de Pesquisa informada AEstrela (a*)
pesquisaAEstrela(Origem, Destino, Caminho, Tempo) :-
findall(
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
ListaParagens
),
resolve_aestrela((Origem, 'Inicio'), Destino, Caminho/Tempo, ListaParagens).
resolve_aestrela((Origem, 'Inicio'), Destino, Caminho/Tempo, ListaParagens) :-
paragem(Origem, LatX, LongX, _, _, _, _, _, _, _),
paragem(Destino, LatY, LongY, _, _, _, _, _, _, _),
tempoEstimado((LatX, LongX), (LatY, LongY), Estima),
aestrela([[(Origem, 'Inicio')]/0/Estima], InvCaminho/Tempo/_, Destino, ListaParagens),
inverso(InvCaminho, Caminho).
aestrela(Caminhos, Caminho, Destino, _) :-
obtem_melhor(Caminhos, Caminho),
Caminho = [(Paragem, _)|_]/_/_,
Destino == Paragem.
aestrela(Caminhos, SolucaoCaminho, Destino, ListaParagens) :-
obtem_melhor(Caminhos, MelhorCaminho),
seleciona(MelhorCaminho, Caminhos, OutrosCaminhos),
expande_aestrela(MelhorCaminho, ExpCaminhos, Destino, ListaParagens),
append(OutrosCaminhos, ExpCaminhos, NovoCaminhos),
aestrela(NovoCaminhos, SolucaoCaminho, Destino, ListaParagens).
obtem_melhor([Caminho], Caminho) :- !.
obtem_melhor([Caminho1/Tempo1/Est1, _/Tempo2/Est2|Caminhos], MelhorCaminho) :-
Tempo1 + Est1 =< Tempo2 + Est2, !,
obtem_melhor([Caminho1/Tempo1/Est1|Caminhos], MelhorCaminho).
obtem_melhor([_|Caminhos], MelhorCaminho) :-
obtem_melhor(Caminhos, MelhorCaminho).
expande_aestrela(Caminho, ExpCaminhos, Destino, ListaParagens) :-
findall(
NovoCaminho,
adjacente_aestrela(Caminho, NovoCaminho, Destino, ListaParagens),
ExpCaminhos
).
% A adição dos 2 min serve como tempo médio de espera entre viagens
adjacente_aestrela([(Paragem, Carreira1)|Caminho]/Tempo/_, [(ProxParagem, Carreira2), (Paragem, Carreira1)|Caminho]/NovoTempo/Est,
Destino, ListaParagens) :-
adjacente(Paragem, ProxParagem, Carreira2, PassoTempo, ListaParagens),
\+ member((ProxParagem, Carreira2), Caminho),
NovoTempo is Tempo + PassoTempo + 2,
paragem(ProxParagem, LatX, LongX, _, _, _, _, _, _, _),
paragem(Destino, LatY, LongY, _, _, _, _, _, _, _),
tempoEstimado((LatX, LongX), (LatY, LongY), Est).
seleciona(E, [E|Xs], Xs).
seleciona(E, [X|Xs], [X|Ys]) :-
seleciona(E, Xs, Ys).
% pesquisaAEstrela(183, 79, Caminho, Tempo).
%--------------------------------------------------------------------------------------------------------
% PESQUISA GULOSA
% Algoritmo de Pesquisa informada Gulosa (Greedy)
pesquisaGulosa(Origem, Destino, Caminho, Tempo) :-
findall(
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
paragem(Gid, Lat, Long, Estado, TipoAbrigo, Publicidade, Operadora, Codigo, NomeRua, Freguesia),
ListaParagens
),
resolve_gulosa((Origem, 'Inicio'), Destino, Caminho/Tempo, ListaParagens).
resolve_gulosa((Origem, 'Inicio'), Destino, Caminho/Tempo, ListaParagens) :-
paragem(Origem, LatX, LongX, _, _, _, _, _, _, _),
paragem(Destino, LatY, LongY, _, _, _, _, _, _, _),
tempoEstimado((LatX, LongX), (LatY, LongY), Estima),
gulosa([[(Origem, 'Inicio')]/0/Estima], InvCaminho/Tempo/_, Destino, ListaParagens),
inverso(InvCaminho, Caminho).
gulosa(Caminhos, Caminho, Destino, _) :-
obtem_melhor_gulosa(Caminhos, Caminho),
Caminho = [(Paragem, _)|_]/_/_,
Destino == Paragem.
gulosa(Caminhos, SolucaoCaminho, Destino, ListaParagens) :-
obtem_melhor_gulosa(Caminhos, MelhorCaminho),
seleciona(MelhorCaminho, Caminhos, OutrosCaminhos),
expande_aestrela(MelhorCaminho, ExpCaminhos, Destino, ListaParagens),
append(OutrosCaminhos, ExpCaminhos, NovoCaminhos),
gulosa(NovoCaminhos, SolucaoCaminho, Destino, ListaParagens).
obtem_melhor_gulosa([Caminho], Caminho) :- !.
obtem_melhor_gulosa([Caminho1/Tempo1/Est1, _/_/Est2|Caminhos], MelhorCaminho) :-
Est1 =< Est2, !,
obtem_melhor_gulosa([Caminho1/Tempo1/Est1|Caminhos], MelhorCaminho).
obtem_melhor_gulosa([_|Caminhos], MelhorCaminho) :-
obtem_melhor_gulosa(Caminhos, MelhorCaminho).
% pesquisaGulosa(183, 499, C, T).
% pesquisaGulosa(183, 250, C, T).