build.gradle

import java.text.SimpleDateFormat

plugins {
    id 'application'
    id 'java-library'
    id 'maven-publish'
}

group 'com.reportmill'
version  new SimpleDateFormat("yyyy.MM").format(new Date())

sourceSets.main.java.srcDirs = ['src']
sourceSets.main.resources.srcDirs = ['src']

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

repositories {
    mavenCentral()
}

dependencies {

    // SnapKit project
    implementation project(':SnapKit')

    // SnapKitGL project
    implementation project(':SnapKitGL')

}

mainClassName = 'snapcharts.app.App'

publishing {

    repositories {
        maven {
            name = "GitHubPackages"
            url = "https://maven.pkg.github.com/reportmill/SnapCharts"
            credentials {
                username = System.getenv("GITHUB_ACTOR")
                password = System.getenv("GITHUB_TOKEN")
                println "GitHubPackages Publish Artifact:\n\tusername=$username\n\ttoken=$password"
            }
        }
    }

    publications {
        gpr(MavenPublication) {
            artifactId 'snapcharts'
            from(components.java)
        }
    }
}

/**
 * Build executable jar SnapChartsAll.jar.
 *
 * We could use the standard jar task just by using jar { ... } and deleting 'baseName' and 'with jar' lines.
 */
task buildExecJar(type: Jar) {
    manifest {
        attributes 'Main-Class': 'snapcharts.app.App'
    }
    archiveBaseName = 'SnapChartsAll'
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
    with jar
}