-
Notifications
You must be signed in to change notification settings - Fork 1
/
grammar.ebnf
47 lines (34 loc) · 1.18 KB
/
grammar.ebnf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
GRAMMAR
-------
Inspired by the POSIX standard for the "Shell Command Language"
[1]. Specified in a kind of EBNF [2][3]. Tokens are written in
uppercase and parser rules in lowercase.
Described for humans - the lexer and parser are written by hand. The
"program" rule is the root of the parser.
======= grammar below ================================================
WORD = ? like the WORD in the POSIX shell standard, but dumber ? ;
GT = ">" ;
DGT = ">>" ;
LT = "<" ;
DLT = "<<" ;
AMP = "&" ;
AND = "&&" ;
PIPE = "|" ;
OR = "||" ;
SEMI = ";" ;
IONUM = ? digit ?, { ? digit ? } ;
program = and or, { separator, and or } ;
and or = pipe sequence
| and or, AND, pipe sequence
| and or, OR, pipe sequence
;
pipe sequence = command, { PIPE, command } ;
command = WORD, { WORD }, { redirect } ;
redirect = [ IONUM ], ( LT | GT | DGT ), WORD ;
separator = ( AMP | SEMI ) ;
======= grammar above ================================================
References:
-----------
[1]: https://pubs.opengroup.org/onlinepubs/9699919799/utilities/V3_chap02.html
[2]: https://en.wikipedia.org/wiki/Extended_Backus%E2%80%93Naur_form
[3]: https://www.ics.uci.edu/~pattis/misc/ebnf2.pdf