Runfile

EXPORT RUN := ${.RUN}
EXPORT RUNFILE := ${.RUNFILE}

## 
# Build Covey
# OPTION LIVE -l, --live Build Covey without bundling any assets.
# OPTION RELEASE -r, --release Strip symbols and compress Covey binary.
build:
    TAGS=""
    LD=""
    "${RUN}" -r "${RUNFILE}" agent --release
    [[ "${LIVE}" ]] && TAGS=-tags=live && echo "Building Covey without assets"
    [[ "${RELEASE}" ]] && echo "Building Covey without symbols"
    echo "Building Covey"
    [[ "${RELEASE}" ]] \
        && go build -trimpath ${TAGS} -ldflags="-s -w" github.com/chabad360/covey \
        || go build -trimpath ${TAGS} github.com/chabad360/covey
    [[ "${RELEASE}" ]] && echo "Compressing binary" && upx covey 

## 
# Build Covey Agent
# OPTION RELEASE -r, --release Strip symbols and compress the Agent binary.
agent:
    LD=""
    echo "Building Covey Agent"
    [[ "${RELEASE}" ]] \
        && echo "Building Covey Agent without symbols" \
        && go build -trimpath -ldflags="-s -w" -o assets/agent/agent github.com/chabad360/covey/agent \
        || go build -o assets/agent/agent github.com/chabad360/covey/agent
    [[ "${RELEASE}" ]] && echo "Compressing binary" && upx assets/agent/agent


## Build and run Covey with -tag live
run:
    "${RUN}" -r "${RUNFILE}" build --live && ./covey