build.gradle

buildscript {
    ext {
        KOTLIN_VERSION = "1.2.61"
    }

    repositories {
        jcenter()
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${KOTLIN_VERSION}"
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.20.0'
    }
}

apply plugin: "kotlin"
apply plugin: "application"
apply plugin: "com.github.ben-manes.versions"

mainClassName = "org.ethereum.lists.tokens.MainKt"

repositories {
    jcenter()
    maven { url 'https://jitpack.io' }
    maven { url "https://kotlin.bintray.com/kotlinx" }
}

task correctFileNames(type: JavaExec) {
    main = "org.ethereum.lists.tokens.CorrectFileNamesKt"
    classpath = sourceSets.main.runtimeClasspath
}

task correctDecimals(type: JavaExec) {
    main = "org.ethereum.lists.tokens.CorrectDecimalsKt"
    classpath = sourceSets.main.runtimeClasspath
}

task importMEW(type: JavaExec) {
    main = "org.ethereum.lists.tokens.ImportKt"
    classpath = sourceSets.main.runtimeClasspath
    if (project.hasProperty("importPath")) {
        args importPath
    }
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib:${KOTLIN_VERSION}"
    compile "com.github.ethereum-lists:cilib:0.2"
    compile "com.github.walleth.kethereum:erc55:0.59"
    compile 'com.beust:klaxon:3.0.8'
    compile 'com.squareup.moshi:moshi-kotlin:1.6.0'
}