-
Notifications
You must be signed in to change notification settings - Fork 16
/
OperatorEnumConstruction.jl
278 lines (250 loc) · 9.8 KB
/
OperatorEnumConstruction.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
module OperatorEnumConstructionModule
import Requires: @init, @require
import ..OperatorEnumModule: AbstractOperatorEnum, OperatorEnum, GenericOperatorEnum
import ..EquationModule: string_tree, Node
import ..EvaluateEquationModule: eval_tree_array
import ..EvaluateEquationDerivativeModule: eval_grad_tree_array
import ..EvaluationHelpersModule: _grad_evaluator
generate_diff_operators(::Any, ::Any) = error("`Zygote` not loaded.")
@init @require Zygote = "e88e6eb3-aa80-5325-afca-941959d7151f" @eval begin
include("zygote_interface.jl")
end
function create_evaluation_helpers!(operators::OperatorEnum)
@eval begin
Base.print(io::IO, tree::Node) = print(io, string_tree(tree, $operators))
Base.show(io::IO, tree::Node) = print(io, string_tree(tree, $operators))
function (tree::Node)(X; kws...)
Base.depwarn(
"The `tree(X; kws...)` syntax is deprecated. Use `tree(X, operators; kws...)` instead.",
:Node,
)
return tree(X, $operators; kws...)
end
# Gradients:
function _grad_evaluator(tree::Node, X; kws...)
Base.depwarn(
"The `tree'(X; kws...)` syntax is deprecated. Use `tree'(X, operators; kws...)` instead.",
:Node,
)
return _grad_evaluator(tree, X, $operators; kws...)
end
end
end
function create_evaluation_helpers!(operators::GenericOperatorEnum)
@eval begin
Base.print(io::IO, tree::Node) = print(io, string_tree(tree, $operators))
Base.show(io::IO, tree::Node) = print(io, string_tree(tree, $operators))
function (tree::Node)(X; kws...)
Base.depwarn(
"The `tree(X; kws...)` syntax is deprecated. Use `tree(X, operators; kws...)` instead.",
:Node,
)
return tree(X, $operators; kws...)
end
function _grad_evaluator(tree::Node, X; kws...)
return error("Gradients are not implemented for `GenericOperatorEnum`.")
end
end
end
function _extend_unary_operator(f::Symbol, op, type_requirements)
quote
quote
function $($f)(l::Node{T})::Node{T} where {T<:$($type_requirements)}
return if (l.degree == 0 && l.constant)
Node(T; val=$($f)(l.val::T))
else
Node($($op), l)
end
end
end
end
end
function _extend_binary_operator(f::Symbol, op, type_requirements, build_converters)
quote
quote
function $($f)(l::Node{T}, r::Node{T}) where {T<:$($type_requirements)}
if (l.degree == 0 && l.constant && r.degree == 0 && r.constant)
Node(T; val=$($f)(l.val::T, r.val::T))
else
Node($($op), l, r)
end
end
function $($f)(l::Node{T}, r::T) where {T<:$($type_requirements)}
if l.degree == 0 && l.constant
Node(T; val=$($f)(l.val::T, r))
else
Node($($op), l, Node(T; val=r))
end
end
function $($f)(l::T, r::Node{T}) where {T<:$($type_requirements)}
if r.degree == 0 && r.constant
Node(T; val=$($f)(l, r.val::T))
else
Node($($op), Node(T; val=l), r)
end
end
if $($build_converters)
# Converters:
function $($f)(
l::Node{T1}, r::Node{T2}
) where {T1<:$($type_requirements),T2<:$($type_requirements)}
T = promote_type(T1, T2)
l = convert(Node{T}, l)
r = convert(Node{T}, r)
return $($f)(l, r)
end
function $($f)(
l::Node{T1}, r::T2
) where {T1<:$($type_requirements),T2<:$($type_requirements)}
T = promote_type(T1, T2)
l = convert(Node{T}, l)
r = convert(T, r)
return $($f)(l, r)
end
function $($f)(
l::T1, r::Node{T2}
) where {T1<:$($type_requirements),T2<:$($type_requirements)}
T = promote_type(T1, T2)
l = convert(T, l)
r = convert(Node{T}, r)
return $($f)(l, r)
end
end
end
end
end
function _extend_operators(operators, skip_user_operators, __module__::Module)
binary_ex = _extend_binary_operator(:f, :op, :type_requirements, :build_converters)
unary_ex = _extend_unary_operator(:f, :op, :type_requirements)
return quote
local type_requirements
local build_converters
if isa($operators, OperatorEnum)
type_requirements = Number
build_converters = true
else
type_requirements = Any
build_converters = false
end
for (op, f) in enumerate(map(Symbol, $(operators).binops))
if isdefined(Base, f)
f = :(Base.$(f))
elseif $(skip_user_operators)
continue
else
f = :($($__module__).$(f))
end
eval($binary_ex)
end
for (op, f) in enumerate(map(Symbol, $(operators).unaops))
if isdefined(Base, f)
f = :(Base.$(f))
elseif $(skip_user_operators)
continue
else
f = :($($__module__).$(f))
end
eval($unary_ex)
end
end
end
"""
@extend_operators operators
Extends all operators defined in this operator enum to work on the
`Node` type. While by default this is already done for operators defined
in `Base` when you create an enum and pass `define_helper_functions=true`,
this does not apply to the user-defined operators. Thus, to do so, you must
apply this macro to the operator enum in the same module you have the operators
defined.
"""
macro extend_operators(operators)
ex = _extend_operators(esc(operators), false, __module__)
expected_type = AbstractOperatorEnum
quote
if !isa($(esc(operators)), $expected_type)
error("You must pass an operator enum to `@extend_operators`.")
end
$ex
end
end
"""
@extend_operators_base operators
Similar to `@extend_operators`, but only extends operators already
defined in `Base`.
"""
macro extend_operators_base(operators)
ex = _extend_operators(esc(operators), true, __module__)
expected_type = AbstractOperatorEnum
quote
if !isa($(esc(operators)), $expected_type)
error("You must pass an operator enum to `@extend_operators_base`.")
end
$ex
end
end
"""
OperatorEnum(; binary_operators=[], unary_operators=[], enable_autodiff::Bool=false, define_helper_functions::Bool=true)
Construct an `OperatorEnum` object, defining the possible expressions. This will also
redefine operators for `Node` types, as well as `show`, `print`, and `(::Node)(X)`.
It will automatically compute derivatives with `Zygote.jl`.
# Arguments
- `binary_operators::Vector{Function}`: A vector of functions, each of which is a binary
operator.
- `unary_operators::Vector{Function}`: A vector of functions, each of which is a unary
operator.
- `enable_autodiff::Bool=false`: Whether to enable automatic differentiation.
- `define_helper_functions::Bool=true`: Whether to define helper functions for creating
and evaluating node types. Turn this off when doing precompilation. Note that these
are *not* needed for the package to work; they are purely for convenience.
"""
function OperatorEnum(;
binary_operators=[],
unary_operators=[],
enable_autodiff::Bool=false,
define_helper_functions::Bool=true,
)
@assert length(binary_operators) > 0 || length(unary_operators) > 0
binary_operators = Function[op for op in binary_operators]
unary_operators = Function[op for op in unary_operators]
diff_bin, diff_una = if enable_autodiff
Base.require(@__MODULE__, :Zygote)
Base.invokelatest(generate_diff_operators, binary_operators, unary_operators)
else
Function[], Function[]
end
operators = OperatorEnum(binary_operators, unary_operators, diff_bin, diff_una)
if define_helper_functions
@extend_operators_base operators
create_evaluation_helpers!(operators)
end
return operators
end
"""
GenericOperatorEnum(; binary_operators=[], unary_operators=[], define_helper_functions::Bool=true)
Construct a `GenericOperatorEnum` object, defining possible expressions.
Unlike `OperatorEnum`, this enum one will work arbitrary operators and data types.
This will also redefine operators for `Node` types, as well as `show`, `print`,
and `(::Node)(X)`.
# Arguments
- `binary_operators::Vector{Function}`: A vector of functions, each of which is a binary
operator.
- `unary_operators::Vector{Function}`: A vector of functions, each of which is a unary
operator.
- `define_helper_functions::Bool=true`: Whether to define helper functions for creating
and evaluating node types. Turn this off when doing precompilation. Note that these
are *not* needed for the package to work; they are purely for convenience.
"""
function GenericOperatorEnum(;
binary_operators=[], unary_operators=[], define_helper_functions::Bool=true
)
@assert length(binary_operators) > 0 || length(unary_operators) > 0
binary_operators = Function[op for op in binary_operators]
unary_operators = Function[op for op in unary_operators]
operators = GenericOperatorEnum(binary_operators, unary_operators)
if define_helper_functions
@extend_operators_base operators
create_evaluation_helpers!(operators)
end
return operators
end
end