sendInvite (WIFI problem)

[krystianlenc]

Hi! I need to make a midi cc receiver that converts midi cc to dmx (artnet) to control the lighting controller from the midiwirst application (iphone, apple watch). Since I don't want to use an additional computer for this, I need to connect the applemidi session directly to the iPhone. I found a way:
IPAddress remote(2, 1, 1, 116);
AppleMIDI.sendInvite(remote, DEFAULT_CONTROL_PORT); // port is 5004 by default

unfortunately, it only compiles from ethernet, when using wifi I get a compilation error "Compilation error: 'class appleMidi::AppleMIDISession' has no member named 'sendInvite'"

Can I do anything in this case? I want to use esp8266 (esp01s) to keep the dimensions of the device as small as possible, WiFi latency is not a problem for me!

[stelopin2]

Hi krystianlenc,
I want to accomplish the same with a WEMOS D1. This old fork has the needed function: https://github.com/Hackmancoltaire/mousepiano/blob/master/GarmentController/GarmentController.ino

Use this example https://github.com/Hackmancoltaire/Arduino-AppleMidi-Library/tree/master/examples/Esp8266_NoteOnOffEverySec
and add the lines between start and finish:
AppleMIDI.begin("test");
// start
// https://github.com/Hackmancoltaire/mousepiano/blob/master/GarmentController/GarmentController.ino
// Actively connect to a remote host
IPAddress remote(192, 168, 178, 23); // iPad
AppleMIDI.invite(remote, 5004);
// finish

AppleMIDI.OnConnected(OnAppleMidiConnected);

In the Serial Monitor I see the MIDI-Commands from my iPad to control our lights (currently by PC_Dimmer, but maybe in the future by a fork of ESP8266_ArtNetNode_DMX):

8:38:41.975 -> WiFi connected
18:38:41.975 ->
18:38:41.975 -> IP address is 192.168.178.142
18:38:41.975 -> OK, now make sure you an rtpMIDI session that is Enabled
18:38:41.975 -> Add device named Arduino with Host/Port 192.168.178.142:5004
18:38:41.975 -> Then press the Connect button
18:38:41.975 -> Then open a MIDI listener (eg MIDI-OX) and monitor incoming notes
18:38:41.975 -> Sending NoteOn/Off of note 45, every second
18:54:06.672 -> .......
18:54:10.378 -> WiFi connected
18:54:10.378 ->
18:54:10.378 -> IP address is 192.168.178.142
18:54:10.378 -> OK, now make sure you an rtpMIDI session that is Enabled
18:54:10.378 -> Add device named Arduino with Host/Port 192.168.178.142:5004
18:54:10.425 -> Then press the Connect button
18:54:10.425 -> Then open a MIDI listener (eg MIDI-OX) and monitor incoming notes
18:54:10.425 -> Sending NoteOn/Off of note 45, every second
18:54:12.112 -> Connected to session iPad
18:55:47.473 -> Incoming NoteOn from channel:1 note:6 velocity:1
18:55:47.473 -> Incoming NoteOn from channel:1 note:6 velocity:1
18:55:47.988 -> Incoming NoteOn from channel:1 note:6 velocity:3
18:55:47.988 -> Incoming NoteOn from channel:1 note:6 velocity:3

[Hackmancoltaire]

Isn't this same example available in the current code?
https://github.com/lathoub/Arduino-AppleMIDI-Library/blob/master/examples/ESP8266_NoteOnOffEverySec/ESP8266_NoteOnOffEverySec.ino

[stelopin2]

Hi krystianlenc,

since you did not answer him about his question about sendInvite and also of his compiling errors I thought your Implemention would not have this method. A quick google search took me to the above fork.

After your comment I tried your suggestion and it works even with the ESP8266WiFi include and not only by using the Ethernet one.
Thank you for this wunderful library.

Here is now my working example to play with.

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <WiFiUdp.h>

#define SerialMon Serial
#define APPLEMIDI_INITIATOR // needed for AppleMIDI.sendInvite
#include <AppleMIDI_Debug.h> // for DBG()

// Sketch as POC how to receive MIDI over APPLE-MIDI
// SL Define the pins for your status leds
#define LED1 12 // yellow for WIFI-Connect-Status
#define LED2 13 // blue for MIDI-receive-Status
#include <AppleMIDI.h>

char ssid[] = "yourSID"; //  your network SSID (name)
char pass[] = "yourPassword";    // your network password (use for WPA, or use as key for WEP)
IPAddress remote(192, 168, 178, 23); // IP of your iPad
//IPAddress remote(192, 168, 178, 189); // IP of your iPhone

unsigned long t0 = millis();
unsigned long t1 = millis();
int8_t isConnected = 0;
int8_t isConnectedCount = 0;

APPLEMIDI_CREATE_DEFAULTSESSION_INSTANCE();

// -----------------------------------------------------------------------------
//
// -----------------------------------------------------------------------------
void setup()
{
  pinMode(LED1, OUTPUT); // Network/Session-Status. HIGH=Not connected
  pinMode(LED2, OUTPUT); // MIDI-Receive-Status
  digitalWrite(LED1, HIGH); // Network/Session-Status. HIGH=Not connected

  DBG_SETUP(115200);
  DBG("Booting");

  WiFi.begin(ssid, pass);

  Serial.print("\n\rEstablishing connection to WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    isConnectedCount++;
    delay(500);
    Serial.print(".");
    if (isConnectedCount == 30) {
      Serial.println("\n\rNo WiFi-Connection possible. Restart ESP...");
      ESP.restart();
    }
  }
  isConnectedCount = 0;
  DBG("\n\rConnected to network with IP", WiFi.localIP());
  digitalWrite(LED1, LOW); // Network/Session-Status. HIGH=Not connected

  MIDI.begin();

  AppleMIDI.setHandleConnected([](const APPLEMIDI_NAMESPACE::ssrc_t & ssrc, const char* name) {
    isConnected = 1;
    digitalWrite(LED1, LOW); // Network/Session-Status. HIGH=Not connected
    DBG(F("Connected to session"), ssrc, name, "after", isConnectedCount, "trys");
    isConnectedCount = 0;
  });

  AppleMIDI.setHandleDisconnected([](const APPLEMIDI_NAMESPACE::ssrc_t & ssrc) {
    isConnected = 0;
    digitalWrite(LED1, HIGH); // Network/Session-Status. HIGH=Not connected
    DBG(F("Disconnected from session"), ssrc);
  });

  MIDI.setHandleNoteOn([](byte channel, byte note, byte velocity) {
    digitalWrite(LED2, HIGH); // MIDI-Receive-Status
    DBG(F("Incoming NoteOn from channel:"), channel, "note:", note, "velocity:", velocity);
    digitalWrite(LED2, LOW); // MIDI-Receive-Status
  });

  MIDI.setHandleNoteOff([](byte channel, byte note, byte velocity) {
    digitalWrite(LED2, HIGH); // MIDI-Receive-Status
    DBG(F("Incoming NoteOff from channel:"), channel, "note:", note, "velocity:", velocity);
    digitalWrite(LED2, LOW); // MIDI-Receive-Status
  });

  DBG(F("Connecting to"), remote, "Port", DEFAULT_CONTROL_PORT, "(Name", AppleMIDI.getName(), ")");
  DBG(F("Watch as this session is added to the Participants list"));
  DBG(F("Then open a MIDI listener and monitor incoming notes"));

  DBG(F("Sending NoteOn/Off of note 45, every second"));
}

// -----------------------------------------------------------------------------
//
// -----------------------------------------------------------------------------
void loop()
{
  // Listen to incoming notes
  MIDI.read();

  // send a note every second
  // (dont call delay(1000) as it will stall the pipeline)
  if ((isConnected == 1) && (millis() - t0) > 1000)
  {
    t0 = millis();

    byte note = 45;
    byte velocity = 55;
    byte channel = 1;

    MIDI.sendNoteOn(note, velocity, channel);
    MIDI.sendNoteOff(note, velocity, channel);
  }

  // Seems the connection lost sometimes for unknown reason
  // Check every 1 Second if reconnect to iPad if needed
  if ((isConnected == 0) && (millis() - t1) > 1000)
  {
    t1 = millis();
    isConnectedCount++;
    if (isConnectedCount == 1) {
      Serial.print("Try connect to remote "); Serial.println(remote);
    } else {
      Serial.print(" "); Serial.print(isConnectedCount);
      if (isConnectedCount == 30) {
        Serial.println("\n\rNo connection to session or WiFi possible. Restart ESP...");
        ESP.restart();
      }
    }
    AppleMIDI.sendInvite(remote, DEFAULT_CONTROL_PORT); // port is 5004 by default
  }
} // Loop