build.gradle

plugins {
    id 'maven-publish'
    id 'fabric-loom' version '1.6-SNAPSHOT' apply false

    // https://github.com/ReplayMod/preprocessor
    // https://github.com/Fallen-Breath/preprocessor
    id 'com.replaymod.preprocess' version '88169fc'

    // https://github.com/Fallen-Breath/yamlang
    id 'me.fallenbreath.yamlang' version '1.3.1' apply false
}

preprocess {
    def mc120 = createNode('1.20.1'  , 1_20_01, 'yarn')
    def mc1202 = createNode('1.20.2'  , 1_20_02, 'yarn')
    def mc1204 = createNode('1.20.4'  , 1_20_04, 'yarn')
    def mc1206 = createNode('1.20.6'  , 1_20_06, 'yarn')

    mc1206.link(mc1204, file('versions/mapping-1.20.6-1.20.4.txt'))
    mc1204.link(mc1202, file('versions/mapping-1.20.4-1.20.2.txt'))
    mc1202.link(mc120, file('versions/mapping-1.20.2-1.20.1.txt'))
}

tasks.register('buildAndGather') {
    subprojects {
        dependsOn project.tasks.named('build').get()
    }
    doFirst {
        println 'Gathering builds'
        def buildLibs = {
            p -> p.buildDir.toPath().resolve('libs')
        }
        delete fileTree(buildLibs(rootProject)) {
            include '*'
        }
        subprojects {
            copy {
                from(buildLibs(project)) {
                    include '*.jar'
                    exclude '*-dev.jar', '*-sources.jar'
                }
                into buildLibs(rootProject)
                duplicatesStrategy DuplicatesStrategy.INCLUDE
            }
        }
    }
}