build.gradle

buildscript {

    repositories {
        mavenLocal()
        jcenter()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:2.1.0"
        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.4.1'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.6'
    }
}

group = 'com.taobao.android'

version = '1.1.4.22-rc8'



apply plugin: 'com.android.library'
//apply plugin: 'maven-publish'
apply plugin: 'com.github.dcendents.android-maven'
apply plugin: 'com.jfrog.bintray'
//apply from: 'http://gitlab.alibaba-inc.com/android-build-system/buildscript/raw/master/mtl-publish.gradle'


android {
    compileSdkVersion 23
    buildToolsVersion "23.0.2"
    lintOptions {
        checkReleaseBuilds false
        abortOnError false
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }


}

repositories {
    mavenLocal()
    jcenter()
}

dependencies {

    compile 'com.taobao.android:atlas_core:5.1.0.9-rc2'
    compile 'io.reactivex.rxjava2:rxjava:2.0.1'
    compile 'org.reactivestreams:reactive-streams:1.0.0@jar'
}

def siteUrl = 'https://github.com/alibaba/atlas'
// 项目的主页
def gitUrl = 'https://github.com/alibaba/atlas'
// Git仓库的url
install {
    repositories.mavenInstaller {
        // This generates POM.xml with proper parameters
        pom {
            project {
                packaging 'aar'
                // Add your description here
                name 'atlasupdate' //项目描述
                // Set your license
                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id 'alibabaatlas' //填写的一些基本信息
                        name project.name
                        email 'alibabaatlasframework@gmail.com'
                    }
                }
                scm {
                    connection gitUrl
                    developerConnection gitUrl
                    url siteUrl
                }
            }
        }
    }
}

Properties properties = new Properties()
properties.load(project.rootProject.file('local.properties').newDataInputStream())
bintray {
    user = properties.getProperty("bintray.user")
    key = properties.getProperty("bintray.apikey")

    // publications = ['mavenJava']
   configurations = ['archives']
    // publications = ['maven']
    pkg {
        repo = "maven"
        name = project.name	//发布到JCenter上的项目名字
        websiteUrl = "atlas.alibaba.net"
        vcsUrl = gitUrl
        licenses = ["Apache-2.0"]
        publish = true
    }
}

task sourcesJar(type: Jar) {
    from('src/main/java') {
        include '**'
    }
    classifier = 'sources'
}

artifacts {
    archives sourcesJar
}