build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:5.1.0'
    }
}

apply plugin: 'com.github.johnrengelman.shadow'

wrapper {
    distributionType = Wrapper.DistributionType.ALL
}

allprojects {
    apply plugin: 'java'

    group = 'com.coinbase.exchange'
    description = 'Client for the Coinbase Pro API'
    version = '0.11.0'

    repositories {
        mavenCentral()
    }

    test {
        exclude '**/*IntegrationTest*'
    }

    /**
     * User can run these as optional against the sandbox api exchange
     **/
    task integrationTest(type: Test) {
        include '**/*IntegrationTest*'
    }
}

subprojects { }

// apply dependency constraints to all java modules
configure(subprojects.findAll { true }) {

    sourceCompatibility = 1.11
    targetCompatibility = 1.11

    dependencies {
        constraints {
            implementation 'com.fasterxml.jackson.core:jackson-core:2.11.0'
            implementation 'com.fasterxml.jackson.core:jackson-databind:2.11.0'
            implementation 'com.fasterxml.jackson.core:jackson-annotations:2.11.0'
            implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.11.0'
            implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.11.0'
            implementation 'org.slf4j:slf4j-api:1.7.28'
            implementation 'ch.qos.logback:logback-classic:1.2.3'
            implementation 'ch.qos.logback:logback-core:1.2.3'
            implementation 'org.springframework.boot:spring-boot-starter-web:2.2.7.RELEASE'
            implementation 'org.springframework:spring-context:5.2.6.RELEASE'

            // --------------------------------------
            testImplementation 'junit:junit:4.12'
            testImplementation 'org.junit.jupiter:junit-jupiter-api:5.5.2'
            testImplementation 'org.junit.jupiter:junit-jupiter-params:5.5.2'
            testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.5.2'
            testImplementation 'org.junit.platform:junit-platform-suite-api:1.3.2'

            testImplementation 'org.springframework.boot:spring-boot-test:2.2.7.RELEASE'
            testImplementation 'org.springframework.boot:spring-boot-starter-test:2.2.7.RELEASE'

            testImplementation 'org.mockito:mockito-core:3.0.0'
            testImplementation 'org.mockito:mockito-junit-jupiter:3.0.0'

            testImplementation 'org.assertj:assertj-core:3.13.2'
        }
    }
}

dependencies {
    compile project(":api")
    compile project(":model")
    compile project(":security")
    compile project(":websocketfeed")
}