Coded PHY w/ ESP32 & Arduino IDE

[mvrk2024]

Hello…I’ve managed to successfully migrate my ESP32 Arduino sketch (originally coded using the Kolban/Chegewara Arduino BLE library) to NimBLE-Arduino format. The sketch simply notifies a couple of volts/amps characteristic values on a one-second interval. I can currently connect the Android phone app I created to the ESP32 via BLE at up to ~ 24 meters. I’d like to try LE Coded (coded PHY) to see if I can extend this range. The XIAO ESP32S3 I’m using is capable of BLE 5.0 Long Range.

The first step I took was to un-comment the line ‘#define CONFIG_BT_NIMBLE_EXT_ADV 1’ in the nimconfig.h file. That produced the error: ‘Compilation error: 'NimBLEAdvertising' was not declared in this scope’. I then added the following commands but continued to get the same error. At this stage, I’m not sure how to proceed. I suspect the way BLE advertising functions are called in my sketch need to change with coded PHY, but I'm not sure how. Any guidance you could provide would be greatly appreciated! - Frank

#define CONFIG_BT_NIMBLE_EXT_ADV 1
NimBLEAdvertising* pAdvertising = NimBLEDevice::getAdvertising();
pAdvertising->addServiceUUID(SERVICE_UUID);
pAdvertising->setScanResponse(false);
pAdvertising->setAdvertisementType(BLE_HCI_ADV_TYPE_EXT_IND);
pAdvertising->setAdvertisementParameters(
BLE_HCI_ADV_PHY_CODED,
BLE_HCI_ADV_PHY_CODED);
NimBLEDevice::startAdvertising();
Serial.println("Start advertising...");

This is my sketch that functions properly at LE 1M advertising type:

#include <Adafruit_INA260.h>
#include <esp_sleep.h>
#include <NimBLEDevice.h>

Adafruit_INA260 ina260 = Adafruit_INA260();

NimBLEServer* pServer = NULL;
NimBLECharacteristic* pVoltsCharacteristic = NULL;
NimBLECharacteristic* pAmpsCharacteristic = NULL;
bool deviceConnected = false;
bool oldDeviceConnected = false;

#define SERVICE_UUID "4fafc201-1fb5-459e-8fcc-c5c9c331914b"
#define VOLTS_CHARACTERISTIC_UUID "7dd120c3-5d28-4264-88f9-f62233315f45"
#define AMPS_CHARACTERISTIC_UUID "3e37576d-9603-4637-b7b7-1d703e113268"

class MyServerCallbacks : public NimBLEServerCallbacks {
  void onConnect(NimBLEServer* pServer) {
    deviceConnected = true;
    Serial.println("Device connected");
  }

  void onDisconnect(NimBLEServer* pServer) {
    deviceConnected = false;
    Serial.println("Device disconnected");
  }
};

const uint64_t uS_TO_S_FACTOR = 1000000;  // Conversion factor for microseconds to seconds
const uint64_t TIME_TO_SLEEP = 60 * uS_TO_S_FACTOR;  // Time ESP32 will go to sleep (in microseconds)
const uint64_t TIME_TO_WAKE = 15 * uS_TO_S_FACTOR;   // Time ESP32 will stay awake (in microseconds)

void enterDeepSleep() {
  Serial.println("Going to sleep now");
  Serial.flush();  // Ensure all serial data is sent before sleeping
  
  // Deinitialize BLE
  NimBLEDevice::deinit(true);
  
  // Set wake up timer
  esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP);
  
  // Enter deep sleep
  esp_deep_sleep_start();
}

void setup() {
  Serial.begin(115200);
  ina260.begin();

  // Check if waking up from deep sleep
  if (esp_sleep_get_wakeup_cause() == ESP_SLEEP_WAKEUP_TIMER) {
    Serial.println("Woke up from deep sleep");
  } else {
    Serial.println("Normal boot");
  }

  // Initialize BLE
  NimBLEDevice::init("ESP32S3");

  // Set BLE power level
  NimBLEDevice::setPower(ESP_PWR_LVL_P9); // Set max power level: +9 dBm

  // Create the BLE Server
  pServer = NimBLEDevice::createServer();
  pServer->setCallbacks(new MyServerCallbacks());

  // Create the BLE Service
  NimBLEService* pService = pServer->createService(SERVICE_UUID);

  // Create BLE Characteristics
  pVoltsCharacteristic = pService->createCharacteristic(
    VOLTS_CHARACTERISTIC_UUID,
    NIMBLE_PROPERTY::READ | NIMBLE_PROPERTY::NOTIFY
  );
  pAmpsCharacteristic = pService->createCharacteristic(
    AMPS_CHARACTERISTIC_UUID,
    NIMBLE_PROPERTY::READ | NIMBLE_PROPERTY::NOTIFY
  );

  // Start the service
  pService->start();

  // Start advertising
  NimBLEAdvertising* pAdvertising = NimBLEDevice::getAdvertising();
  pAdvertising->addServiceUUID(SERVICE_UUID);
  pAdvertising->setScanResponse(false);
  NimBLEDevice::startAdvertising();
  Serial.println("Start advertising...");
}

void loop() {
  static uint64_t sleep_start_time = esp_timer_get_time();

  // notify changed value
  float voltsValue = (ina260.readBusVoltage() / 1000);
  float ampsValue = (ina260.readCurrent() / 1000);
  Serial.println(voltsValue, 3);
  Serial.println(ampsValue, 3);

  if (deviceConnected) {
    pVoltsCharacteristic->setValue(voltsValue);
    pVoltsCharacteristic->notify();
    pAmpsCharacteristic->setValue(ampsValue);
    pAmpsCharacteristic->notify();
    delay(1000);  // Avoid BLE congestion
  }

  // disconnecting
  if (!deviceConnected && oldDeviceConnected) {
    delay(500);                   // Give the Bluetooth stack the chance to get things ready
    pServer->startAdvertising();  // Restart advertising
    Serial.println("Start advertising...");
    oldDeviceConnected = deviceConnected;
  }

  // connecting
  if (deviceConnected && !oldDeviceConnected) {
    // do stuff here on connecting
    oldDeviceConnected = deviceConnected;
  }

  // Check if it's time to go to sleep
  if (esp_timer_get_time() - sleep_start_time >= TIME_TO_WAKE) {
    enterDeepSleep();
  }
}

[h2zero]

When extended advertisements are enable you must use a different class, NimBLEExtAdvertisement. Check the BT5 examples to see this.