-
Notifications
You must be signed in to change notification settings - Fork 0
/
decimal.v
220 lines (194 loc) · 4.65 KB
/
decimal.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
module vdecimal
// Arbitrary-precision fixed-point decimal numbers
import math.big
import math
import strings
// Decimal represents a fixed-point decimal.
// number = value * 10 ^ exp
pub struct Decimal {
value big.Integer
exp int
}
// new returns a new fixed-point decimal, value * 10 ^ exp.
pub fn new(value i64, exp int) Decimal {
return Decimal{
value: big.integer_from_i64(value)
exp: exp
}
}
// decimal_from_string returns a new Decimal from a string representation.
// Trailing zeroes are not trimmed.
pub fn decimal_from_string(value string) !Decimal {
mut int_string := ''
mut exp := 0
// maybe replace this with strings.textscanner
mut p_index := -1
for i := 0; i < value.len; i++ {
if value[i] == `.` {
if p_index > -1 {
return error('can\'t convert ${value} to decimal: too many .s"')
}
p_index = i
}
}
if p_index == -1 {
// There is no decimal point, we can just parse the original string as
// an int
int_string = value
} else {
if p_index + 1 < value.len {
int_string = value.substr(0, p_index) + value.substr(p_index + 1, value.len)
} else {
int_string = value.substr(0, p_index)
}
exp -= value.substr(p_index + 1, value.len).len
}
d_value := big.integer_from_string(int_string) or {
return error('can\'t convert ${value} to decimal')
}
return Decimal{
value: d_value
exp: exp
}
}
// decimal_from_int converts an int to Decimal.
pub fn decimal_from_int(a int) Decimal {
return new(a, 0)
}
// int_part returns the integer component of the decimal.
pub fn (d Decimal) int_part() int {
scaled := d.rescale(0)
return scaled.value.int()
}
// rescale returns a rescaled version of the decimal. Returned
// decimal may be less precise if the given exponent is bigger
// than the initial exponent of the Decimal.
// NOTE: this will truncate, NOT round
//
// Example:
//
// d := new(12345, -4)
// d2 := d.rescale(-1)
// d3 := d2.rescale(-4)
// println(d)
// println(d2)
// println(d3)
//
// Output:
//
// 1.2345
// 1.2
// 1.2000
//
fn (d Decimal) rescale(exp int) Decimal {
if d.exp == exp {
return d
}
diff := u32(math.abs(exp - d.exp))
mut value := d.value
ten_int := big.integer_from_int(10)
exp_scale := ten_int.pow(diff)
if exp > d.exp {
value /= exp_scale
} else if exp < d.exp {
value *= exp_scale
}
return Decimal{
value: value
exp: exp
}
}
// rescale_pair rescales two decimals to common exponential value (minimal exp of both decimals)
fn rescale_pair(d1 Decimal, d2 Decimal) (Decimal, Decimal) {
if d1.exp == d2.exp {
return d1, d2
}
base_scale := math.min(d1.exp, d2.exp)
if base_scale != d1.exp {
return d1.rescale(base_scale), d2
}
return d1, d2.rescale(base_scale)
}
// str returns the string representation of the decimal
// with the fixed point.
// Trailing zeroes in the fractional part are trimmed.
//
// Example:
//
// d := new(-12345, -3)
// println(d)
//
// Output:
//
// -12.345
//
pub fn (d Decimal) str() string {
if d.exp >= 0 {
return d.rescale(0).value.str()
}
abs := d.value.abs()
str := abs.str()
mut int_part := ''
mut fractional_part := ''
if str.len > -d.exp {
int_part = str.substr(0, str.len + d.exp)
fractional_part = str.substr(str.len + d.exp, str.len)
} else {
int_part = '0'
num_zeroes := -d.exp - str.len
fractional_part = strings.repeat(`0`, num_zeroes) + str
}
// Trim trailing zeroes
mut i := fractional_part.len - 1
for ; i >= 0; i-- {
if fractional_part[i] != `0` {
break
}
}
fractional_part = fractional_part.substr(0, i + 1)
mut number := int_part
if fractional_part.len > 0 {
number += '.' + fractional_part
}
if d.value.signum < 0 {
return '-' + number
}
return number
}
pub fn (decimal Decimal) + (addend Decimal) Decimal {
rd, rd2 := rescale_pair(decimal, addend)
result_value := rd.value + rd2.value
return Decimal{
value: result_value
exp: rd.exp
}
}
pub fn (decimal Decimal) - (subtrahend Decimal) Decimal {
rd, rd2 := rescale_pair(decimal, subtrahend)
result_value := rd.value - rd2.value
return Decimal{
value: result_value
exp: rd.exp
}
}
pub fn (decimal Decimal) * (multiplicand Decimal) Decimal {
exp_i64 := i64(decimal.exp) + i64(multiplicand.exp)
// better to panic than to give incorrect results as
// Decimals are usually used for money
if exp_i64 > i64(math.max_i32) || exp_i64 < i64(math.min_i32) {
panic('exponent ${exp_i64} overflows an int32')
}
result_value := decimal.value * multiplicand.value
return Decimal{
value: result_value
exp: int(exp_i64)
}
}
pub fn (a Decimal) == (b Decimal) bool {
rd_a, rd_b := rescale_pair(a, b)
return rd_a.value == rd_b.value
}
pub fn (a Decimal) < (b Decimal) bool {
rd_a, rd_b := rescale_pair(a, b)
return rd_a.value < rd_b.value
}