build.gradle

/*
 * Copyright 2017 ThoughtWorks, Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'java'
apply from: 'https://raw.githubusercontent.com/gocd/gradle-task-helpers/4d3374681565f5eb8b06e7389e069d4d997efefc/helper.gradle'


gocdPlugin {
    id = 'cd.go.artifact.s3'
    pluginVersion = "2.1.1"
    goCdVersion = '18.7.0'
    name = 'Artifact plugin for S3'
    description = 'Plugin allows to store and fetch artifacts using Amazon S3'
    vendorName = 'Diogo Oliveira'
    vendorUrl = 'https://github.com/absa-group/s3-artifact-plugin'

    githubRepo {
        owner = 'absa-group'
        repo = 's3-artifact-plugin-cldfrc'
        token = System.getenv('GITHUB_TOKEN') ?: 'bad-token'
    }

    pluginProject = project

    prerelease = !"No".equalsIgnoreCase(System.getenv('PRERELEASE'))
    assetsToRelease = [project.tasks.findByName('jar')]
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

version = gocdPlugin.fullVersion(project)

repositories {
    mavenCentral()
}

sourceSets {
    test {
        java {
            compileClasspath += configurations.compileOnly
            runtimeClasspath += configurations.compileOnly
        }
    }
}

test {
    useJUnit {
        excludeCategories 'diogomrol.gocd.s3.artifact.plugin.IntegrationTests'
    }
}

task integrationTest(type: Test) {
    description = 'Runs integration tests.'
    group = 'verification'

    testClassesDirs = sourceSets.test.output.classesDirs
    classpath = sourceSets.test.runtimeClasspath
    shouldRunAfter test

    useJUnit {
        includeCategories 'diogomrol.gocd.s3.artifact.plugin.IntegrationTests'
    }
}

check.dependsOn integrationTest

dependencies {
    compileOnly group: 'cd.go.plugin', name: 'go-plugin-api', version: '18.6.0'
    compile group: 'com.google.code.gson', name: 'gson', version: '2.8.5'
    compile group: 'com.spotify', name: 'docker-client', version: '8.10.1'
    compile group: 'com.amazonaws', name: 'aws-java-sdk-s3', version: '1.11.987'
    compile group: 'org.apache.commons', name: 'commons-lang3', version: '3.5'
    compile group: 'org.apache.ant', name: 'ant', version: '1.10.5'

    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile group: 'org.assertj', name: 'assertj-core', version: '3.12.2'
    testCompile group: 'org.mockito', name: 'mockito-core', version: '2.25.1'
    testCompile group: 'org.skyscreamer', name: 'jsonassert', version: '1.5.0'
    testCompile group: 'org.jsoup', name: 'jsoup', version: '1.10.2'
    testCompile group: 'cd.go.plugin', name: 'go-plugin-api', version: '18.6.0'
}

jar {
    from(configurations.compile) {
        into "lib/"
    }
}