-
Notifications
You must be signed in to change notification settings - Fork 3k
/
httpc.erl
1575 lines (1423 loc) · 54.4 KB
/
httpc.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%
%% %CopyrightBegin%
%%
%% Copyright Ericsson AB 2009-2023. All Rights Reserved.
%%
%% Licensed under the Apache License, Version 2.0 (the "License");
%% you may not use this file except in compliance with the License.
%% You may obtain a copy of the License at
%%
%% http://www.apache.org/licenses/LICENSE-2.0
%%
%% Unless required by applicable law or agreed to in writing, software
%% distributed under the License is distributed on an "AS IS" BASIS,
%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
%% See the License for the specific language governing permissions and
%% limitations under the License.
%%
%% %CopyrightEnd%
%%
%%
%% Description:
%%% This version of the HTTP/1.1 client supports:
%%% - RFC 2616 HTTP 1.1 client part
%%% - RFC 2818 HTTP Over TLS
-module(httpc).
-behaviour(inets_service).
%% API
-export([
request/1, request/2, request/4, request/5,
cancel_request/1, cancel_request/2,
set_option/2, set_option/3,
set_options/1, set_options/2,
get_option/1, get_option/2,
get_options/1, get_options/2,
store_cookies/2, store_cookies/3,
cookie_header/1, cookie_header/2, cookie_header/3,
which_cookies/0, which_cookies/1,
reset_cookies/0, reset_cookies/1,
which_sessions/0, which_sessions/1,
stream_next/1,
default_profile/0,
profile_name/1, profile_name/2,
ssl_verify_host_options/1,
info/0, info/1
]).
%% Behavior callbacks
-export([start_standalone/1, start_service/1,
stop_service/1,
services/0, service_info/1]).
-include_lib("inets/src/http_lib/http_internal.hrl").
-include("httpc_internal.hrl").
-define(DEFAULT_PROFILE, default).
%%%=========================================================================
%%% API
%%%=========================================================================
default_profile() ->
?DEFAULT_PROFILE.
-spec profile_name(pid()) -> pid();
(atom()) -> pid() | atom().
profile_name(?DEFAULT_PROFILE) ->
httpc_manager;
profile_name(Profile) when is_pid(Profile) ->
Profile;
profile_name(Profile) ->
Prefix = lists:flatten(io_lib:format("~w_", [?MODULE])),
profile_name(Prefix, Profile).
profile_name(Prefix, Profile) when is_atom(Profile) ->
list_to_atom(Prefix ++ atom_to_list(Profile));
profile_name(_Prefix, Profile) when is_pid(Profile) ->
Profile.
-spec request(uri_string:uri_string()) -> {ok, Result} | {error, term()} when
Result :: {StatusLine :: { HttpVersion, StatusCode, string()}
, [HttpHeader]
, HttpBodyResult}
| { StatusCode
, HttpBodyResult}
| RequestId
| saved_to_file,
HttpBodyResult :: uri_string:uri_string() | binary(),
HttpVersion :: uri_string:uri_string(),
StatusCode :: non_neg_integer(),
HttpHeader :: { Field :: [byte()]
, Value :: binary() | iolist()},
RequestId :: any().
request(Url) ->
request(Url, default_profile()).
-spec request(Url, Profile) -> {ok, Result} | {error, term()} when
Url :: uri_string:uri_string(),
Profile :: atom() | pid(),
Result ::{ StatusLine, [HttpHeader], HttpBodyResult}
| { StatusCode, HttpBodyResult}
| RequestId
| saved_to_file,
HttpHeader :: { Field :: [byte()]
, Value :: binary() | iolist()},
HttpBodyResult :: uri_string:uri_string() | binary(),
StatusLine :: { HttpVersion
, StatusCode
, string()},
HttpVersion :: uri_string:uri_string(),
StatusCode :: non_neg_integer(),
RequestId :: any().
request(Url, Profile) ->
request(get, {Url, []}, [], [], Profile).
%% @doc Sends a HTTP-request. The function can be both synchronous and
%% asynchronous in the later case the function will return `{ok, RequestId}'
%% and later on a message will be sent to the
%% calling process on the format {http, {RequestId, {StatusLine,
%% Headers, Body}}} or {http, {RequestId, {error, Reason}}}.
%% Only octects are accepted in header fields and values.
-spec request(Method, Request, HttpOptions, Options) -> {ok, Result} | {error, term()} when
Method :: head | get | put | patch | post | trace | options | delete,
Request :: { uri_string:uri_string()
, [HttpHeader] }
| { uri_string:uri_string()
, [ HttpHeader ]
, ContentType::uri_string:uri_string()
, HttpBody},
HttpBody :: iolist()
| binary()
| { fun((Accumulator::term()) ->
eof | {ok, iolist(), Accumulator::term()}), Accumulator::term()}
| { chunkify
, fun((Accumulator::term()) ->
eof | {ok, iolist(), Accumulator::term()})
, Accumulator::term() },
HttpOptions :: [HttpOption],
HttpOption :: {timeout, timeout()}
| {connect_timeout, timeout()}
| {ssl, [ssl:tls_option()]}
| {autoredirect, boolean()}
| {proxy_auth, {string(), string()}}
| {version, HttpVersion} | {relaxed, boolean()},
Options :: [OptionRequest],
OptionRequest :: {sync, boolean()}
| {stream, StreamTo}
| {body_format, BodyFormat}
| {full_result, boolean()}
| {headers_as_is, boolean()}
| {socket_opts, [SocketOpt]}
| {receiver, Receiver}
| {ipv6_host_with_brackets, boolean()},
StreamTo :: none | self | {self, once} | file:name_all(),
SocketOpt :: term(),
BodyFormat :: string() | binary() | atom(),
Receiver :: pid()
| fun((term()) -> term())
| { ReceiverModule::atom()
, ReceiverFunction::atom()
, ReceiverArgs::list()},
Result :: { StatusLine , [HttpHeader], HttpBodyResult}
| { StatusCode, HttpBodyResult}
| RequestId
| saved_to_file,
StatusCode::non_neg_integer(),
StatusLine :: { HttpVersion
, StatusCode
, string()},
HttpVersion :: uri_string:uri_string(),
HttpHeader :: { Field :: [byte()]
, Value :: binary() | iolist()},
HttpBodyResult :: uri_string:uri_string() | binary(),
RequestId :: any().
request(Method, Request, HttpOptions, Options) ->
request(Method, Request, HttpOptions, Options, default_profile()).
-define(WITH_BODY, [post, put, patch, delete]).
-define(WITHOUT_BODY, [get, head, options, trace, put, delete]).
-spec request(Method, Request, HttpOptions, Options, Profile) -> {ok, Result} | {error, term()} when
Method :: head | get | put | patch | post | trace | options | delete,
Request :: { uri_string:uri_string()
, [HttpHeader] }
| { uri_string:uri_string()
, [ HttpHeader ]
, ContentType::uri_string:uri_string()
, HttpBody},
HttpBody :: iolist()
| binary()
| { fun((Accumulator::term()) ->
eof | {ok, iolist(), Accumulator::term()}), Accumulator::term()}
| { chunkify
, fun((Accumulator::term()) ->
eof | {ok, iolist(), Accumulator::term()})
, Accumulator::term() },
HttpHeader :: { Field :: [byte()]
, Value :: binary() | iolist()},
HttpOptions :: [HttpOption],
HttpOption :: {timeout, timeout()}
| {connect_timeout, timeout()}
| {ssl, [ssl:tls_option()]}
| {autoredirect, boolean()}
| {proxy_auth, {string(), string()}}
| {version, HttpVersion} | {relaxed, boolean()},
Options :: [OptionRequest],
OptionRequest :: {sync, boolean()}
| {stream, StreamTo}
| {body_format, BodyFormat}
| {full_result, boolean()}
| {headers_as_is, boolean()}
| {socket_opts, [SocketOpt]}
| {receiver, Receiver}
| {ipv6_host_with_brackets, boolean()},
StreamTo :: none | self | {self, once} | file:name_all(),
BodyFormat :: string() | binary() | atom(),
SocketOpt :: term(),
Receiver :: pid()
| fun((term()) -> term())
| { ReceiverModule::atom()
, ReceiverFunction::atom()
, ReceiverArgs::list()},
Profile :: atom() | pid(),
HttpVersion :: uri_string:uri_string(),
Result :: {StatusLine
, [HttpHeader]
, HttpBodyResult}
| { StatusCode
, HttpBodyResult}
| RequestId
| saved_to_file,
StatusLine :: { HttpVersion, StatusCode, string()},
StatusCode :: non_neg_integer(),
HttpBodyResult :: uri_string:uri_string() | binary(),
RequestId :: any().
request(Method, Request, HTTPOptions, Options, Profile)
when is_atom(Profile) orelse is_pid(Profile) ->
WithBody = lists:member(Method, ?WITH_BODY),
WithoutBody = lists:member(Method, ?WITHOUT_BODY),
case check_request(WithBody, WithoutBody, Request) of
ok ->
do_request(Method, Request,
HTTPOptions, Options, Profile);
{error, _} = Error ->
Error
end.
do_request(Method, {Url, Headers}, HTTPOptions, Options, Profile) ->
do_request(Method, {Url, Headers, [], []}, HTTPOptions, Options, Profile);
do_request(Method, {Url, Headers, ContentType, Body}, HTTPOptions, Options, Profile) ->
case normalize_and_parse_url(Url) of
{error, Reason, _} ->
{error, Reason};
ParsedUrl ->
case header_parse(Headers) of
{error, Reason} ->
{error, Reason};
ok ->
handle_request(Method, Url,
ParsedUrl, Headers, ContentType, Body,
HTTPOptions, Options, Profile)
end
end.
%% Check combination of method and presence of body
check_request(false, false, _Request) ->
{error, invalid_method};
check_request(_, true, {_URL, _Headers}) ->
ok;
check_request(true, _, {_URL, _Headers, ContentType, Body})
when is_list(ContentType)
andalso (is_list(Body) orelse is_binary(Body)) ->
ok;
check_request(true, _, {_URL, _Headers, ContentType, Body})
when is_list(ContentType) andalso is_tuple(Body) ->
check_body_gen(Body);
check_request(_, _, _Request) ->
{error, invalid_request}.
%%
%% @doc Description: Cancels a HTTP-request.
%%
-spec cancel_request(RequestId) -> ok when
RequestId :: any().
cancel_request(RequestId) ->
cancel_request(RequestId, default_profile()).
%%
%% @doc Cancels an asynchronous HTTP request. Notice that this does not
%% guarantee that the request response is not delivered. Because it is
%% asynchronous, the request can already have been completed when the
%% cancellation arrives.
%%
-spec cancel_request(RequestId, Profile) -> ok when
RequestId :: any(),
Profile :: atom() | pid().
cancel_request(RequestId, Profile)
when is_atom(Profile) orelse is_pid(Profile) ->
httpc_manager:cancel_request(RequestId, profile_name(Profile)).
%% @doc Sets options to be used for subsequent requests.
%% @see set_options/2. Informs the httpc_manager of the new settings.
-spec set_options(Options) -> ok | {error, Reason} when
Options :: [Option],
Option :: {proxy, {Proxy, NoProxy}}
| {https_proxy, {Proxy, NoProxy}}
| {max_sessions, MaxSessions}
| {max_keep_alive_length, MaxKeepAlive}
| {keep_alive_timeout, KeepAliveTimeout}
| {max_pipeline_length, MaxPipeline}
| {pipeline_timeout, PipelineTimeout}
| {cookies, CookieMode}
| {ipfamily, IpFamily}
| {ip, IpAddress}
| {port, Port}
| {socket_opts, SocketOpts}
| {verbose, VerboseMode}
| {unix_socket, UnixSocket},
Proxy :: {HostName, Port},
Port :: non_neg_integer(),
NoProxy :: [DomainDesc | HostName | IpAddressDesc],
MaxSessions :: integer(),
MaxKeepAlive :: integer(),
KeepAliveTimeout :: integer(),
MaxPipeline :: integer(),
PipelineTimeout :: integer(),
CookieMode :: enabled | disabled | verify,
IpFamily :: inet | inet6 | local | inet6fb4,
IpAddressDesc :: uri_string:uri_string(),
IpAddress :: inet:ip_address(),
VerboseMode :: false | verbose | debug | trace,
SocketOpts :: [SocketOpt],
SocketOpt :: term(),
UnixSocket :: file:name_all(),
Reason :: term(),
DomainDesc :: string(),
HostName :: uri_string:uri_string().
set_options(Options) ->
set_options(Options, default_profile()).
%% @doc Sets options to be used for subsequent requests.
-spec set_options(Options, Profile) -> ok | {error, Reason} when
Options :: [Option],
Option :: {proxy, {Proxy, NoProxy}}
| {https_proxy, {Proxy, NoProxy}}
| {max_sessions, MaxSessions}
| {max_keep_alive_length, MaxKeepAlive}
| {keep_alive_timeout, KeepAliveTimeout}
| {max_pipeline_length, MaxPipeline}
| {pipeline_timeout, PipelineTimeout}
| {cookies, CookieMode}
| {ipfamily, IpFamily}
| {ip, IpAddress}
| {port, Port}
| {socket_opts, [SocketOpt]}
| {verbose, VerboseMode}
| {unix_socket, UnixSocket},
Profile :: atom() | pid(),
SocketOpt :: term(),
Proxy :: {HostName, Port},
Port :: non_neg_integer(),
NoProxy :: [DomainDesc | HostName | IpAddressDesc],
MaxSessions :: integer(),
MaxKeepAlive :: integer(),
KeepAliveTimeout :: integer(),
MaxPipeline :: integer(),
PipelineTimeout :: integer(),
CookieMode :: enabled | disabled | verify,
IpFamily :: inet | inet6 | local | inet6fb4,
IpAddressDesc :: uri_string:uri_string(),
IpAddress :: inet:ip_address(),
VerboseMode :: false | verbose | debug | trace,
UnixSocket :: string(),
Reason :: term(),
DomainDesc :: string(),
HostName :: uri_string:uri_string().
set_options(Options, Profile) when is_atom(Profile) orelse is_pid(Profile) ->
case validate_options(Options) of
{ok, Opts} ->
httpc_manager:set_options(Opts, profile_name(Profile));
{error, Reason} ->
{error, Reason}
end.
-spec set_option(atom(), term()) -> ok | {error, term()}.
set_option(Key, Value) ->
set_option(Key, Value, default_profile()).
-spec set_option(atom(), term(), atom()) -> ok | {error, term()}.
set_option(Key, Value, Profile) ->
set_options([{Key, Value}], Profile).
-spec get_options() -> term().
get_options() ->
record_info(fields, options).
%%
%% @doc Retrieves the options currently used by the client.
%%
-spec get_options(OptionItems) -> {ok, Values} | {error, Reason} when
OptionItems :: all | [OptionItem],
OptionItem :: proxy | https_proxy | max_sessions | keep_alive_timeout
| max_keep_alive_length | pipeline_timeout | max_pipeline_length | cookies
| ipfamily | ip | port | socket_opts | verbose | unix_socket,
Values :: [{OptionItem, term()}],
Reason :: term().
get_options(Options) ->
get_options(Options, default_profile()).
%%
%% @doc Retrieves the options currently used by the client.
%%
-spec get_options(OptionItems, Profile) -> {ok, Values} | {error, Reason} when
OptionItems :: all | [OptionItem],
OptionItem :: proxy | https_proxy | max_sessions | keep_alive_timeout
| max_keep_alive_length | pipeline_timeout | max_pipeline_length | cookies
| ipfamily | ip | port | socket_opts | verbose | unix_socket,
Values :: [{OptionItem, term()}],
Profile :: atom() | pid(),
Reason :: term().
get_options(all = _Options, Profile) ->
get_options(get_options(), Profile);
get_options(Options, Profile)
when (is_list(Options) andalso
(is_atom(Profile) orelse is_pid(Profile))) ->
case Options -- get_options() of
[] ->
try
begin
{ok, httpc_manager:get_options(Options,
profile_name(Profile))}
end
catch
exit:{noproc, _} ->
{error, inets_not_started}
end;
InvalidGetOptions ->
{error, {invalid_options, InvalidGetOptions}}
end.
get_option(Key) ->
get_option(Key, default_profile()).
get_option(Key, Profile) ->
case get_options([Key], Profile) of
{ok, [{Key, Value}]} ->
{ok, Value};
Error ->
Error
end.
%%--------------------------------------------------------------------------
%% Default client ssl options to verify server
%%
%% WildcardHostName=true does wildcard matching on the hostname check
%%--------------------------------------------------------------------------
-spec ssl_verify_host_options(WildcardHostName) -> list() when
WildcardHostName :: boolean().
ssl_verify_host_options(WildcardHostName) ->
WildCard = case WildcardHostName of
true ->
Fun = public_key:pkix_verify_hostname_match_fun(https),
[{customize_hostname_check,[{match_fun, Fun}]}];
false ->
[]
end,
[{verify, verify_peer}, {cacerts, public_key:cacerts_get()} | WildCard].
-spec store_cookies(SetCookieHeaders, Url) -> ok | {error, Reason} when
SetCookieHeaders :: [HttpHeader],
HttpHeader :: { Field :: [byte()], Value :: binary() | iolist()},
Url :: term(),
Reason :: term().
store_cookies(SetCookieHeaders, Url) ->
store_cookies(SetCookieHeaders, Url, default_profile()).
%%
%% @doc Saves the cookies defined in `SetCookieHeaders; in the client profile
%% cookie database. Call this function if option `cookies' is set to `verify'. If no
%% profile is specified, the default profile is used.
-spec store_cookies(SetCookieHeaders, Url, Profile) -> ok | {error, Reason} when
SetCookieHeaders :: [HttpHeader],
HttpHeader :: { Field :: [byte()], Value :: binary() | iolist()},
Url :: term(),
Profile :: atom() | pid(),
Reason :: term().
store_cookies(SetCookieHeaders, Url, Profile)
when is_atom(Profile) orelse is_pid(Profile) ->
case normalize_and_parse_url(Url) of
{error, Bad, _} ->
{error, {parse_failed, Bad}};
URI ->
Scheme = scheme_to_atom(maps:get(scheme, URI, undefined)),
Host = maps:get(host, URI, ""),
Port = maps:get(port, URI, default_port(Scheme)),
Path = uri_string:recompose(#{path => maps:get(path, URI, "")}),
%% Since the Address part is not actually used
%% by the manager when storing cookies, we dont
%% care about ipv6-host-with-brackets.
Address = {Host, Port},
ProfileName = profile_name(Profile),
Cookies = httpc_cookie:cookies(SetCookieHeaders, Path, Host),
httpc_manager:store_cookies(Cookies, Address, ProfileName),
ok
end.
default_port(http) ->
80;
default_port(https) ->
443.
-spec cookie_header(Url) -> HttpHeader | {error, Reason} when
Url :: uri_string:uri_string(),
HttpHeader :: { Field :: [byte()], Value :: binary() | iolist()},
Reason :: term().
cookie_header(Url) ->
cookie_header(Url, default_profile()).
-spec cookie_header(Url, ProfileOrOpts) -> HttpHeader | {error, Reason} when
Url :: uri_string:uri_string(),
HttpHeader :: { Field :: [byte()], Value :: binary() | iolist()},
ProfileOrOpts :: Profile | Opts,
Profile :: atom() | pid(),
Opts :: [CookieHeaderOpt],
CookieHeaderOpt :: {ipv6_host_with_brackets, boolean()},
Reason :: term().
cookie_header(Url, Profile) when is_atom(Profile) orelse is_pid(Profile) ->
cookie_header(Url, [], Profile);
cookie_header(Url, Opts) when is_list(Opts) ->
cookie_header(Url, Opts, default_profile()).
%%
%% @doc Returns the cookie header that would have been sent when making a
%% request to Url using profile Profile. If no profile is specified, the default
%% profile is used.
%%
-spec cookie_header(Url, Opts, Profile) -> HttpHeader | {error, Reason} when
Url :: uri_string:uri_string(),
HttpHeader :: { Field :: [byte()], Value :: binary() | iolist()},
Profile :: atom() | pid(),
Opts :: [CookieHeaderOpt],
CookieHeaderOpt :: {ipv6_host_with_brackets, boolean()},
Reason :: term().
cookie_header(Url, Opts, Profile)
when (is_list(Opts) andalso (is_atom(Profile) orelse is_pid(Profile))) ->
try
begin
httpc_manager:which_cookies(Url, Opts, profile_name(Profile))
end
catch
exit:{noproc, _} ->
{error, {not_started, Profile}}
end.
-spec which_cookies() -> [CookieStores] when
CookieStores :: {cookies, Cookies} | {session_cookies, Cookies},
Cookies :: [term()].
which_cookies() ->
which_cookies(default_profile()).
%%
%% @doc Produces a list of the entire cookie database. Intended for
%% debugging/testing purposes. If no profile is specified, the default profile
%% is used.
%%
-spec which_cookies(Profile) -> [CookieStores] when
Profile :: atom() | pid(),
CookieStores :: {cookies, Cookies} | {session_cookies, Cookies},
Cookies :: [term()].
which_cookies(Profile) ->
?hcrt("which cookies", [{profile, Profile}]),
try
begin
httpc_manager:which_cookies(profile_name(Profile))
end
catch
exit:{noproc, _} ->
{error, {not_started, Profile}}
end.
-spec which_sessions() -> SessionInfo when
SessionInfo :: {GoodSession, BadSessions, NonSessions},
GoodSession :: [Session],
BadSessions :: [term()],
NonSessions :: [term()],
Session :: term().
which_sessions() ->
which_sessions(default_profile()).
%%
%% @doc This function is intended for debugging only. It produces a slightly
%% processed dump of the session database. The first list of the session
%% information tuple will contain session information on an internal format. The
%% last two lists of the session information tuple should always be empty if the
%% code is working as intended. If no profile is specified, the default profile
%% is used. The dumped sessions database is sorted into three groups
%% (Good-, Bad- and Non-sessions).
%%
-spec which_sessions(Profile) -> SessionInfo when
Profile :: atom() | pid(),
SessionInfo :: {GoodSession, BadSessions, NonSessions},
GoodSession :: [Session],
BadSessions :: [term()],
NonSessions :: [term()],
Session :: term().
which_sessions(Profile) ->
try
begin
httpc_manager:which_sessions(profile_name(Profile))
end
catch
exit:{noproc, _} ->
{[], [], []}
end.
%%
%% @doc Produces a list of miscellaneous information. Intended for debugging. If
%% no profile is specified, the default profile is used.
%%
-spec info() -> list() | {error, Reason} when
Reason :: term().
info() ->
info(default_profile()).
%%
%% @doc Produces a list of miscellaneous information. Intended for debugging. If
%% no profile is specified, the default profile is used.
%%
-spec info(Profile) -> list() | {error, Reason} when
Reason :: term(),
Profile :: atom() | pid().
info(Profile) ->
try
begin
httpc_manager:info(profile_name(Profile))
end
catch
exit:{noproc, _} ->
{error, {not_started, Profile}}
end.
%%
%% @doc Debug function. Resets (clears) the cookie database for the default profile
%%
-spec reset_cookies() -> Void when
Void :: term().
reset_cookies() ->
reset_cookies(default_profile()).
%%
%% @doc Debug function. Resets (clears) the cookie database for the specified
%% `Profile'. If no profile is specified the default profile is used.
%%
-spec reset_cookies(Profile) -> Void when
Profile :: atom() | pid(),
Void :: term().
reset_cookies(Profile) ->
try
begin
httpc_manager:reset_cookies(profile_name(Profile))
end
catch
exit:{noproc, _} ->
{error, {not_started, Profile}}
end.
%%
%% @doc Triggers the next message to be streamed, that is, the same behavior as
%% active ones for sockets.
%%
-spec stream_next(Pid) -> ok when
Pid :: pid().
stream_next(Pid) ->
httpc_handler:stream_next(Pid).
%%%========================================================================
%%% Behaviour callbacks
%%%========================================================================
start_standalone(PropList) ->
case proplists:get_value(profile, PropList) of
undefined ->
{error, no_profile};
Profile ->
Dir =
proplists:get_value(data_dir, PropList, only_session_cookies),
httpc_manager:start_link(Profile, Dir, stand_alone)
end.
start_service(Config) ->
httpc_profile_sup:start_child(Config).
stop_service(Profile) when is_atom(Profile) ->
httpc_profile_sup:stop_child(Profile);
stop_service(Pid) when is_pid(Pid) ->
case service_info(Pid) of
{ok, [{profile, Profile}]} ->
stop_service(Profile);
Error ->
Error
end.
services() ->
[{httpc, Pid} || {_, Pid, _, _} <-
supervisor:which_children(httpc_profile_sup)].
service_info(Pid) ->
try [{ChildName, ChildPid} ||
{ChildName, ChildPid, _, _} <-
supervisor:which_children(httpc_profile_sup)] of
Children ->
child_name2info(child_name(Pid, Children))
catch
exit:{noproc, _} ->
{error, service_not_available}
end.
%%%========================================================================
%%% Internal functions
%%%========================================================================
-spec normalize_and_parse_url(Characters) -> NormalizedURI when
Characters :: uri_string:uri_string(),
NormalizedURI :: uri_string:uri_string() | uri_string:uri_map()
| uri_string:error().
normalize_and_parse_url(Url) ->
uri_string:normalize(unicode:characters_to_list(Url), [return_map]).
handle_request(Method, Url,
URI,
Headers0, ContentType, Body0,
HTTPOptions0, Options0, Profile) ->
Started = http_util:timestamp(),
NewHeaders0 = [{http_util:to_lower(Key), Val} || {Key, Val} <- Headers0],
try
begin
{NewHeaders, Body} =
case Body0 of
{chunkify, ProcessBody, Acc}
when is_function(ProcessBody, 1) ->
NewHeaders1 = ensure_chunked_encoding(NewHeaders0),
Body1 = {mk_chunkify_fun(ProcessBody), Acc},
{NewHeaders1, Body1};
{ProcessBody, _}
when is_function(ProcessBody, 1) ->
{NewHeaders0, Body0};
_ when is_list(Body0) orelse is_binary(Body0) ->
{NewHeaders0, Body0};
_ ->
throw({error, {bad_body, Body0}})
end,
HTTPOptions = http_options(HTTPOptions0),
Options = request_options(Options0),
Sync = proplists:get_value(sync, Options),
Stream = proplists:get_value(stream, Options),
Receiver = proplists:get_value(receiver, Options),
SocketOpts = proplists:get_value(socket_opts, Options),
UnixSocket = proplists:get_value(unix_socket, Options),
BracketedHost = proplists:get_value(ipv6_host_with_brackets,
Options),
Scheme = scheme_to_atom(maps:get(scheme, URI, undefined)),
Userinfo = maps:get(userinfo, URI, ""),
Host = http_util:maybe_add_brackets(maps:get(host, URI, ""), BracketedHost),
Port = maps:get(port, URI, default_port(Scheme)),
Host2 = http_request:normalize_host(Scheme, Host, Port),
Path = uri_string:recompose(#{path => maps:get(path, URI, "")}),
Query = add_question_mark(maps:get(query, URI, "")),
HeadersRecord = header_record(NewHeaders, Host2, HTTPOptions),
Request = #request{from = Receiver,
scheme = Scheme,
address = {Host, Port},
path = Path,
pquery = Query,
method = Method,
headers = HeadersRecord,
content = {ContentType, Body},
settings = HTTPOptions,
abs_uri = Url,
userinfo = Userinfo,
stream = Stream,
headers_as_is = headers_as_is(Headers0, Options),
socket_opts = SocketOpts,
started = Started,
unix_socket = UnixSocket,
ipv6_host_with_brackets = BracketedHost},
case httpc_manager:request(Request, profile_name(Profile)) of
{ok, RequestId} ->
handle_answer(RequestId, Sync, Options);
{error, Reason} ->
{error, Reason}
end
end
catch
error:{noproc, _} ->
{error, {not_started, Profile}};
throw:Error ->
Error
end.
add_question_mark(<<>>) ->
<<>>;
add_question_mark([]) ->
[];
add_question_mark(Comp) when is_binary(Comp) ->
<<$?, Comp/binary>>;
add_question_mark(Comp) when is_list(Comp) ->
[$?|Comp].
scheme_to_atom("http") ->
http;
scheme_to_atom("https") ->
https;
scheme_to_atom(undefined) ->
throw({error, {no_scheme}});
scheme_to_atom(Scheme) ->
throw({error, {bad_scheme, Scheme}}).
ensure_chunked_encoding(Hdrs) ->
Key = "transfer-encoding",
lists:keystore(Key, 1, Hdrs, {Key, "chunked"}).
mk_chunkify_fun(ProcessBody) ->
fun(eof_body) ->
eof;
(Acc) ->
case ProcessBody(Acc) of
eof ->
{ok, <<"0\r\n\r\n">>, eof_body};
{ok, Data, NewAcc} ->
Chunk = [
integer_to_list(iolist_size(Data), 16),
"\r\n",
Data,
"\r\n"],
{ok, Chunk, NewAcc}
end
end.
handle_answer(RequestId, false, _) ->
{ok, RequestId};
handle_answer(RequestId, true, Options) ->
receive
{http, {RequestId, saved_to_file}} ->
{ok, saved_to_file};
{http, {RequestId, {_,_,_} = Result}} ->
return_answer(Options, Result);
{http, {RequestId, {error, Reason}}} ->
{error, Reason}
end.
return_answer(Options, {StatusLine, Headers, BinBody}) ->
Body = maybe_format_body(BinBody, Options),
case proplists:get_value(full_result, Options, true) of
true ->
{ok, {StatusLine, Headers, Body}};
false ->
{_, Status, _} = StatusLine,
{ok, {Status, Body}}
end.
maybe_format_body(BinBody, Options) ->
case proplists:get_value(body_format, Options, string) of
string ->
binary_to_list(BinBody);
_ ->
BinBody
end.
-spec headers_as_is(HeaderRequest, OptionsRequest) -> HeaderRequest when
HeaderRequest :: [{list(), list() | binary()}] | [tuple()],
OptionsRequest :: [OptionRequest],
OptionRequest :: {sync, boolean()}
| {stream, StreamTo}
| {body_format, BodyFormat}
| {full_result, boolean()}
| {headers_as_is, boolean()}
| {socket_opts, [SocketOpt]}
| {receiver, Receiver}
| {ipv6_host_with_brackets, boolean()},
BodyFormat :: string() | binary() | atom(),
StreamTo :: none | self | {self, once} | file:name_all(),
SocketOpt :: term(),
Receiver :: pid()
| fun((term()) -> term())
| { ReceiverModule::atom()
, ReceiverFunction::atom()
, ReceiverArgs::list()}.
%% This options is a workaround for http servers that do not follow the
%% http standard and have case sensitive header parsing. Should only be
%% used if there is no other way to communicate with the server or for
%% testing purpose.
headers_as_is(Headers, Options) ->
case proplists:get_value(headers_as_is, Options, false) of
false ->
[];
true ->
Headers
end.
http_options(HttpOptions) ->
HttpOptionsDefault = http_options_default(),
http_options(HttpOptionsDefault, HttpOptions, #http_options{}).
http_options([], [], Acc) ->
Acc;
http_options([], HttpOptions, Acc) ->
Fun = fun(BadOption) ->
Report = io_lib:format("Invalid option ~p ignored ~n",
[BadOption]),
error_logger:info_report(Report)
end,
lists:foreach(Fun, HttpOptions),
Acc;
http_options([{Tag, Default, Idx, Post} | Defaults], HttpOptions, Acc) ->
case lists:keysearch(Tag, 1, HttpOptions) of
{value, {Tag, Val0}} ->
case Post(Val0) of
{ok, Val} ->
Acc2 = setelement(Idx, Acc, Val),
HttpOptions2 = lists:keydelete(Tag, 1, HttpOptions),
http_options(Defaults, HttpOptions2, Acc2);
error ->
Report = io_lib:format("Invalid option ~p:~p ignored ~n",
[Tag, Val0]),
error_logger:info_report(Report),
HttpOptions2 = lists:keydelete(Tag, 1, HttpOptions),
http_options(Defaults, HttpOptions2, Acc)
end;
false ->
DefaultVal =
case Default of
{value, Val} ->
Val;
{value_lazy, ValFn} ->
ValFn();
{field, DefaultIdx} ->
element(DefaultIdx, Acc)
end,
Acc2 = setelement(Idx, Acc, DefaultVal),
http_options(Defaults, HttpOptions, Acc2)
end.
http_options_default() ->
VersionPost =
fun(Value) when is_atom(Value) ->
{ok, http_util:to_upper(atom_to_list(Value))};
(Value) when is_list(Value) ->
{ok, http_util:to_upper(Value)};
(_) ->
error
end,
TimeoutPost = fun(Value) when is_integer(Value) andalso (Value >= 0) ->
{ok, Value};
(infinity = Value) ->
{ok, Value};
(_) ->
error
end,
AutoRedirectPost = boolfun(),
SslPost = fun(Value) when is_list(Value) ->
{ok, {ssl, Value}};
({ssl, SslOptions}) when is_list(SslOptions) ->
{ok, {ssl, SslOptions}};
%% backwards compat
({essl, SslOptions}) when is_list(SslOptions) ->
{ok, {ssl, SslOptions}};
(_) ->
error
end,
ProxyAuthPost = fun({User, Passwd} = Value) when is_list(User) andalso
is_list(Passwd) ->
{ok, Value};
(_) ->