build.gradle

import com.github.jk1.license.render.TextReportRenderer

plugins {
    id 'com.github.jk1.dependency-license-report' version '2.0'
    id "org.cyclonedx.bom" version "1.5.0"
}

licenseReport {
    outputDir = "$projectDir/build/licenses"

    renderers = [new TextReportRenderer("../../THIRD-PARTY-LICENSES.txt")]
}

allprojects {

    repositories {
        mavenCentral()
        maven {
            name 'Nexus@NT'
            url "https://repository.novatec-gmbh.de/content/repositories/3rd_party_libs/"
        }
    }

    apply plugin: 'java'
    apply plugin: 'jacoco'

    if (!project.hasProperty('buildVersion') || project.getProperty('buildVersion').empty) {
        ext.buildVersion = 'SNAPSHOT'
    }

    version = "$buildVersion"
}

cyclonedxBom {
    // includeConfigs is the list of configuration names to include when generating the BOM (leave empty to include every configuration)
    // includeConfigs += ["runtimeClasspath"]
    // skipConfigs is a list of configuration names to exclude when generating the BOM
    // skipConfigs += ["compileClasspath", "testCompileClasspath"]
}

task codeCoverageReport(type: JacocoReport) {
    group = 'Verification'
    description = 'Generates a combined report from all subprojects'

    executionData { fileTree(project.rootDir.absolutePath).include("**/build/jacoco/*.exec") }

    dependsOn(':inspectit-ocelot-agent:systemTest')
    dependsOn(':inspectit-ocelot-agent:test')
    dependsOn(':inspectit-ocelot-bootstrap:test')
    dependsOn(':inspectit-ocelot-config:test')
    dependsOn(':inspectit-ocelot-core:test')


    [project(':inspectit-ocelot-agent'), project(':inspectit-ocelot-bootstrap'), project(':inspectit-ocelot-config'), project(':inspectit-ocelot-core')].each {
        sourceSets it.sourceSets.main
    }

    reports {
        xml.enabled true
        xml.destination file("${buildDir}/reports/jacoco/report.xml")
        html.enabled true
        html.destination file("${buildDir}/reports/jacoco/html")
        csv.enabled false
    }
}