build.gradle

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
    }

    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.0'
    }
}

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'checkstyle'
apply plugin: 'com.github.johnrengelman.shadow'

group = 'org.hypergraphql'
version = '2.0.0'

sourceCompatibility = 11
targetCompatibility = 11

repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
}

ext {
    graphqlVersion = '15.0'
    jenaVersion = '3.8.0'
}
dependencies {

    compileOnly group: 'org.projectlombok', name:'lombok', version: '1.18.16'
    annotationProcessor group: 'org.projectlombok', name:'lombok', version: '1.18.16'

    compile group: 'com.graphql-java', name: 'graphql-java', version: graphqlVersion

    compile group: 'org.apache.jena', name: 'jena-arq', version: jenaVersion
    compile group: 'org.apache.jena', name: 'jena', version: jenaVersion
    compile group: 'org.apache.jena', name: 'jena-core', version: jenaVersion
    compile group: 'org.apache.jena', name: 'jena-fuseki-embedded', version: '3.8.0'

    compile group: 'log4j', name: 'log4j', version: '1.2.17'
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
    compile group: 'org.slf4j', name: 'slf4j-log4j12', version: '1.7.25'

    compile group: 'com.sparkjava', name: 'spark-core', version: '2.9.2'
    compile group: 'com.sparkjava', name: 'spark-template-velocity', version: '2.7.1'
    compile group: 'com.sparkjava', name: 'spark-core', version: '2.9.2'
    compile group: 'com.mashape.unirest', name: 'unirest-java', version: '1.4.9'
    compile group: 'com.amazonaws', name: 'aws-java-sdk-s3', version: '1.11.869'

    testCompile group: 'org.mockito', name: 'mockito-core', version: '3.5.11'

    testCompileOnly('org.apiguardian:apiguardian-api:1.1.0')

    testImplementation(
            'org.junit.jupiter:junit-jupiter-api:5.7.0'
    )
    testRuntimeOnly(
            'org.junit.jupiter:junit-jupiter-engine:5.7.0'
    )

    testCompileOnly group: 'org.projectlombok', name:'lombok', version: '1.18.16'
    testAnnotationProcessor group: 'org.projectlombok', name:'lombok', version: '1.18.16'
}

checkstyle {
    toolVersion '8.29'
    configFile file("checkstyle/checkstyle.xml")
}
checkstyleMain {
    source ='src/main/java'
}
checkstyleTest {
    source ='src/test/java'
}

test {
    systemProperty 'hgql_version', project.version
    useJUnitPlatform()
    testLogging {
        events 'PASSED', 'FAILED', 'SKIPPED'
    }
}

task execute(type:JavaExec) {
    systemProperty('hgql_version', project.version)
    main = 'org.hypergraphql.Application'
    classpath = sourceSets.main.runtimeClasspath

    if(project.hasProperty('a')){
        args(a.split(','))
    }
}

sourceSets {
    main {
        resources {
            include '**/*.json', '**/*.xml', '**/*.vtl', '**/*.properties', '**/*.txt', '**/*.graphql'
        }
    }
}

shadowJar {
    zip64 = true
    exclude 'META-INF/*', 'META-INF/**', 'LICENSE', 'LICENSE/**', 'license', 'license/**'
    classifier = 'exe'

    manifest {
        attributes("Main-Class": "org.hypergraphql.Application")
    }
}