build.gradle

plugins {
  id 'java'
  id 'idea'
  id 'signing'
  id 'maven-publish'
  id 'nebula.javadoc-jar' version '18.1.0'
  id 'nebula.source-jar' version '18.1.0'
  id 'com.github.johnrengelman.shadow' version '7.1.0'
  id 'nebula.dependency-lock' version "12.1.5"
}

apply plugin: 'nebula.dependency-lock'

wrapper {
  gradleVersion = '7.3'
}

apply from: "$rootDir/gradle/libs.gradle"

allprojects {

  sourceCompatibility = 1.8

  repositories {
    mavenCentral()
  }

  apply plugin: 'java'
  apply plugin: 'idea'
  apply plugin: 'signing'
  apply plugin: 'maven-publish'
  apply plugin: 'nebula.javadoc-jar'
  apply plugin: 'nebula.source-jar'
  apply plugin: 'nebula.dependency-lock'

  idea {
    module {
      downloadSources = true
      downloadJavadoc = true
    }
  }

  publishing {
    repositories {
      maven {

        def stagingRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2'
        def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots/'

        url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : stagingRepoUrl

        ext.sonatypeUsername = project.properties.ossrhUsername
        ext.sonatypePassword = project.properties.ossrhPassword
        credentials {
          username sonatypeUsername
          password sonatypePassword
        }
      }
    }
  }
}