Welcome to TM1637TinyDisplay Discussions!

[jasonacox]

👋 Welcome!

We’re using Discussions as a place to connect with other members of our community. We hope that you:

• Ask questions you’re wondering about.
• Share ideas, perhaps exploration of new features?
• Engage with other community members.
• Welcome others and are open-minded. Remember that this is a community we
  build together 💪.

[ROSW6341]

I have a TM1637 with a colon and 4 decimal dots. I would really like to be able to flip the digits and use the decimal point at the original far right as an AM indicator for a clock. Flipping the display works fine and can even blink the colon. However I've been unable to get any of the decimal dots to display using showNumberDec().
Is there a means to use showString() and/or showNumber() with decimal point to accomplish what I want?
Suggestions welcome.

[jasonacox]

Unfortunately, you have encountered a known hardware issue with the TM1637 modules. The TM1637 module makers hardwire it to only control the colon OR the decimals. It sounds like the module you have controls the colon only?

The reason for this limitation is that the TM1637 chip is designed to control 8 LEDs per segment. For a 7-segment LED digit, you are only left with 1-bit to control (the decimal or the colon) per digit.

You can see the 8 SEG lines and the 6 GRID (digits). That is why this chip is used for 4-digit and 6-digit displays. Technically they could use some of the GRID outputs to control more than the 8 LEDs on a typical 7-segment display, but I haven't found one yet.

If you find one that controls both, please do let me know so I can get some!

As a note, you can gain full control of the segment registers by using setSegments() and set the individual bit. Here is some code to turn on all available segments in a 4-digit display:

#include <TM1637TinyDisplay.h>

TM1637TinyDisplay display(CLK, DIO);
byte buf[4] = { 0b11111111, 0b11111111, 0b11111111, 0b11111111 };

void setup() { 
  display.begin();
  display.setBrightness(BRIGHT_7);
  display.setSegments(buf);
  delay(1000);
}

void loop() {
}

[FIKR3392]

i want to make running text display with two tm1637 4 digit module in series. because the text is long enaught so it hard to see it clearly. perhaps you could help me with that. thanks before.

[jasonacox]

Hi @FIKR3392 - You can definitely do that. However, you will need to write the code that sets up both displays and splits the text across both:

#include <TM1637TinyDisplay.h>

// Define the CLK and DIO pins for the displays
#define CLK_PIN1 2
#define DIO_PIN1 3
#define CLK_PIN2 4
#define DIO_PIN2 5

TM1637TinyDisplay display1(CLK_PIN1, DIO_PIN1);
TM1637TinyDisplay display2(CLK_PIN2, DIO_PIN2);

void setup() {
  // Initialize the displays
  display1.begin();
  display1.setBrightness(7);  // Set brightness (0-7)

  display2.begin();
  display2.setBrightness(7);  // Set brightness (0-7)
}

void loop() {
  char textToDisplay[] = "Hello12345"; // Change this to the desired text

  // Ensure the input string is not longer than 8 characters
  if (strlen(textToDisplay) > 8) {
    textToDisplay[8] = '\0'; // Truncate the string at 8 characters
  }

  // Split the input string into two parts
  char part1[5];
  char part2[5];
  strncpy(part1, textToDisplay, 4);
  part1[4] = '\0'; // Null-terminate the first part
  strcpy(part2, textToDisplay + 4);

  // Display the first part on the first display
  display1.showString(part1);

  // Display the second part on the second display
  display2.showString(part2);

  delay(2000); // Delay to keep the text displayed for a while
}

[FIKR3392]

thank you so much for your help.

[AndrewMcW]

Hi folks - I was wondering if anyone has an example using the showString_P function?

This is my test program:

// platformio
#include <Arduino.h>

// 6 digit display:
#include <TM1637TinyDisplay6.h>
// For ATTiny84 dev board, use PA0 as data and PA1 as clock for the display
#define DISP_CLK PIN_PA1
#define DISP_DIO PIN_PA0
#define DISP_BRIGHT 3

TM1637TinyDisplay6 display(DISP_CLK, DISP_DIO);

void setup() {

  display.begin();
  display.setBrightness(DISP_BRIGHT);

  const char msg_P[] PROGMEM = {"ABC123"};
  display.showString_P(msg_P);
  delay(1000);

  const char msg[] = {"DEF890"};
  display.showString(msg);
  delay(1000);

}


void loop() {
}

The result is a bunch of gibberish instead if "ABC123" (looks like it might be diagnostic info?), but the DEF890 displays fine.

Any advice greatly appreciated!

[jasonacox]

In the Arduino framework, PROGMEM is used to store data in program memory instead of RAM. When you use PROGMEM, you need to use special functions to access the data. For strings, you should use the F() or PSTR() macros to store and access them. You can also declare your PROGMEM string in the assignment with const PROGMEM char s[] = "something"

Sample from examples/TM1637-6Digit-Test/TM1637-6Digit-Test.ino

const PROGMEM char FlashString[] = "Flash Test - 1234567890";
const PROGMEM char FlashString2[] = "good";

// Test Strings in PROGMEM flash memory
display.showString_P(FlashString);
delay(1000);
display.showString_P(FlashString2);
delay(1000);

Another example from examples/ATtiny85/ATtiny85.ino

// Includes
#include <Arduino.h>
#include <TM1637TinyDisplay.h>
#include <avr/pgmspace.h>

// Define Digital Pins
#define CLK 4
#define DIO 5

// Initialize TM1637TinyDisplay
TM1637TinyDisplay display(CLK, DIO);

void setup() {
  display.begin();
}

void loop() {

  // Say Hello
  display.showString_P(PSTR("HELLO"));
  delay(500);
}

[AndrewMcW]

Thanks so much! Looks like my issue was that my declaration if msg_P has to be global - moving it so that it sits before setup() fixed the problem.

Cheers - Andrew

[AndrewMcW]

Please forgive me for asking - this might not be the right place - but when I first compile my project in VSS Code/PlatformIO, I get a couple of warnings in the compilation of the TM1637TinyDisplay.cpp. Short version of the warnings is:

lib\TM1637TinyDisplay\TM1637TinyDisplay6.cpp:32:0: warning: "labs" redefined

lib\TM1637TinyDisplay\TM1637TinyDisplay6.cpp:435:23: warning: comparison between signed and unsigned integer expressions [-Wsign-compare]

( Can post the full text if needed)
They cause no problems as far as I can tell but might be confusing for some...is it worth fixing? I'm happy to do so.
Cheers - Andrew

[jasonacox]

I would love to fix the warning @AndrewMcW ! Please, if you have time, submit a PR or at least an Issue to add to the TODO stack. Thanks for posting!

[AndrewMcW]

Issue submitted.
I'm a bit of a newbie with Github but I'll try to figure out how to do the pull request and fix the issue - is that ok?

[AndrewMcW]

I'm afraid I just can't figure out how to get a copy of the library in such a way that VSCode/PlatformIO doesn't throw up a bunch of spurious warnings - which makes it kind of difficult to have confidence in any changes!

Instead I edited the copy of the library as it appears in my project - this seems to have fixed the issues.

These are the changes I made:

1. The labs redefinition is resolved by simply surrounding with an #ifndef/#endif guard:

#ifndef labs
#define labs(x) ((x)>0?(x):-(x))
#endif

(This problem appears to have been introduced with change 815eb23 made on 2023-04-16.)

2. The signed unsigned comparison warnings can be resolved as follows
   (I'll refer to the TM1637TinyDisplay.cpp file only, as the 6-digit code is almost identical; obviously the same changes are needed there):

• line 432 becomes
  for (size_t x = 0; x < strlen(s); x++) {
• line 483 becomes
  for (size_t x = 0; x < strlen_P(s); x++) {
• line 614 and 625 both need a cast. (safe, as we've already checked that offset is non-neagtive)
  if (offset >= 0 && (unsigned int)offset < m_animation_frames - (2 * MAXDIGITS)) {

I don't know if putting these changes here helps in any way... As I said Iwould have done these myself if I could figure out how!

[jasonacox]

Thanks @AndrewMcW - I'll take a look. To be clear, the current code only throws warning in PlatformIO but otherwise it works?

[AndrewMcW]

Hi Jason,
I've only seen the warnings only come up in VSCode/PlatformIO during the first compile, or if I do a clean then build.
The Arduino IDE doesn't seem to care - no warnings come up there. (Tested with 1.8.15 and 2.2.1)
And yes - it all works fine, no problem at all. Thanks for all your hard work!