build.gradle

plugins {
    id 'java'
    id 'application'
}

group 'com.shade'
version '0.1.24'

application {
    mainClass = 'com.shade.platform.Launcher'
    executableDir = ''
    applicationDefaultJvmArgs = [
            // Required for UIUtils#minimizePanel
            '--add-opens', 'java.desktop/javax.swing.plaf.basic=ALL-UNNAMED'
    ]
}

dependencies {
    implementation project(':bundle-lwjgl')
    implementation project(':platform-model')
    implementation project(':platform-ui')
    implementation project(':decima-model')
    implementation project(':decima-ui')
    implementation project(':decima-ext-model-exporter')
    implementation project(':decima-ext-model-viewer')
    implementation project(':decima-ext-shader-viewer')
    implementation project(':decima-ext-texture-viewer')
}

allprojects {
    apply plugin: 'java'
    apply plugin: 'java-library'

    repositories {
        mavenCentral()
    }

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(17)
        }
    }

    test {
        useJUnitPlatform()
    }

    dependencies {
        // https://mvnrepository.com/artifact/ch.qos.logback/logback-classic
        implementation group: 'ch.qos.logback', name: 'logback-classic', version: '1.4.4'

        // https://mvnrepository.com/artifact/org.junit.jupiter
        testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: '5.9.1'
        testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-params', version: '5.9.1'
        testRuntimeOnly group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: '5.9.1'
    }
}