-
Notifications
You must be signed in to change notification settings - Fork 0
/
stack.tf
325 lines (266 loc) · 10.3 KB
/
stack.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
locals {
service_account_name = "terraform-sa"
service_account_editor_name = "sa-editor"
otlp_name = "${var.slug}-otlp-access"
read_only_name = "${var.slug}-read-only-access"
read_only_multi_stack = "${var.slug}-read-only-multi-stack-access"
write_only_name = "${var.slug}-write-only-access"
rules_management_name = "${var.slug}-rules-management-access"
}
resource "grafana_cloud_stack" "this" {
provider = grafana.cloud
name = var.hosted_zone_name != null ? aws_route53_record.this[0].fqdn : var.stack_name
slug = var.slug
region_slug = var.region_slug
description = var.stack_description
url = var.hosted_zone_name != null ? "https://${aws_route53_record.this[0].fqdn}" : var.url
labels = var.stack_labels
}
resource "grafana_cloud_stack_service_account" "this" {
provider = grafana.cloud
stack_slug = grafana_cloud_stack.this.slug
name = local.service_account_name
role = "Admin"
is_disabled = false
}
resource "grafana_cloud_stack_service_account_token" "this" {
provider = grafana.cloud
stack_slug = grafana_cloud_stack.this.slug
name = "${local.service_account_name}-key"
service_account_id = grafana_cloud_stack_service_account.this.id
}
resource "grafana_cloud_stack_service_account" "editor" {
count = length(var.service_account_editor_permissions) > 0 ? 1 : 0
provider = grafana.cloud
stack_slug = grafana_cloud_stack.this.slug
name = local.service_account_editor_name
role = "Viewer"
is_disabled = false
}
resource "grafana_cloud_stack_service_account_token" "editor" {
count = length(var.service_account_editor_permissions) > 0 ? 1 : 0
provider = grafana.cloud
stack_slug = grafana_cloud_stack.this.slug
name = "${local.service_account_editor_name}-key"
service_account_id = grafana_cloud_stack_service_account.editor[0].id
}
resource "grafana_role_assignment_item" "editor" {
provider = grafana.stack
for_each = toset(var.service_account_editor_permissions)
role_uid = data.grafana_role.this[each.value].uid
service_account_id = trimprefix(grafana_cloud_stack_service_account.editor[0].id, "${var.slug}:")
}
resource "aws_ssm_parameter" "grafana_cloud_stack_service_account_token" {
provider = aws.route53
name = "/grafana-cloud/${var.slug}/${local.service_account_name}-access-token"
type = "SecureString"
value = grafana_cloud_stack_service_account_token.this.key
}
resource "aws_ssm_parameter" "grafana_cloud_stack_url" {
provider = aws.route53
name = "/grafana-cloud/${var.slug}/stack-url"
type = "String"
value = grafana_cloud_stack.this.url
}
resource "grafana_cloud_plugin_installation" "this" {
for_each = { for x in var.plugins : x.plugin => x }
provider = grafana.cloud
stack_slug = grafana_cloud_stack.this.slug
slug = each.value.plugin
version = each.value.version
}
resource "grafana_cloud_access_policy" "read_only" {
count = var.create_read_only_token ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
name = local.read_only_name
scopes = ["metrics:read", "logs:read", "traces:read", "profiles:read", "alerts:read", "rules:read"]
realm {
type = "stack"
identifier = grafana_cloud_stack.this.id
}
}
resource "grafana_cloud_access_policy_token" "read_only" {
count = var.create_read_only_token ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
access_policy_id = grafana_cloud_access_policy.read_only[0].policy_id
name = local.read_only_name
}
resource "aws_ssm_parameter" "read_only" {
count = var.create_read_only_token ? 1 : 0
provider = aws.route53
name = "/grafana-cloud/${var.slug}/read-only-access-token"
type = "SecureString"
value = grafana_cloud_access_policy_token.read_only[0].token
}
data "grafana_cloud_stack" "this" {
provider = grafana.cloud
for_each = toset(var.stacks_for_multi_stack_querying)
slug = each.value
}
resource "grafana_cloud_access_policy" "read_only_multi_stack" {
count = length(var.stacks_for_multi_stack_querying) > 0 ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
name = local.read_only_multi_stack
scopes = ["metrics:read", "logs:read", "traces:read", "profiles:read", "alerts:read", "rules:read"]
dynamic "realm" {
for_each = toset(var.stacks_for_multi_stack_querying)
content {
type = "stack"
identifier = data.grafana_cloud_stack.this[realm.value].id
}
}
}
resource "grafana_cloud_access_policy_token" "read_only_multi_stack" {
count = length(var.stacks_for_multi_stack_querying) > 0 ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
access_policy_id = grafana_cloud_access_policy.read_only_multi_stack[0].policy_id
name = local.read_only_multi_stack
}
resource "aws_ssm_parameter" "read_only_multi_stack" {
count = length(var.stacks_for_multi_stack_querying) > 0 ? 1 : 0
provider = aws.route53
name = "/grafana-cloud/${var.slug}/read-only-multi-stack-access-token"
type = "SecureString"
value = grafana_cloud_access_policy_token.read_only_multi_stack[0].token
}
resource "grafana_team" "this" {
provider = grafana.stack
for_each = { for team in var.teams : team.name => team }
name = each.value.name
team_sync {
groups = each.value.groups
}
}
data "grafana_role" "this" {
depends_on = [grafana_cloud_stack_service_account_token.this]
provider = grafana.stack
for_each = toset(flatten([
for team in var.teams : team.permissions
]))
name = each.value
}
resource "grafana_role_assignment_item" "this" {
provider = grafana.stack
for_each = { for combination in flatten([
for team in var.teams : [
for permission in team.permissions : {
key = "${team.name}-${permission}",
name = team.name,
permission = permission
}
]
]) :
combination.key => combination
}
role_uid = data.grafana_role.this[each.value.permission].uid
team_id = grafana_team.this[each.value.name].id
}
resource "grafana_cloud_access_policy" "write_only" {
count = var.create_write_only_token ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
name = local.write_only_name
scopes = ["metrics:write", "metrics:import", "logs:write", "traces:write", "alerts:write", "rules:write", "profiles:write"]
realm {
type = "stack"
identifier = grafana_cloud_stack.this.id
}
}
resource "grafana_cloud_access_policy_token" "write_only" {
count = var.create_write_only_token ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
access_policy_id = grafana_cloud_access_policy.write_only[0].policy_id
name = local.write_only_name
}
resource "aws_ssm_parameter" "write_only" {
count = var.create_write_only_token ? 1 : 0
provider = aws.route53
name = "/grafana-cloud/${var.slug}/write-only-access-token"
type = "SecureString"
value = grafana_cloud_access_policy_token.write_only[0].token
}
resource "grafana_cloud_access_policy" "rules_management" {
count = var.create_rules_management_token ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
name = local.rules_management_name
scopes = ["rules:read", "rules:write", "adaptive-metrics-rules:read", "adaptive-metrics-rules:write", "adaptive-metrics-rules:delete"]
realm {
type = "stack"
identifier = grafana_cloud_stack.this.id
}
}
resource "grafana_cloud_access_policy_token" "rules_management" {
count = var.create_rules_management_token ? 1 : 0
provider = grafana.cloud
region = grafana_cloud_stack.this.region_slug
access_policy_id = grafana_cloud_access_policy.rules_management[0].policy_id
name = local.rules_management_name
}
# trunk-ignore(checkov/CKV_AWS_337)
resource "aws_ssm_parameter" "rules_management" {
count = var.create_rules_management_token ? 1 : 0
provider = aws.route53
name = "/grafana-cloud/${var.slug}/rules-management-access-token"
type = "SecureString"
value = grafana_cloud_access_policy_token.rules_management[0].token
}
# trunk-ignore(checkov/CKV2_AWS_34)
resource "aws_ssm_parameter" "prometheus_url" {
provider = aws.route53
name = "/grafana-cloud/${var.slug}/prometheus-url"
type = "String"
value = grafana_cloud_stack.this.prometheus_url
}
# trunk-ignore(checkov/CKV_AWS_337)
resource "aws_ssm_parameter" "prometheus_user_id" {
provider = aws.route53
name = "/grafana-cloud/${var.slug}/prometheus-user-id"
type = "SecureString"
value = grafana_cloud_stack.this.prometheus_user_id
}
resource "aws_ssm_parameter" "otlp_endpoint" {
count = var.create_write_only_token ? 1 : 0
provider = aws.route53
name = "/grafana-cloud/${var.slug}/otlp-endpoint"
type = "String"
value = "${grafana_cloud_stack.this.otlp_url}/otlp"
}
resource "aws_ssm_parameter" "otlp_user_name" {
count = var.create_write_only_token ? 1 : 0
provider = aws.route53
name = "/grafana-cloud/${var.slug}/otlp-user-name"
type = "String"
value = grafana_cloud_stack.this.id
}
resource "grafana_sso_settings" "this" {
count = var.enable_sso_saml ? 1 : 0
provider = grafana.stack
provider_name = "saml"
saml_settings {
name = "SAML"
allow_sign_up = true
single_logout = true
certificate = var.sso_saml_certificate
private_key = var.sso_saml_private_key
signature_algorithm = "rsa-sha256"
idp_metadata_url = var.sso_saml_idp_metadata_url
assertion_attribute_name = "displayname"
assertion_attribute_login = "email"
assertion_attribute_email = "email"
assertion_attribute_groups = "groups"
assertion_attribute_role = var.sso_saml_assertion_attribute_role
role_values_admin = var.sso_saml_role_values_admin # "Admin"
role_values_editor = var.sso_saml_role_values_editor # "Editor"
role_values_viewer = var.sso_saml_role_values_viewer # "Viewer"
name_id_format = "urn:oasis:names:tc:SAML:1.1:nameid-format:emailAddress"
enabled = true
max_issue_delay = "90s"
metadata_valid_duration = "48h"
}
}