-
Notifications
You must be signed in to change notification settings - Fork 0
/
EximQueue.pm
369 lines (293 loc) · 7.27 KB
/
EximQueue.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
#!/usr/bin/perl
use warnings;
use strict;
################################################################################
package EximQueue;
use constant DEFAULT_QUEUE_DIR => "/var/spool/exim4";
sub new
{
my ($class, $dir) = @_;
$dir = DEFAULT_QUEUE_DIR unless defined $dir;
return bless {
DIR => $dir,
}, $class;
}
sub dir { $_[0]{DIR} }
sub scan
{
my ($self, $callback) = @_;
my $dir = $self->{DIR};
opendir(my $dh, "$dir/input") or die $!;
while (defined(my $id = readdir $dh))
{
$id =~ s/-H$// or next;
my $body_fh;
unless (open($body_fh, "<", "$dir/input/$id-D"))
{
next if $!{ENOENT};
warn "open $id-D: $!\n";
next;
}
scalar <$body_fh>;
my $bytes = -s($body_fh);
my $mtime = (stat _)[9];
$bytes -= tell($body_fh);
my $fh;
unless (open($fh, "<", "$dir/input/$id-H"))
{
close $body_fh;
next if $!{ENOENT};
warn "open $id-H: $!\n";
next;
}
my $ent = parse_h_fh($fh);
close $fh;
$ent->{queue} = $self;
$ent->{full_path} = "$dir/input/$id-H";
$ent->{message_id} = $id;
my $p = {
queue => $self,
full_path => "$dir/input/$id-H",
message_id => $id,
body_fh => $body_fh,
size => $bytes,
mtime => $mtime,
%$ent,
};
my $item = EximQueueItem->new($p);
&$callback($item);
}
closedir($dh);
}
sub parse_h_fh
{
my ($fh) = @_;
my $ent = {};
# See the Exim Spec, "Format of the -H file"
my $top = do { local $/; <$fh> };
$ent->{_all} = $top;
$top =~ s/\A(\w{6}-\w{6}-\w{2})-H\n// or die "? $top";
$ent->{id} = $1;
# username uid gid
$top =~ s/\A([\w-]+) (\d+) (\d+)\n// or die "? $top";
# sender
$top =~ s/\A<(.*)>\n// or die "? $top";
$ent->{sender} = $1;
# time received / number of delay warnings sent
$top =~ s/\A(\d+) (\d+)\n// or die "? $top";
# helo_name etc
while ($top =~ s/\A-(\w+)(?: (.*))?\n//)
{
my ($k, $v) = ($1, $2);
$v = "true" if not defined $v;
if ($k eq "acl" and $v =~ /^(\d+) (\d+)$/)
{
my ($varnum, $length) = ($1, $2);
$v = substr($top, 0, $length, '');
defined($v) or die;
$top =~ s/\A\n// or die "Newline missing after acl $varnum in $ent->{id}: $top";
$k = ($varnum < 10 ? "acl_c_$varnum" : "acl_m_".($varnum-10));
}
if ($k =~ /^acl[mc]$/ and $v =~ /^(\d+) (\d+)$/)
{
my ($varnum, $length) = ($1, $2);
$v = substr($top, 0, $length, '');
defined($v) or die;
$top =~ s/\A\n// or die "Newline missing after acl $varnum in $ent->{id}: $top";
$k = "acl_".substr($k,3,1)."_$varnum";
}
$ent->{options}{$k} = $v;
}
my %done_recipients;
unless ($top =~ s/\AXX\n//)
{
our $read_tree;
$read_tree = sub {
my ($indent) = (@_);
$top =~ s/\A([YN])([YN]) (.*)\n// or die "error reading $ent->{id}: $top";
my ($has_left, $has_right, $addr) = ($1, $2, $3);
$done_recipients{$addr} = 1;
my $out = "$addr\n";
$out = &$read_tree(" ") . $out if $has_left eq "Y";
$out = $out . &$read_tree(" ") if $has_right eq "Y";
$out =~ s/^/$indent/mg;
return $out;
};
$ent->{tree} = &$read_tree("");
}
$top =~ s/\A(\d+)\n// or die "? $top";
my $num_recipients = $1;
$ent->{num_recipients} = $num_recipients;
my %r;
for (1..$num_recipients)
{
$top =~ s/\A(\S+)\n// or die "? $top";
$r{$1} = ($done_recipients{$1} ? 1 : 0);
}
$ent->{rcpt} = \%r;
$top =~ s/\A\n// or die "? $top";
if (($ent->{options}{host_address}||"") =~ /^(\d+\.\d+\.\d+\.\d+)\.(\d+)$/)
{
$ent->{ip} = $1;
}
$ent->{s} = $ent->{sender};
$ent->{r} = $ent->{recipients};
open(my $hfh, "<", \$top);
($ent->{headers}, $ent->{last_headers}) = read_headers($hfh);
# use Data::Dumper;
# print Data::Dumper->Dump([ $ent ],[ 'ent' ]);
return $ent;
}
sub read_headers
{
my ($fh) = @_;
my $all = do { local $/; <$fh> };
my @h;
my %last;
while ($all)
{
$all =~ s/\A(\d+)(.) // or die "? $all";
my ($len, $flag) = ($1, $2);
$flag = "" if $flag eq " ";
my $data = substr($all, 0, $len, "");
chomp $data;
push @h, $data;
(my $tag, $data) = $data =~ /\A(.*?):\s*(.*)\z/s;
# push @h, [ $tag, $data, $flag ];
$data =~ s/\n\s+/ /g;
$last{lc $tag} = $data;
}
return(\@h, \%last);
}
################################################################################
package EximQueueItem;
sub new
{
my ($class, $p) = @_;
return bless $p, $class;
}
sub get_header
{
my ($self, $tag) = @_;
return $self->{last_headers}{lc $tag},
# TODO list context
}
sub get_sending_peer
{
my ($self) = @_;
return {
ptr => $self->{options}{host_name},
helo => $self->{options}{helo_name},
ip => $self->{ip},
}
}
sub move_to_queue
{
my ($self, $todir) = @_;
my $fromdir = $self->{queue}->dir;
unless ((stat $fromdir)[0] == (stat $todir)[0])
{
die "Can't move messages across filesystems";
}
if ((stat $fromdir)[1] == (stat $todir)[1])
{
die "Target directory is the same as source directory\n";
}
my $lockfh = $self->lock
or warn("Can't move locked message $self->{id}\n"), return;
my @files = (
"input/" . $self->{id} . "-H",
"input/" . $self->{id} . "-D",
"msglog/" . $self->{id},
);
# TODO how to claim and lock the ID in the target queue?
die "ID $self->{id} already exists in $todir"
if grep { -e "$todir/$_" } @files;
for my $file (@files)
{
rename "$fromdir/$file", "$todir/$file"
or warn "rename $fromdir/$file => $todir/$file: $!\n";
}
close $lockfh;
}
$^O eq "linux" or die "Unsupported platform";
*pack_fcntl = sub { pack "ssVVV", @_ };
use constant F_SETLK => 6; # Fcntl F_SETLK is actually F_SETLK64
sub lock
{
my ($self) = @_;
my $D = $self->{queue}->dir . "/input/" . $self->{id} . "-D";
open(my $fh, "+<", $D)
or die "open $D: $!";
use Fcntl qw( F_WRLCK SEEK_SET );
my $flock = pack_fcntl(
F_WRLCK, # type
SEEK_SET, # whence
0, # start
19, # len - length of an Exim ID (xxxxxx-yyyyyy-zz\n) plus a bit?
0, # pid
);
if (fcntl($fh, F_SETLK, $flock))
{
return $fh;
}
if ($!{EAGAIN} or $!{EACCES})
{
return undef;
}
die "fcntl F_SETLK on $D: $!";
}
sub compile_filter
{
my ($class, $filter) = @_;
$filter =~ /\S/ or return undef;
my %replace = (
IP => '$peer->{ip}',
ID => '$p->{message_id}',
SIZE => '$p->{size}',
SUBJECT => '$subject',
SENDER => '$p->{sender}',
RECIPIENTS => 'join("\n", keys %{ $p->{rcpt} })',
);
my $reIP = qr/\d+\.\d+\.\d+\.\d+/;
$filter =~ s/^($reIP)$/IP eq '$1'/g;
$filter =~ s/\b IP \s* (?:==?|eq) \s*($reIP) \b/IP eq '$1'/gx;
$filter =~ s/\b IP \s* (?:!=|<>|ne) \s*($reIP) \b/IP ne '$1'/gx;
my $re = join "|", keys %replace;
$filter =~ s/\b($re)\b/$replace{$1}/g;
warn "Using filter: $filter " if $ENV{DEBUG};
my $sub = eval '
sub {
my $p = shift;
my $r = $p->{rcpt};
my $peer = $p->get_sending_peer;
my $subject = $p->get_header("Subject");
no warnings "uninitialized";
' . $filter . '
}
';
die "Failed to compile filter ($filter): $@" if $@;
return $sub;
}
sub matches_filter
{
my ($self, $filter) = @_;
return 1 unless defined $filter;
return &$filter($self);
}
################################################################################
unless (caller)
{
my $q = EximQueue->new;
$q->scan_remote(sub {
my $p = shift;
() = $p->get_sending_peer;
$p->{subject} = $p->get_header("Subject");
$p->{contenttype} = $p->get_header("Content-Type");
use Data::Dumper;
print Data::Dumper->Dump([ $p ],[ 'p' ]);
print "\n";
});
}
1;
# eof