build.gradle

buildscript {
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.2'
    }
}

repositories {
    // Used for com.jhlabs:javaproj-noawt
    maven {
        url "https://raw.github.com/mvestola/helsinki-testbed2-android-repo/master/repo"
    }
    google()
    jcenter()
}

apply plugin: 'com.android.application'

android {
    compileSdkVersion 33
    buildToolsVersion "33.0.2"

    defaultConfig {
        applicationId "fi.testbed2"
        minSdkVersion 26
        targetSdkVersion 33
        versionCode 25
        versionName "2.0.17"
    }

    signingConfigs {
        release {
            storeFile file(RELEASE_STORE_FILE)
            storePassword RELEASE_STORE_PASSWORD
            keyAlias RELEASE_KEY_ALIAS
            keyPassword RELEASE_KEY_PASSWORD
            v1SigningEnabled true
            v2SigningEnabled true
        }
    }

    buildTypes {
        debug {
            buildConfigField "String", "ENVIRONMENT", '"TEST"'
            buildConfigField "boolean", "DEBUG_OUTPUT", "true"
        }
        release {
            buildConfigField "String", "ENVIRONMENT", '"PRODUCTION"'
            buildConfigField "boolean", "DEBUG_OUTPUT", "false"
            signingConfig signingConfigs.release
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    testOptions {
        unitTests {
            includeAndroidResources = true
        }
        unitTests.all {
            systemProperty 'robolectric.dependency.repo.url', 'https://repo1.maven.org/maven2'
            systemProperty 'robolectric.dependency.repo.id', 'mavenCentral'
        }
    }
    namespace 'fi.testbed2'
}

def powerMockVersion = '2.0.9'
def androidAnnotationsVersion = '4.8.0'
def robolectricVersion = '4.5.1'
def mockServerVersion = '5.11.2'
def lombokVersion = '1.18.18'

dependencies {
    implementation 'androidx.appcompat:appcompat:1.2.0'
    testImplementation 'junit:junit:4.13.1'
    annotationProcessor "org.projectlombok:lombok:$lombokVersion"
    //noinspection AnnotationProcessorOnCompilePath
    compileOnly "org.projectlombok:lombok:$lombokVersion"
    annotationProcessor "org.androidannotations:androidannotations:$androidAnnotationsVersion"
    implementation "org.androidannotations:androidannotations-api:$androidAnnotationsVersion"
    annotationProcessor "org.androidannotations:roboguice:$androidAnnotationsVersion"
    implementation "org.androidannotations:roboguice-api:$androidAnnotationsVersion"
    implementation 'com.google.android.gms:play-services-ads:21.5.0'
    implementation 'com.jhlabs:javaproj-noawt:1.0.6'
    //noinspection GradleDependency
    implementation 'org.roboguice:roboguice:3.0.1'
    implementation 'com.github.pwittchen:weathericonview:1.1.0'
    implementation 'com.google.android:flexbox:1.1.1'
    implementation 'com.jaredrummler:colorpicker:1.1.0'
    testImplementation "org.robolectric:robolectric:$robolectricVersion"
    testImplementation "org.robolectric:shadows-httpclient:$robolectricVersion"
    testImplementation "org.powermock:powermock-module-junit4:$powerMockVersion"
    testImplementation "org.powermock:powermock-module-junit4-rule:$powerMockVersion"
    testImplementation "org.powermock:powermock-classloading-xstream:$powerMockVersion"
    testImplementation "org.powermock:powermock-api-mockito2:$powerMockVersion"
    testImplementation "org.mock-server:mockserver-netty:$mockServerVersion"
    testImplementation "org.mock-server:mockserver-junit-rule:$mockServerVersion"
}