diff --git a/README.md b/README.md index e5cfe5a..0b5ceb2 100644 --- a/README.md +++ b/README.md @@ -1,2 +1,70 @@ # terraform-aws-sqs Terraform module which creates a sqs queue + + +## Requirements + +| Name | Version | +|------|---------| +| [terraform](#requirement\_terraform) | >= 1.3.0 | +| [aws](#requirement\_aws) | >= 4.67 | + +## Providers + +| Name | Version | +|------|---------| +| [aws](#provider\_aws) | >= 4.67 | + +## Modules + +| Name | Source | Version | +|------|--------|---------| +| [sqs](#module\_sqs) | terraform-aws-modules/sqs/aws | 4.0.1 | +| [this](#module\_this) | justtrackio/label/null | 0.26.0 | + +## Resources + +| Name | Type | +|------|------| +| [aws_cloudwatch_metric_alarm.backlog](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/cloudwatch_metric_alarm) | resource | +| [aws_sns_topic_subscription.default](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/sns_topic_subscription) | resource | +| [aws_iam_policy_document.subscription](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/data-sources/iam_policy_document) | data source | + +## Inputs + +| Name | Description | Type | Default | Required | +|------|-------------|------|---------|:--------:| +| [additional\_tag\_map](#input\_additional\_tag\_map) | Additional key-value pairs to add to each map in `tags_as_list_of_maps`. Not added to `tags` or `id`.
This is for some rare cases where resources want additional configuration of tags
and therefore take a list of maps with tag key, value, and additional configuration. | `map(string)` | `{}` | no | +| [alarm](#input\_alarm) | The details of the alarm such as datapoints to alarm, evaluation periods, backlog minutes, period, and threshold. | 
object({
    datapoints_to_alarm = optional(number, 3)
    description         = optional(string, null)
    evaluation_periods  = optional(number, 3)
    backlog_minutes     = optional(number, 3)
    period              = optional(number, 60)
    threshold           = optional(number, 0)
  })
| `{}` | no | +| [alarm\_enabled](#input\_alarm\_enabled) | Defines if the alarm should be created. | `bool` | `false` | no | +| [alarm\_topic\_arn](#input\_alarm\_topic\_arn) | The ARN of the SNS Topic used for notifying about alarm/ok messages. | `string` | `null` | no | +| [attributes](#input\_attributes) | ID element. Additional attributes (e.g. `workers` or `cluster`) to add to `id`,
in the order they appear in the list. New attributes are appended to the
end of the list. The elements of the list are joined by the `delimiter`
and treated as a single ID element. | `list(string)` | `[]` | no | +| [aws\_account\_id](#input\_aws\_account\_id) | AWS account id | `string` | `null` | no | +| [aws\_region](#input\_aws\_region) | AWS region | `string` | `null` | no | +| [context](#input\_context) | Single object for setting entire context at once.
See description of individual variables for details.
Leave string and numeric variables as `null` to use default value.
Individual variable settings (non-null) override settings in context object,
except for attributes, tags, and additional\_tag\_map, which are merged. | `any` | 
{
  "additional_tag_map": {},
  "attributes": [],
  "delimiter": null,
  "descriptor_formats": {},
  "enabled": true,
  "environment": null,
  "id_length_limit": null,
  "label_key_case": null,
  "label_order": [],
  "label_value_case": null,
  "labels_as_tags": [
    "unset"
  ],
  "name": null,
  "namespace": null,
  "regex_replace_chars": null,
  "stage": null,
  "tags": {},
  "tenant": null
}
| no | +| [delimiter](#input\_delimiter) | Delimiter to be used between ID elements.
Defaults to `-` (hyphen). Set to `""` to use no delimiter at all. | `string` | `null` | no | +| [descriptor\_formats](#input\_descriptor\_formats) | Describe additional descriptors to be output in the `descriptors` output map.
Map of maps. Keys are names of descriptors. Values are maps of the form
`{
format = string
labels = list(string)
}`
(Type is `any` so the map values can later be enhanced to provide additional options.)
`format` is a Terraform format string to be passed to the `format()` function.
`labels` is a list of labels, in order, to pass to `format()` function.
Label values will be normalized before being passed to `format()` so they will be
identical to how they appear in `id`.
Default is `{}` (`descriptors` output will be empty). | `any` | `{}` | no | +| [dlq\_enabled](#input\_dlq\_enabled) | Defines if Dead Letter Queue (DLQ) is enabled. | `bool` | `true` | no | +| [dlq\_max\_receive\_count](#input\_dlq\_max\_receive\_count) | The maximum number of times a message can be received from the DLQ before it's discarded. | `number` | `5` | no | +| [enabled](#input\_enabled) | Set to false to prevent the module from creating any resources | `bool` | `null` | no | +| [environment](#input\_environment) | ID element. Usually used for region e.g. 'uw2', 'us-west-2', OR role 'prod', 'staging', 'dev', 'UAT' | `string` | `null` | no | +| [id\_length\_limit](#input\_id\_length\_limit) | Limit `id` to this many characters (minimum 6).
Set to `0` for unlimited length.
Set to `null` for keep the existing setting, which defaults to `0`.
Does not affect `id_full`. | `number` | `null` | no | +| [label\_key\_case](#input\_label\_key\_case) | Controls the letter case of the `tags` keys (label names) for tags generated by this module.
Does not affect keys of tags passed in via the `tags` input.
Possible values: `lower`, `title`, `upper`.
Default value: `title`. | `string` | `null` | no | +| [label\_order](#input\_label\_order) | The order in which the labels (ID elements) appear in the `id`.
Defaults to ["namespace", "environment", "stage", "name", "attributes"].
You can omit any of the 6 labels ("tenant" is the 6th), but at least one must be present. | `list(string)` | `null` | no | +| [label\_value\_case](#input\_label\_value\_case) | Controls the letter case of ID elements (labels) as included in `id`,
set as tag values, and output by this module individually.
Does not affect values of tags passed in via the `tags` input.
Possible values: `lower`, `title`, `upper` and `none` (no transformation).
Set this to `title` and set `delimiter` to `""` to yield Pascal Case IDs.
Default value: `lower`. | `string` | `null` | no | +| [labels\_as\_tags](#input\_labels\_as\_tags) | Set of labels (ID elements) to include as tags in the `tags` output.
Default is to include all labels.
Tags with empty values will not be included in the `tags` output.
Set to `[]` to suppress all generated tags.
**Notes:**
The value of the `name` tag, if included, will be the `id`, not the `name`.
Unlike other `null-label` inputs, the initial setting of `labels_as_tags` cannot be
changed in later chained modules. Attempts to change it will be silently ignored. | `set(string)` | 
[
  "default"
]
| no | +| [name](#input\_name) | ID element. Usually the component or solution name, e.g. 'app' or 'jenkins'.
This is the only ID element not also included as a `tag`.
The "name" tag is set to the full `id` string. There is no tag with the value of the `name` input. | `string` | `null` | no | +| [namespace](#input\_namespace) | ID element. Usually an abbreviation of your organization name, e.g. 'eg' or 'cp', to help ensure generated IDs are globally unique | `string` | `null` | no | +| [organizational\_unit](#input\_organizational\_unit) | Usually used to indicate the AWS organizational unit, e.g. 'prod', 'sdlc' | `string` | `null` | no | +| [regex\_replace\_chars](#input\_regex\_replace\_chars) | Terraform regular expression (regex) string.
Characters matching the regex will be removed from the ID elements.
If not set, `"/[^a-zA-Z0-9-]/"` is used to remove all characters other than hyphens, letters and digits. | `string` | `null` | no | +| [stage](#input\_stage) | ID element. Usually used to indicate role, e.g. 'prod', 'staging', 'source', 'build', 'test', 'deploy', 'release' | `string` | `null` | no | +| [subscription](#input\_subscription) | The subscription details such as topic name and filter policy. | 
map(object({
    topic_name    = string
    filter_policy = optional(string)
  }))
| `{}` | no | +| [subscription\_aws\_account\_id](#input\_subscription\_aws\_account\_id) | The AWS account ID for the subscription. | `string` | `null` | no | +| [tags](#input\_tags) | Additional tags (e.g. `{'BusinessUnit': 'XYZ'}`).
Neither the tag keys nor the tag values will be modified by this module. | `map(string)` | `{}` | no | +| [tenant](#input\_tenant) | ID element \_(Rarely used, not included by default)\_. A customer identifier, indicating who this instance of a resource is for | `string` | `null` | no | +| [visibility\_timeout\_seconds](#input\_visibility\_timeout\_seconds) | The visibility timeout for the queue. An integer from 0 to 43200 (12 hours) | `number` | `null` | no | + +## Outputs + +No outputs. + diff --git a/cloudwatch.tf b/cloudwatch.tf new file mode 100644 index 0000000..903b636 --- /dev/null +++ b/cloudwatch.tf @@ -0,0 +1,90 @@ +locals { + alarm_description = var.alarm.description != null ? var.alarm.description : "SQS Queue Metrics: https://${module.this.aws_region}.console.aws.amazon.com/sqs/v2/home?region=${module.this.aws_region}#/queues/https%3A%2F%2Fsqs.${module.this.aws_region}.amazonaws.com%2F${module.this.aws_account_id}%2F${module.sqs.queue_name}" +} + +resource "aws_cloudwatch_metric_alarm" "backlog" { + count = module.this.enabled && var.alarm_enabled ? 1 : 0 + + alarm_description = jsonencode(merge({ + Severity = "warning" + Description = local.alarm_description + }, module.this.tags, module.this.additional_tag_map)) + alarm_name = "${module.sqs.queue_name}-backlog" + comparison_operator = "GreaterThanThreshold" + datapoints_to_alarm = var.alarm.datapoints_to_alarm + evaluation_periods = var.alarm.evaluation_periods + threshold = var.alarm.threshold + treat_missing_data = "notBreaching" + + metric_query { + id = "visible" + return_data = false + + metric { + dimensions = { + QueueName = module.sqs.queue_name + } + metric_name = "ApproximateNumberOfMessagesVisible" + namespace = "AWS/SQS" + period = var.alarm.period + stat = "Sum" + } + } + + metric_query { + id = "incoming" + return_data = false + + metric { + dimensions = { + QueueName = module.sqs.queue_name + } + metric_name = "NumberOfMessagesSent" + namespace = "AWS/SQS" + period = var.alarm.period + stat = "Sum" + } + } + + metric_query { + id = "delayed" + return_data = false + + metric { + dimensions = { + QueueName = module.sqs.queue_name + } + metric_name = "ApproximateNumberOfMessagesDelayed" + namespace = "AWS/SQS" + period = var.alarm.period + stat = "Sum" + } + } + + metric_query { + id = "deleted" + return_data = false + + metric { + dimensions = { + QueueName = module.sqs.queue_name + } + metric_name = "NumberOfMessagesDeleted" + namespace = "AWS/SQS" + period = var.alarm.period + stat = "Sum" + } + } + + metric_query { + expression = "visible - delayed + incoming - (deleted * ${var.alarm.backlog_minutes})" + id = "backlog" + label = "visible - delayed + incoming - (deleted * ${var.alarm.backlog_minutes})" + return_data = true + } + + alarm_actions = var.alarm_topic_arn != null ? [var.alarm_topic_arn] : [] + ok_actions = var.alarm_topic_arn != null ? [var.alarm_topic_arn] : [] + + tags = module.this.tags +} diff --git a/main.tf b/main.tf new file mode 100644 index 0000000..9a3786e --- /dev/null +++ b/main.tf @@ -0,0 +1,58 @@ +data "aws_iam_policy_document" "subscription" { + count = length(var.subscription) >= 1 ? 1 : 0 + + statement { + actions = [ + "sqs:SendMessage", + "sqs:ReceiveMessage", + ] + + resources = [module.sqs.queue_arn] + + principals { + type = "AWS" + identifiers = ["*"] + } + + dynamic "condition" { + for_each = var.subscription + content { + test = "ArnEquals" + values = [for key in keys(aws_sns_topic_subscription.default) : aws_sns_topic_subscription.default[key].topic_arn] + variable = "aws:SourceArn" + } + } + } +} + +module "sqs" { + source = "terraform-aws-modules/sqs/aws" + version = "4.0.1" + + name = module.this.id + + create_queue_policy = length(var.subscription) >= 1 + + source_queue_policy_documents = try([data.aws_iam_policy_document.subscription[0].json], []) + + create_dlq = var.dlq_enabled + + redrive_policy = { + maxReceiveCount = var.dlq_max_receive_count + } + + tags = module.this.tags + + visibility_timeout_seconds = var.visibility_timeout_seconds + +} + +resource "aws_sns_topic_subscription" "default" { + for_each = var.subscription + topic_arn = "arn:aws:sns:${module.this.aws_region}:${var.subscription_aws_account_id}:${each.value.topic_name}" + confirmation_timeout_in_minutes = "1" + endpoint_auto_confirms = "false" + protocol = "sqs" + endpoint = module.sqs.queue_arn + filter_policy = each.value.filter_policy +} diff --git a/outputs.tf b/outputs.tf new file mode 100644 index 0000000..e69de29 diff --git a/variables.tf b/variables.tf new file mode 100644 index 0000000..3c4f104 --- /dev/null +++ b/variables.tf @@ -0,0 +1,57 @@ +variable "alarm" { + type = object({ + datapoints_to_alarm = optional(number, 3) + description = optional(string, null) + evaluation_periods = optional(number, 3) + backlog_minutes = optional(number, 3) + period = optional(number, 60) + threshold = optional(number, 0) + }) + description = "The details of the alarm such as datapoints to alarm, evaluation periods, backlog minutes, period, and threshold." + default = {} +} + +variable "alarm_enabled" { + type = bool + description = "Defines if the alarm should be created." + default = false +} + +variable "alarm_topic_arn" { + type = string + description = "The ARN of the SNS Topic used for notifying about alarm/ok messages." + default = null +} + +variable "dlq_enabled" { + type = bool + description = "Defines if Dead Letter Queue (DLQ) is enabled." + default = true +} + +variable "dlq_max_receive_count" { + type = number + description = "The maximum number of times a message can be received from the DLQ before it's discarded." + default = 5 +} + +variable "subscription" { + type = map(object({ + topic_name = string + filter_policy = optional(string) + })) + description = "The subscription details such as topic name and filter policy." + default = {} +} + +variable "subscription_aws_account_id" { + type = string + description = "The AWS account ID for the subscription." + default = null +} + +variable "visibility_timeout_seconds" { + description = "The visibility timeout for the queue. An integer from 0 to 43200 (12 hours)" + type = number + default = null +} diff --git a/versions.tf b/versions.tf new file mode 100644 index 0000000..d20b84c --- /dev/null +++ b/versions.tf @@ -0,0 +1,9 @@ +terraform { + required_providers { + aws = { + source = "hashicorp/aws" + version = ">= 4.67" + } + } + required_version = ">= 1.3.0" +}