build.gradle

buildscript {
  repositories { jcenter() }
  dependencies { 
    classpath 'com.netflix.nebula:gradle-rxjava-project-plugin:4.0.0'
    classpath 'ru.vyarus:gradle-animalsniffer-plugin:1.1.0' 
  }
}

apply plugin: 'java'
apply plugin: 'nebula.rxjava-project'
apply plugin: 'jacoco'
apply plugin: 'ru.vyarus.animalsniffer'

dependencies {
    signature 'org.codehaus.mojo.signature:java16:1.1@signature'

    compile 'io.reactivex:rxjava:1.1.6'

    testCompile 'junit:junit:4.12'
    testCompile 'org.mockito:mockito-core:1.10.19'
}

// support for snapshot/final releases with the various branches RxJava uses
nebulaRelease {
    addReleaseBranchPattern(/\d+\.\d+\.\d+/)
    addReleaseBranchPattern('HEAD')
}

if (project.hasProperty('release.useLastTag')) {
    tasks.prepare.enabled = false
}

jacoco {
    toolVersion = '0.7.7.201606060606' // See http://www.eclemma.org/jacoco/.
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

build.dependsOn jacocoTestReport
check.dependsOn jacocoTestReport