-
Notifications
You must be signed in to change notification settings - Fork 3
/
lflat.lgt
3947 lines (3281 loc) · 111 KB
/
lflat.lgt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% %
% lflat.lgt - the Logtalk Formal Language and Automata Toolkit %
% %
% - Artur Miguel Dias %
% (CITI, Depart. de Informatica, Univ. Nova de Lisboa) %
% - Paulo Moura %
% (CRACS, INESC Porto) %
% - Michel Wermelinger %
% (Computing Department, The Open University) %
% %
% L-FLAT, version 2.1.2 %
% 07/November/2024 %
% %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% (TABSTOPS = 4)
/*
Changelog (sumary):
07/November/2024 -- L-FLAT version 2.1.2 (Paulo Moura, A. Miguel Dias)
* Update for Logtalk 3.57.0, which is now the minimum version required.
* Fix loading of the gensym library.
* Fix name conflicts when loading all the examples.
* Fix reference to non-existant and unused predicate.
23/May/2022 -- L-FLAT version 2.1.1 (Paulo Moura, A. Miguel Dias)
* Fix linter warning.
11/Oct/2021 -- L-FLAT version 2.1.0 (Paulo Moura, A. Miguel Dias)
* Don't use a settings file to simplify making L-FLAT avaialble as a pack.
05/Feb/2021 -- L-FLAT version 2.0.2 (Paulo Moura, A. Miguel Dias)
* Fix linter warnings.
03/Mar/2020 -- L-FLAT version 2.0.1 (Paulo Moura, A. Miguel Dias)
* Update for Logtalk 3.36.0, which is now the minimum version required.
15/Aug/2009 -- L-FLAT version 2.0 (Paulo Moura, A. Miguel Dias)
* The entire application was rewritten in Logtalk. Virtually all the
same functionality has been kept. Now making the aplication evolve
will be easier due to the advantages of Logtalk.
25/Mar/2007 -- P-FLAT version 1.7 (A. Miguel Dias)
* Made the application more conformant to the ISO Prolog standard.
05/Jul/2006 -- P-FLAT version 1.6 (A. Miguel Dias)
* Introduced support for automated contexts using Mooshak, the programming
contests management system.
10/Mar/2006 -- P-FLAT version 1.5 (A. Miguel Dias)
* Introduced "overloaded operations", operations that are universal,
each kind of entity supplying its own implementation. As now
the overloaded operations are:
alpha/2, show/1, accept/2, accept/3, word/2, tracing/2.
* Introduced "generic predicates" that implement generic algorithms
applicable to all kinds of entities. Some types of entities use
the generic predicates, some others provide more efficient
customised implementations. As now the generic predicates are:
generic_accept/3, generic_accept/2, generic_tracing/2,
generic_word/2.
* Tracing was completely revised and is now available to all the
mechanisms: PREDs, REs, FAs, CFGs, PDAs and TMs
* accept/2 and accept/3 can now handle non-deterministic mechanisms,
with the help of the breath-first strategy. Loop detection is
also implemented to allow some endless executions paths to be
pruned: this helps when trying to reject words and also improves
eficiency. accept/2 and accept/3 are semi-algorithms.
* Now show/1 presents more information, e.g. whether a mechanism is
deterministic.
* Introduced the auxiliary predicate cfg_valid_config/2 to help
reducing the combinatorial explosion in the breath-first
generation of new configurations. This concerns CFGs only.
* The predicates enter/0, execute/1 and execute/3 were promoted
from the file "tutorial.pl" to the main source code file of
P-FLAT. They are very useful to write P-FLAT scripts, and from
now on, the "script" will be considered an important concept
in P-FLAT.
30/Jun/2005 -- P-FLAT version 1.0 (Michel Wermelinger, A. Miguel Dias)
* Initial release, corresponding to the ITiCSE'2005 paper.
*/
%%%%%%%%%%%%
% CONCEPTS %
%%%%%%%%%%%%
/*
A LANGUAGE is partially defined using "unit tests" that is using a set of
positive and a set of negative test cases.
A MECHANISM is an attempt to implement a particular language, either using
a generator or a recognizer. The supported mechanisms are: PREDICATE, RE,
FA, CFG, PDA, TM.
AUTOMATED CONTESTS are implemented for the Mooshak automatic judging manager.
Mooshak is a WEB application that suports automatic judging of submitted programs.
The entities that can have a composite form are the following: ALPHABET, WORD,
RE, MIX. MIX is yet to be implemented.
*/
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Back-end Prolog compiler configuration %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Allows long lists and large terms to be completely displayed in SWI-Prolog
% (no "..." abbreviations will be used)
:- if(current_logtalk_flag(prolog_dialect, swi)).
% bypass the compiler to avoid a portability warning on the flag
{:- set_prolog_flag(toplevel_print_options, [max_depth(200)])}.
:- endif.
% Allows missing/not imported predicates to be discovered
:- if(\+ current_logtalk_flag(prolog_dialect, qp)).
:- set_prolog_flag(unknown, error).
:- endif.
:- op(300, xf, ^*).
:- op(300, xf, ^+).
:- object(modes).
:- info([
version is 2:1:1,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2021-05-23,
comment is 'Flags defining application modes for warning and error reporting.']).
:- public(set_warning_mode/1).
:- mode(set_warning_mode(+atom), one).
:- info(set_warning_mode/1, [
comment is 'Sets warning mode.',
argnames is ['Mode']]).
:- public(current_warning_mode/1).
:- mode(current_warning_mode(?atom), one).
:- info(current_warning_mode/1, [
comment is '.',
argnames is ['Mode']]).
:- public(set_conceal_mode/1).
:- mode(set_conceal_mode(+atom), one).
:- info(set_conceal_mode/1, [
comment is 'Sets warnings mode.',
argnames is ['Mode']]).
:- public(current_conceal_mode/1).
:- mode(current_conceal_mode(?atom), one).
:- info(current_conceal_mode/1, [
comment is '.',
argnames is ['Mode']]).
:- public(set_error_mode/1).
:- mode(set_error_mode(+atom), one).
:- info(set_error_mode/1, [
comment is 'Sets error mode.',
argnames is ['Mode']]).
:- public(current_error_mode/1).
:- mode(current_error_mode(?atom), one).
:- info(current_error_mode/1, [
comment is '.',
argnames is ['Mode']]).
:- private(warning_mode_/1). % default is high
:- dynamic(warning_mode_/1).
warning_mode_(high).
set_warning_mode(Mode) :-
once((Mode == off ; Mode == low ; Mode == high)),
retractall(warning_mode_(_)),
assertz(warning_mode_(Mode)).
current_warning_mode(Mode) :-
warning_mode_(Mode).
:- private(conceal_mode_/1). % default is off
:- dynamic(conceal_mode_/1).
conceal_mode_(off).
set_conceal_mode(Mode) :-
once((Mode == off ; Mode == on)),
retractall(conceal_mode_(_)),
assertz(conceal_mode_(Mode)).
current_conceal_mode(Mode) :-
conceal_mode_(Mode).
:- private(error_mode_/1). % default is off
:- dynamic(error_mode_/1).
error_mode_(off).
set_error_mode(Mode) :-
once((Mode == off ; Mode == on)),
retractall(error_mode_(_)),
assertz(error_mode_(Mode)).
current_error_mode(Mode) :-
error_mode_(Mode).
:- end_object.
:- object(interaction).
:- info([
version is 2:1:2,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2024-11-07,
comment is 'Predicates for command-line user interaction.']).
:- public(banner/0).
:- mode(banner, one).
:- info(banner/0, [
comment is 'Prints the L-FLAT banner.']).
:- public(run_example/1).
:- mode(run_example(+atom), one).
:- info(run_example/1, [
comment is 'Loads and runs an example.',
argnames is ['Example']]).
:- public(run_examples/1).
:- mode(run_examples(+list(atom)), one).
:- info(run_examples/1, [
comment is 'Loads and runs a list of examples.',
argnames is ['Examples']]).
banner :-
write('L-FLAT 2.1.2 - the Logtalk Formal Language and Automata Toolkit'), nl,
write('Copyright (c) 2005-2024 Artur Miguel Dias, Paulo Moura, Michel Wermelinger'), nl, nl.
run_example(Example) :-
logtalk_load(lflat_examples(Example), [hook(hook)]).
run_examples([]).
run_examples([X|Xs]) :-
run_example(X),
separator,
enter,
nl, nl,
separator,
run_examples(Xs).
enter :-
nl, write('Press ENTER to continue'), nl, get_code(_).
separator :-
write('------------------------------------'), nl.
:- end_object.
:- category(messages).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Utility predicates for composing and writing messages.']).
:- public([
message/4,
fail_with_warning/3,
fail_with_error/3,
halt_with_error/3
]).
:- public(execute/1).
:- meta_predicate(execute(0)).
:- mode(execute(+callable), one).
:- info(execute/1, [
comment is 'Calls a goal, printing "Yes" or "No".',
argnames is ['Goal']]).
:- public(execute/3).
:- meta_predicate(execute(0, *, *)).
:- mode(execute(+callable, +atom, +callable), one).
:- info(execute/3, [
comment is 'Calls a goal Goal, writing result Result until Goal fails or stop condition Stop succeeds.',
argnames is ['Goal', 'Result', 'Stop']]).
:- public(write_symbol_list/2).
:- mode(write_symbol_list(+list, +atom), one).
:- info(write_symbol_list/2, [
comment is 'Writes a sequence of symbols (starting with a prefix).',
argnames is ['Symbols', 'Prefix']]).
:- uses(list, [member/2]).
execute(G, R, S) :-
write('?- '), write(G), write('.'), nl, call(G),
( R == none ->
true
; write(R), write(' ;'), nl
),
call(S), write('Yes'), nl, !.
execute(_, _, _) :-
write('No'), nl.
execute(Goal) :-
execute(Goal, none, true).
write_symbol_list([], _).
write_symbol_list([Symbol| Symbols], Prefix) :-
write(Prefix), write(Symbol),
write_symbol_list(Symbols).
write_symbol_list([]).
write_symbol_list([Symbol| Symbols]) :-
write(' '), write(Symbol),
write_symbol_list(Symbols).
% warnings and errors
writerr(Term) :-
write(user_error, Term).
nlerr :-
nl(user_error).
message_body(Name, Msg1, Msg2) :-
writerr(Name),
writerr(': '),
writerr(Msg1),
writerr(' '),
writerr(Msg2),
nlerr.
message(weak_warning, Name, Msg1, Msg2) :-
( modes::current_warning_mode(high) ->
writerr('Warning in '),
message_body(Name, Msg1, Msg2)
; true
).
message(warning, Name, Msg1, Msg2) :-
( modes::current_warning_mode(off) ->
true
; writerr('Warning in '),
message_body(Name, Msg1, Msg2)
).
message(error, Name, Msg1, Msg2) :-
modes::set_error_mode(on),
writerr('Error in '),
message_body(Name, Msg1, Msg2).
fail_with_warning(Name, Msg1, Msg2) :-
message(warning, Name, Msg1, Msg2),
fail.
fail_with_error(Name, Msg1, Msg2) :-
message(error, Name, Msg1, Msg2),
fail.
halt_with_error(Name, Msg1, Msg2) :-
message(error, Name, Msg1, Msg2),
halt.
:- end_category.
:- object(term_classification).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Classification of terms as valid elements for sets, valid names for declarations, etc.']).
:- public(is_element/1).
:- mode(is_element(@term), zero_or_one).
:- info(is_element/1, [
comment is 'Term is a valid element for a set.',
argnames is ['Term']]).
:- public(is_symbol/1).
:- mode(is_symbol(@term), zero_or_one).
:- info(is_symbol/1, [
comment is 'Symbol is a symbol that can be used in an alphabet.',
argnames is ['Symbol']]).
:- public(is_lambda/1).
:- mode(is_lambda(@term), zero_or_one).
:- info(is_lambda/1, [
comment is 'Lambda is used in the representation of lambda transitions.',
argnames is ['Lambda']]).
:- public(is_state/1).
:- mode(is_state(@term), zero_or_one).
:- info(is_state/1, [
comment is 'State is a valid name for a state.',
argnames is ['State']]).
:- uses(term, [ground/1]).
is_element(Element) :-
ground(Element).
is_symbol(Symbol) :-
atomic(Symbol),
Symbol \== [],
Symbol \== {},
( atom(Symbol) ->
\+ current_object(Symbol)
; true
).
is_lambda(Lambda) :-
Lambda == [].
is_empty_re(EmptyRE) :-
EmptyRE == {}.
is_state(State) :-
ground(State).
:- end_object.
:- object(entity,
imports(messages),
instantiates(abstract_class),
specializes(object)).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Predicates common to all entities.']).
:- public(show/0).
:- mode(show, one).
:- info(show/0, [
comment is 'Prints a description of the declaration.']).
:- public(valid/0).
:- mode(valid, zero_or_one).
:- info(valid/0, [
comment is 'Declaration is valid.']).
:- public(diagnostics/0).
:- mode(diagnostics, one).
:- info(diagnostics/0, [
comment is 'Prints all diagnostics.']).
:- public(diagnostic/1).
:- mode(diagnostic(-compound), zero_or_more).
:- info(diagnostic/1, [
comment is 'Diagnostic represents a problem diagnostic.',
argnames is ['Diagnostic']]).
:- protected(build_error/3).
:- protected(build_warning/3).
:- protected(build_weak_warning/3).
build_error(Part1, Part2, error(Declaration, Part1, Part2)) :-
self(Declaration).
build_warning(Part1, Part2, warning(Declaration, Part1, Part2)) :-
self(Declaration).
build_weak_warning(Part1, Part2, weak_warning(Declaration, Part1, Part2)) :-
self(Declaration).
diagnostics :-
self(Self),
write('Starting diagnostics of '), write(Self), write(' ...'), nl,
::diagnostic(Diagnostic),
Diagnostic =.. [Kind, Name, Msg1, Msg2],
::message(Kind, Name, Msg1, Msg2),
fail.
diagnostics :-
write('... diagnostics finished'), nl.
:- end_object.
:- object(meta_alphabet,
specializes(class)).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Metaclass of alphabet.']).
:- public(equal/2).
:- mode(equal(@alphabet, @alphabet), zero_or_one).
:- info(equal/2, [
comment is 'The two alphabet expressions define the same set of symbols.',
argnames is ['Alphabet1', 'Alphabet2']]).
:- public(contains/2).
:- mode(contains(@alphabet, @alphabet), zero_or_one).
:- info(contains/2, [
comment is 'The first alphabet contains the symbols of the second alphabet.',
argnames is ['Alphabet1', 'Alphabet2']]).
:- public(new/2).
:- mode(new(?object_identifier, +nonvar), one).
:- info(new/2, [
comment is 'Creates a new alphabet.',
argnames is ['Id', 'Expression']]).
equal(Alphabet1, Alphabet2) :-
alphabet(Alphabet1)::symbols(Symbols),
alphabet(Alphabet2)::symbols(Symbols).
contains(Alphabet1, Alphabet2) :-
alphabet(Alphabet1)::symbols(Symbols1),
alphabet(Alphabet2)::symbols(Symbols2),
set::subset(Symbols2, Symbols1).
new(Id, Expression) :-
self(Self),
create_object(Id, [instantiates(Self)], [], [expression(Expression)]).
:- end_object.
:- object(alphabet,
instantiates(meta_alphabet),
specializes(entity)).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Alphabets.']).
:- public(expression/1).
:- mode(expression(-nonvar), one).
:- info(expression/1, [
comment is 'Alphabet expression.',
argnames is ['Expression']]).
:- public(symbols/1).
:- mode(symbols(-list), one).
:- info(symbols/1, [
comment is 'Alphabet evaluates to symbol set Symbols.',
argnames is ['Symbols']]).
:- uses(list, [valid/1::is_list/1, permutation/2, sort/2]).
:- uses(term_classification, [is_symbol/1]).
:- uses(set, [valid/1::is_set/1, member/2, union/3, intersection/3, symdiff/3]).
show :-
write('ALPHABET: '),
self(Self),
writeq(Self), nl,
write(' Expression: '),
::expression(Expression),
writeq(Expression), nl,
write(' Symbols: '),
::symbols(Symbols),
writeq(Symbols), nl.
valid :-
::expression(Expression),
valid(Expression).
valid((-)) :-
!,
fail.
valid([]) :-
!.
valid([Symbol| Symbols]) :-
!,
\+ (member(Element, [Symbol| Symbols]), \+ is_symbol(Element)),
is_set([Symbol| Symbols]).
valid(Alphabet1 + Alphabet2) :-
!,
valid(Alphabet1),
valid(Alphabet2).
valid(Alphabet1 - Alphabet2) :-
!,
valid(Alphabet1),
valid(Alphabet2).
valid(Alphabet1 /\ Alphabet2) :-
!,
valid(Alphabet1),
valid(Alphabet2).
valid(Alphabet) :-
Alphabet::expression(Expression),
valid(Expression).
diagnostic(Diagnostic) :-
::expression(Expression),
\+ valid(Expression),
::build_error(Expression, 'is not an alphabet', Diagnostic).
diagnostic(Diagnostic) :-
::symbols([]),
::build_warning('empty alphabet', '', Diagnostic).
symbols(Symbols) :-
::expression(Expression),
symbols(Expression, Symbols).
symbols(List, Symbols) :-
is_list(List),
!,
sort(List, Symbols).
symbols(Alphabet1 + Alphabet2, Symbols) :-
!,
symbols(Alphabet1, Symbols1),
symbols(Alphabet2, Symbols2),
union(Symbols1, Symbols2, Symbols).
symbols(Alphabet1 - Alphabet2, Symbols) :-
!,
symbols(Alphabet1, Symbols1),
symbols(Alphabet2, Symbols2),
symdiff(Symbols1, Symbols2, Symbols).
symbols(Alphabet1 /\ Alphabet2, Symbols) :-
!,
symbols(Alphabet1, Symbols1),
symbols(Alphabet2, Symbols2),
intersection(Symbols1, Symbols2, Symbols).
symbols(Alphabet, Symbols) :-
Alphabet::symbols(Symbols).
:- end_object.
:- object(meta_order,
specializes(class)).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Metaclass of order.']).
:- public(new/3).
:- mode(new(?object_identifier, +nonvar, +list), one).
:- info(new/3, [
comment is 'Creates a new order over an alphabet.',
argnames is ['Id', 'Alphabet', 'Sequence']]).
new(Id, Expression, Sequence) :-
self(Self),
create_object(Id, [instantiates(Self)], [], [alphabet(Expression), sequence(Sequence)]).
:- end_object.
:- object(order,
implements(comparingp),
instantiates(meta_order),
specializes(entity)).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Total order over an alphabet.']).
:- public(alphabet/1).
:- mode(alphabet(-nonvar), one).
:- info(alphabet/1, [
comment is 'Alphabet expression.',
argnames is ['Expression']]).
:- public(sequence/1).
:- mode(sequence(-list), one).
:- info(sequence/1, [
comment is 'The default total alphabet order is specified by Sequence.',
argnames is ['Sequence']]).
:- uses(list, [nth0/3]).
:- uses(set, [intersection/3, symdiff/3]).
Symbol1 < Symbol2 :-
::sequence(Sequence),
nth0(N1, Sequence, Symbol1),
nth0(N2, Sequence, Symbol2),
{N1 < N2}.
Symbol1 =< Symbol2 :-
::sequence(Sequence),
nth0(N1, Sequence, Symbol1),
nth0(N2, Sequence, Symbol2),
{N1 =< N2}.
Symbol1 > Symbol2 :-
::sequence(Sequence),
nth0(N1, Sequence, Symbol1),
nth0(N2, Sequence, Symbol2),
{N1 > N2}.
Symbol1 >= Symbol2 :-
::sequence(Sequence),
nth0(N1, Sequence, Symbol1),
nth0(N2, Sequence, Symbol2),
{N1 >= N2}.
Symbol1 =:= Symbol2 :-
Symbol1 == Symbol2.
Symbol1 =\= Symbol2 :-
Symbol1 \== Symbol2.
show :-
write('ORDER: '), self(Self), writeq(Self), nl,
write(' Alphabet: '), ::alphabet(Expression), writeq(Expression), nl,
write(' Sequence:'), nl,
forall(::sequence(Sequence), (write(' '), writeq(Sequence), nl)).
valid :-
::alphabet(Expression),
alphabet(Expression)::valid,
alphabet(Expression)::symbols(Symbols),
::sequence(Sequence),
intersection(Symbols, Sequence, []).
diagnostic(Diagnostic) :-
::alphabet(Expression),
\+ alphabet(Expression)::valid,
::build_error(Expression, 'is not an alphabet', Diagnostic).
diagnostic(Diagnostic) :-
::alphabet(Expression),
alphabet(Expression)::symbols(Symbols),
::sequence(Sequence),
\+ symdiff(Symbols, Sequence, []),
::build_error(Sequence, 'is not a permutation of the alphabet symbols', Diagnostic).
:- end_object.
:- object(word).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Words are finite sequences of symbols.']).
:- public(valid/1).
:- mode(valid(@term), zero_or_one).
:- info(valid/1, [
comment is 'Term is a valid word (a list of symbols).',
argnames is ['Term']]).
:- public(compute_word/2).
:- mode(compute_word(+nonvar, -list), zero_or_one).
:- info(compute_word/2, [
comment is 'Expression evaluates to word Word.',
argnames is ['Expression', 'Word']]).
:- public(prefix/2).
:- mode(prefix(?list, +list), zero_or_more).
:- info(prefix/2, [
comment is 'Word1 is a prefix of Word2.',
argnames is ['Word1', 'Word2']]).
:- public(suffix/2).
:- mode(suffix(?list, +list), zero_or_more).
:- info(suffix/2, [
comment is 'Word1 is a suffix of Word2.',
argnames is ['Word1', 'Word2']]).
:- public(subword/2).
:- mode(subword(?list, +list), zero_or_one).
:- info(subword/2, [
comment is 'Word1 is contained in Word2.',
argnames is ['Word1', 'Word2']]).
:- public(occurs/3).
:- mode(occurs(+nonvar, +list, -integer), zero_or_one).
:- info(occurs/3, [
comment is 'Symbol occurs N times in Word.',
argnames is ['Symbol', 'Word', 'N']]).
:- public(word_alphabet/2).
:- mode(word_alphabet(?list, @object_identifier), zero_or_more).
:- mode(word_alphabet(?list, @list), zero_or_more).
:- mode(word_alphabet(@list, -nonvar), one).
:- info(word_alphabet/2, [
comment is 'Word is a word over Alphabet.',
argnames is ['Word', 'Alphabet']]).
:- public(lexically_ordered/3).
:- mode(lexically_ordered(?list, +list, +object_identifier), zero_or_one).
:- mode(lexically_ordered(+list, ?list, +object_identifier), zero_or_one).
:- info(lexically_ordered/3, [
comment is 'Word1 < Word2 according to the lexical order based on the total alphabetic order.',
argnames is ['Word1', 'Word2', 'Order']]).
:- public(mixed_ordered/3).
:- mode(mixed_ordered(?list, +list, +object_identifier), zero_or_one).
:- mode(mixed_ordered(+list, ?list, +object_identifier), zero_or_one).
:- info(mixed_ordered/3, [
comment is 'Word1 =< Word2 and are lexically ordered according to the total alphabetic order.',
argnames is ['Word1', 'Word2', 'Alphabet']]).
:- public(next_word/3).
:- mode(next_word(+list, -list, +object_identifier), zero_or_one).
:- info(next_word/3, [
comment is 'Word2 is the successor of Word1 according to the mixed order based on alphabetic order.',
argnames is ['Word1', 'Word2', 'Alphabet']]).
:- uses(term_classification, [is_symbol/1]).
:- uses(list, [member/2, length/2, append/3, reverse/2, nth0/3, valid/1::is_list/1]).
:- uses(set, [valid/1::is_set/1]).
valid((-)) :-
!,
fail.
valid([]).
valid([Symbol| Symbols]) :-
is_symbol(Symbol),
valid(Symbols).
valid(W1 * W2) :- valid(W1), valid(W2).
valid(W ^ N) :- N >= -1, valid(W).
% compute_word(+Expression, ?Word)
% Expression denotes the list of symbols Word
% pre: valid(Expression)
compute_word(Word, Word) :-
is_list(Word),
!.
compute_word(Expression1 * Expression2, Word) :-
compute_word(Expression1, Word1),
compute_word(Expression2, Word2),
append(Word1, Word2, Word).
compute_word(_ ^ 0, []).
compute_word(E ^ N, Wn) :-
N > 0, M is N-1, compute_word(E, W), compute_word(W * W^M, Wn).
compute_word(E ^ N, Wr) :-
-1 is N, compute_word(E, W), reverse(W, Wr).
prefix(Word1, Word2) :-
append(Word1, _, Word2).
suffix(Word1, Word2) :-
append(_, Word1, Word2).
subword(Word1, Word2) :-
prefix(Prefix, Word2),
suffix(Word1, Prefix).
occurs(_, [], 0) :-
!.
occurs(Symbol, [Symbol| Symbols], N) :-
!,
occurs(Symbol, Symbols, M),
N is M + 1.
occurs(Symbol, [_| Symbols], N) :-
occurs(Symbol, Symbols, N).
word_alphabet(Expression, Alphabet) :-
( var(Expression) ->
Word = Expression
; compute_word(Expression, Word)
),
( var(Alphabet) ->
Alphabet = Symbols
; alphabet(Alphabet)::symbols(Symbols)
),
word_symbols(Word, Symbols).
% word_symbols(?/+Word, +/-Symbols)
% pre: (alphabet::valid(Symbols), Symbols = {_}) ; valid(Word)
word_symbols(Word, Symbols) :-
var(Symbols),
!,
setof(Symbol, member(Symbol, Word), Symbols).
word_symbols([], _).
word_symbols([Symbol| Word], Symbols) :-
word_symbols(Word, Symbols),
member(Symbol, Symbols).
lexically_ordered([], [_| _], _).
lexically_ordered([Symbol| Word1], [Symbol| Word2], Order) :-
lexically_ordered(Word1, Word2, Order).
lexically_ordered([Symbol1| _], [Symbol2| _], Order) :-
Order::(Symbol1 < Symbol2).
mixed_ordered(Word1, Word2, Order) :-
length(Word1, N1),
length(Word2, N2),
( N1 < N2
; N1 = N2,
lexically_ordered(Word1, Word2, Order)
; N1 > N2,
!,
fail
).
next_word([], [First], Order) :-
!,
Order::sequence([First| _]).
next_word(Word1, Word2, Order) :-
append(Prefix, [Last], Word1),
Order::sequence(Sequence),
subword([Last, Next], Sequence),
append(Prefix, [Next], Word2).
next_word(Word1, Word2, Order) :-
Order::sequence(Sequence),
suffix([Last], Sequence),
prefix([First], Sequence),
append(Prefix1, [Last], Word1),
next_word(Prefix1, Prefix2, Order),
append(Prefix2, [First], Word2).
:- end_object.
:- object(meta_language,
specializes(class)).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Metaclass of language.']).
:- public(new/4).
:- mode(new(?object_identifier, +nonvar, +list, +list), one).
:- info(new/4, [
comment is 'Creates a new language.',
argnames is ['Id', 'Alphabet', 'Positives', 'Negatives']]).
:- uses(list, [append/3, member/2]).
new(Id, Alphabet, Positives, Negatives) :-
self(Self),
findall(positive(Positive), member(Positive, Positives), Positives),
findall(negative(Negative), member(Negative, Negatives), Negatives),
append(Positives, Negatives, Clauses),
create_object(Id, [instantiates(Self)], [], [alphabet(Alphabet)| Clauses]).
:- end_object.
:- object(language,
instantiates(meta_language),
specializes(entity)).
:- info([
version is 2:1:0,
author is 'Artur Miguel Dias, Paulo Moura, and Michel Wermelinger',
date is 2020-03-03,
comment is 'Languages defined using unit tests.']).
:- public(alphabet/1).
:- mode(alphabet(-nonvar), zero_or_one).
:- info(alphabet/1, [
comment is 'Returns the expression that specifies the language alphapet.',
argnames is ['Expression']]).
:- public(positive/1).
:- mode(positive(?list), zero_or_more).
:- info(positive/1, [
comment is 'Positive example of a language word.',
argnames is ['Word']]).
:- public(negative/1).
:- mode(negative(?list), zero_or_more).
:- info(negative/1, [
comment is 'Negative example of a language word.',
argnames is ['Word']]).
:- public(test_mechanism/1).
:- mode(test_mechanism(+object_identifier), zero_or_one).
:- info(test_mechanism/1, [
comment is 'Tests the definition of Mechanism using the language examples.',
argnames is ['Mechanism']]).
:- uses(word, [valid/1::is_word/1, word_alphabet/2]).
valid :-
::alphabet(Expression),
alphabet(Expression)::valid,
\+ (::positive(Word), \+ is_word(Word)),
\+ (::negative(Word), \+ is_word(Word)),