-
-
Notifications
You must be signed in to change notification settings - Fork 1.3k
/
REAModule.mm
344 lines (289 loc) · 10.7 KB
/
REAModule.mm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
#import <React/RCTBridge+Private.h>
#ifdef RCT_NEW_ARCH_ENABLED
#import <React/RCTFabricSurface.h>
#import <React/RCTScheduler.h>
#import <React/RCTSurface.h>
#import <React/RCTSurfacePresenter.h>
#import <React/RCTSurfacePresenterBridgeAdapter.h>
#import <React/RCTSurfaceView.h>
#if REACT_NATIVE_MINOR_VERSION < 73
#import <React/RCTRuntimeExecutorFromBridge.h>
#endif // REACT_NATIVE_MINOR_VERSION < 73
#endif // RCT_NEW_ARCH_ENABLED
#ifdef RCT_NEW_ARCH_ENABLED
#import <RNReanimated/REAInitializerRCTFabricSurface.h>
#endif // RCT_NEW_ARCH_ENABLED
#import <RNReanimated/NativeProxy.h>
#import <RNReanimated/REAModule.h>
#import <RNReanimated/REANodesManager.h>
#import <RNReanimated/REAUIKit.h>
#import <RNReanimated/RNRuntimeDecorator.h>
#import <RNReanimated/ReanimatedJSIUtils.h>
#import <RNReanimated/SingleInstanceChecker.h>
#import <RNReanimated/WorkletRuntime.h>
#import <RNReanimated/WorkletRuntimeCollector.h>
#if __has_include(<UIKit/UIAccessibility.h>)
#import <UIKit/UIAccessibility.h>
#endif // __has_include(<UIKit/UIAccessibility.h>)
using namespace facebook::react;
using namespace reanimated;
@interface RCTBridge (JSIRuntime)
- (void *)runtime;
@end
@interface RCTBridge (RCTTurboModule)
- (std::shared_ptr<facebook::react::CallInvoker>)jsCallInvoker;
- (void)_tryAndHandleError:(dispatch_block_t)block;
@end
#ifdef RCT_NEW_ARCH_ENABLED
static __strong REAInitializerRCTFabricSurface *reaSurface;
#else
typedef void (^AnimatedOperation)(REANodesManager *nodesManager);
#endif // RCT_NEW_ARCH_ENABLED
@implementation REAModule {
#ifdef RCT_NEW_ARCH_ENABLED
__weak RCTSurfacePresenter *_surfacePresenter;
std::weak_ptr<NativeReanimatedModule> weakNativeReanimatedModule_;
#else
NSMutableArray<AnimatedOperation> *_operations;
#endif // RCT_NEW_ARCH_ENABLED
#ifndef NDEBUG
SingleInstanceChecker<REAModule> singleInstanceChecker_;
#endif // NDEBUG
bool hasListeners;
bool _isBridgeless;
}
@synthesize moduleRegistry = _moduleRegistry;
#if REACT_NATIVE_MINOR_VERSION >= 74 && defined(RCT_NEW_ARCH_ENABLED)
@synthesize runtimeExecutor = _runtimeExecutor;
#endif // REACT_NATIVE_MINOR_VERSION >= 74 && defined(RCT_NEW_ARCH_ENABLED)
RCT_EXPORT_MODULE(ReanimatedModule);
#ifdef RCT_NEW_ARCH_ENABLED
+ (BOOL)requiresMainQueueSetup
{
return YES;
}
#endif // RCT_NEW_ARCH_ENABLED
- (void)invalidate
{
#ifdef RCT_NEW_ARCH_ENABLED
[[NSNotificationCenter defaultCenter] removeObserver:self];
#endif // RCT_NEW_ARCH_ENABLED
[_nodesManager invalidate];
[super invalidate];
}
- (dispatch_queue_t)methodQueue
{
// This module needs to be on the same queue as the UIManager to avoid
// having to lock `_operations` and `_preOperations` since `uiManagerWillPerformMounting`
// will be called from that queue.
return RCTGetUIManagerQueue();
}
#ifdef RCT_NEW_ARCH_ENABLED
- (std::shared_ptr<UIManager>)getUIManager
{
RCTScheduler *scheduler = [_surfacePresenter scheduler];
return scheduler.uiManager;
}
- (void)injectDependencies:(jsi::Runtime &)runtime
{
const auto &uiManager = [self getUIManager];
react_native_assert(uiManager.get() != nil);
if (auto nativeReanimatedModule = weakNativeReanimatedModule_.lock()) {
nativeReanimatedModule->initializeFabric(uiManager);
}
}
#pragma mark-- Initialize
- (void)installReanimatedAfterReload
{
// called from REAInitializerRCTFabricSurface::start
__weak __typeof__(self) weakSelf = self;
_surfacePresenter = self.bridge.surfacePresenter;
[_nodesManager setSurfacePresenter:_surfacePresenter];
// to avoid deadlock we can't use Executor from React Native
// but we can create own and use it because initialization is already synchronized
react_native_assert(self.bridge != nil);
RCTRuntimeExecutorFromBridge(self.bridge)(^(jsi::Runtime &runtime) {
if (__typeof__(self) strongSelf = weakSelf) {
[strongSelf injectDependencies:runtime];
}
});
}
- (void)handleJavaScriptDidLoadNotification:(NSNotification *)notification
{
[self attachReactEventListener];
}
- (void)attachReactEventListener
{
RCTScheduler *scheduler = [_surfacePresenter scheduler];
__weak __typeof__(self) weakSelf = self;
_surfacePresenter.runtimeExecutor(^(jsi::Runtime &runtime) {
__typeof__(self) strongSelf = weakSelf;
if (strongSelf == nil) {
return;
}
if (auto nativeReanimatedModule = strongSelf->weakNativeReanimatedModule_.lock()) {
auto eventListener =
std::make_shared<facebook::react::EventListener>([nativeReanimatedModule](const RawEvent &rawEvent) {
if (!RCTIsMainQueue()) {
// event listener called on the JS thread, let's ignore this event
// as we cannot safely access worklet runtime here
// and also we don't care about topLayout events
return false;
}
return nativeReanimatedModule->handleRawEvent(rawEvent, CACurrentMediaTime() * 1000);
});
[scheduler addEventListener:eventListener];
}
});
}
#pragma mark-- Bridgeless methods
/*
* Taken from RCTNativeAnimatedTurboModule:
* This selector is invoked via BridgelessTurboModuleSetup.
*/
- (void)setSurfacePresenter:(id<RCTSurfacePresenterStub>)surfacePresenter
{
_surfacePresenter = surfacePresenter;
_isBridgeless = true;
}
- (void)setBridge:(RCTBridge *)bridge
{
[super setBridge:bridge];
// only within the first loading `self.bridge.surfacePresenter` exists
// during the reload `self.bridge.surfacePresenter` is null
if (self.bridge.surfacePresenter) {
_surfacePresenter = self.bridge.surfacePresenter;
}
[self setReaSurfacePresenter];
_nodesManager = [[REANodesManager alloc] initWithModule:self bridge:bridge surfacePresenter:_surfacePresenter];
[[NSNotificationCenter defaultCenter] addObserver:self
selector:@selector(handleJavaScriptDidLoadNotification:)
name:RCTJavaScriptDidLoadNotification
object:nil];
[[self.moduleRegistry moduleForName:"EventDispatcher"] addDispatchObserver:self];
}
- (void)setReaSurfacePresenter
{
if (reaSurface == nil) {
// we need only one instance because SurfacePresenter is the same during the application lifetime
reaSurface = [[REAInitializerRCTFabricSurface alloc] init];
[_surfacePresenter registerSurface:reaSurface];
}
reaSurface.reaModule = self;
}
#else // RCT_NEW_ARCH_ENABLED
- (void)setBridge:(RCTBridge *)bridge
{
[super setBridge:bridge];
_nodesManager = [[REANodesManager alloc] initWithModule:self uiManager:self.bridge.uiManager];
_operations = [NSMutableArray new];
[bridge.uiManager.observerCoordinator addObserver:self];
_animationsManager = [[REAAnimationsManager alloc] initWithUIManager:bridge.uiManager];
}
#pragma mark-- Batch handling
- (void)addOperationBlock:(AnimatedOperation)operation
{
[_operations addObject:operation];
}
#pragma mark - RCTUIManagerObserver
- (void)uiManagerWillPerformMounting:(RCTUIManager *)uiManager
{
[_nodesManager maybeFlushUpdateBuffer];
if (_operations.count == 0) {
return;
}
NSArray<AnimatedOperation> *operations = _operations;
_operations = [NSMutableArray new];
REANodesManager *nodesManager = _nodesManager;
[uiManager
addUIBlock:^(__unused RCTUIManager *manager, __unused NSDictionary<NSNumber *, REAUIView *> *viewRegistry) {
for (AnimatedOperation operation in operations) {
operation(nodesManager);
}
[nodesManager operationsBatchDidComplete];
}];
}
#endif // RCT_NEW_ARCH_ENABLED
#pragma mark-- Events
- (NSArray<NSString *> *)supportedEvents
{
return @[ @"onReanimatedCall", @"onReanimatedPropsChange" ];
}
- (void)eventDispatcherWillDispatchEvent:(id<RCTEvent>)event
{
// Events can be dispatched from any queue
[_nodesManager dispatchEvent:event];
}
- (void)startObserving
{
hasListeners = YES;
}
- (void)stopObserving
{
hasListeners = NO;
}
- (void)sendEventWithName:(NSString *)eventName body:(id)body
{
if (hasListeners) {
[super sendEventWithName:eventName body:body];
}
}
RCT_EXPORT_BLOCKING_SYNCHRONOUS_METHOD(installTurboModule : (nonnull NSString *)valueUnpackerCode)
{
if (_isBridgeless) {
#if REACT_NATIVE_MINOR_VERSION >= 74 && defined(RCT_NEW_ARCH_ENABLED)
RCTCxxBridge *cxxBridge = (RCTCxxBridge *)[RCTBridge currentBridge];
auto &rnRuntime = *(jsi::Runtime *)cxxBridge.runtime;
auto executorFunction = ([executor = _runtimeExecutor](std::function<void(jsi::Runtime & runtime)> &&callback) {
// Convert to Objective-C block so it can be captured properly.
__block auto callbackBlock = callback;
[executor execute:^(jsi::Runtime &runtime) {
callbackBlock(runtime);
}];
});
auto nativeReanimatedModule = reanimated::createReanimatedModuleBridgeless(
_moduleRegistry, rnRuntime, std::string([valueUnpackerCode UTF8String]), executorFunction);
[self attachReactEventListener];
[self commonInit:nativeReanimatedModule withRnRuntime:rnRuntime];
#else // REACT_NATIVE_MINOR_VERSION >= 74 && defined(RCT_NEW_ARCH_ENABLED)
[NSException raise:@"Missing bridge" format:@"[Reanimated] Failed to obtain the bridge."];
#endif // REACT_NATIVE_MINOR_VERSION >= 74 && defined(RCT_NEW_ARCH_ENABLED)
} else {
facebook::jsi::Runtime *jsiRuntime = [self.bridge respondsToSelector:@selector(runtime)]
? reinterpret_cast<facebook::jsi::Runtime *>(self.bridge.runtime)
: nullptr;
if (jsiRuntime) {
auto nativeReanimatedModule = reanimated::createReanimatedModule(
self.bridge, self.bridge.jsCallInvoker, std::string([valueUnpackerCode UTF8String]));
jsi::Runtime &rnRuntime = *jsiRuntime;
[self commonInit:nativeReanimatedModule withRnRuntime:rnRuntime];
}
}
return @YES;
}
#ifdef RCT_NEW_ARCH_ENABLED
- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:
(const facebook::react::ObjCTurboModule::InitParams &)params
{
return std::make_shared<facebook::react::NativeReanimatedModuleSpecJSI>(params);
}
#endif // RCT_NEW_ARCH_ENABLED
- (void)commonInit:(std::shared_ptr<NativeReanimatedModule>)nativeReanimatedModule
withRnRuntime:(jsi::Runtime &)rnRuntime
{
#if __has_include(<UIKit/UIAccessibility.h>)
auto isReducedMotion = UIAccessibilityIsReduceMotionEnabled();
#else
auto isReducedMotion = NSWorkspace.sharedWorkspace.accessibilityDisplayShouldReduceMotion;
#endif
WorkletRuntimeCollector::install(rnRuntime);
RNRuntimeDecorator::decorate(rnRuntime, nativeReanimatedModule, isReducedMotion);
#ifdef RCT_NEW_ARCH_ENABLED
weakNativeReanimatedModule_ = nativeReanimatedModule;
if (self->_surfacePresenter != nil) {
// reload, uiManager is null right now, we need to wait for `installReanimatedAfterReload`
[self injectDependencies:rnRuntime];
}
#endif // RCT_NEW_ARCH_ENABLED
}
@end