build.bat

@ECHO OFF
REM ---------------------------------------------------------------------------------------

REM Script to build the resource and UI files. You only really need to run this if you are
REM running from source.

REM Change %OSGEO4W_ROOT% in setenv.bat to change the location of QGIS, if necessary.

REM ---------------------------------------------------------------------------------------

IF /I NOT "%~1"=="help" CALL scripts\setenv.bat
IF "%~1"=="" GOTO build
GOTO %1

:build
IF EXIST build RMDIR /q /s build & ECHO Removing existing build folder..
ECHO Installing requirements..
python -m pip install -r requirements.txt
ECHO Building application..
python setup.py build
IF /I "%~1"=="release" GOTO zip
GOTO END

:zip
IF NOT EXIST release MKDIR release
IF EXIST release\*.zip DEL release\*.zip /Q /F & ECHO Removing existing zip files..
ECHO Building zip file..
SET NAME=%~2
python -m zipfile -c "release\Roam%NAME%.zip" "build\Roam"
IF /I "%~1"=="release" GOTO installer
GOTO END

:installer
IF NOT EXIST %INSTALLER% ECHO  Installer build failed - installer could not be located   & GOTO END
IF NOT EXIST release MKDIR release
IF EXIST release\*.exe DEL release\*.exe /Q /F & ECHO Removing existing installers..
ECHO Building installer...
SET NAME=%~2
%INSTALLER%\iscc /F"Roam%NAME% Installer" "scripts\installer\roam-installer.iss"
IF /I "%~1"=="release" ECHO Build complete and zip file and installer created
GOTO END

:release
ECHO Running complete build..
GOTO build

:test
@ECHO ON
ECHO Running tests
pytest --cov=src\roam src\roam_tests --cov-report html --cov-report term
GOTO END

:test-only
ECHO Running tests
pytest src\roam_tests
GOTO END

:design
ECHO Opening designer
START designer.exe
GOTO END

:watch
python scripts\watchui.py
EXIT

:api-docs
pdoc .\src\roam\ .\src\configmanager\ -o .\docs
GOTO END

:help
ECHO ===========================
ECHO        OPTIONS
ECHO ===========================
ECHO build
ECHO build zip
ECHO build installer
ECHO build release
ECHO build test
ECHO build test-only
ECHO build design
ECHO build watch
ECHO build api-docs
ECHO.
ECHO For zip, installer and release, version details can be added
ECHO eg. build installer " 3.0"
GOTO END

:END