-
Notifications
You must be signed in to change notification settings - Fork 1
/
qualifiedDCToISO19139v1.0.xslt
2042 lines (2011 loc) · 118 KB
/
qualifiedDCToISO19139v1.0.xslt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:gmd="http://www.isotc211.org/2005/gmd"
xmlns:gco="http://www.isotc211.org/2005/gco"
xmlns:gml="http://www.opengis.net/gml/3.2"
xmlns:xlink="http://www.w3.org/1999/xlink"
xmlns:datetime="http://exslt.org/dates-and-times"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:ows="http://www.opengis.net/ows"
xmlns:dct="http://purl.org/dc/terms/"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns:dcmiBox="http://dublincore.org/documents/2000/07/11/dcmi-box/"
exclude-result-prefixes="datetime">
<xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no" indent="yes"/>
<!--
SMR 2018-04-06
Version 1.0 2018-04-25
Transform qualified DC XML metadata to ISO 19139
Version 1.0.1 2018-07-25
update handling of @scheme or @dct:scheme on dct:references to populate gmd:applicationProfile
in CI_OnlineResource elements.
Change title handler to handle only first dc:title if there are >1 titles.
-->
<!-- * @copyright 2018 Stephen M Richard.
All Rights Reserved.
* Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software distributed under the License is
distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and limitations under the License -->
<!-- The contact for the metadata - static value; customize for your application. -->
<xsl:template name="metadatacontact">
<gmd:contact>
<gmd:CI_ResponsibleParty>
<gmd:organisationName>
<gco:CharacterString>CINERGI Metadata catalog</gco:CharacterString>
</gmd:organisationName>
<gmd:contactInfo>
<gmd:CI_Contact>
<gmd:address>
<gmd:CI_Address>
<gmd:electronicMailAddress>
<!--<gco:CharacterString>info@EarthChem.org</gco:CharacterString>-->
<gco:CharacterString>
<xsl:value-of select="'cinergi@sdsc.edu'"/>
</gco:CharacterString>
</gmd:electronicMailAddress>
</gmd:CI_Address>
</gmd:address>
</gmd:CI_Contact>
</gmd:contactInfo>
<gmd:role>
<gmd:CI_RoleCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_RoleCode"
codeListValue="pointOfContact">pointOfContact</gmd:CI_RoleCode>
</gmd:role>
</gmd:CI_ResponsibleParty>
</gmd:contact>
</xsl:template>
<!-- define variables for top level elements in dc xml to simplify xpaths... -->
<xsl:variable name="dc-identifier" select="//*[local-name() = 'identifier']"/>
<xsl:variable name="dc-title">
<!-- make sure something gets put in the title, if there are multiple titles, only take the first -->
<!-- TBD if have multiple title elements, put others in alternate title -->
<xsl:choose>
<xsl:when test="string-length(//*[local-name() = 'title'][1])>0">
<xsl:value-of select="//*[local-name() = 'title'][1]"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="string('No title provided')"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<!-- <xsl:variable name="dc-alternateIDs" select="//*[local-name() = 'alternateIdentifiers']"/>-->
<xsl:variable name="dc-contributors" select="//*[local-name() = 'contributor']"/>
<!-- dc: or dct: -->
<xsl:variable name="dc-creators" select="//*[local-name() = 'creator']"/>
<xsl:variable name="dc-dates" select="//*[contains($dcdates, local-name())]"/>
<xsl:variable name="smallcase" select="'abcdefghijklmnopqrstuvwxyz'"/>
<xsl:variable name="uppercase" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
<!-- don't include references because that will be called out for distribution links -->
<xsl:variable name="dcrelation"
select="'relation|hasVersion|isVersionOf|isReplacedBy|replaces|isRequiredBy|requires|isPartOf|hasPart|isReferencedBy|isFormatOf|hasFormat|conformsTo'"/>
<xsl:variable name="dcdates"
select="'date|created|valid|available|issued|modified|dateAccepted|dateCopyrighted|dateSubmitted'"/>
<!-- these variables set content for gmd:metadataMaintenance element at the end of the record
recommend using these to report on how this record was created and by who. -->
<xsl:variable name="metaMaintenanceNote"
select="
string('This metadata record was generated by an xslt transformation from a dc metadata record; Transform by Stephen M. Richard, based on a transform by Damian Ulbricht. ')"/>
<xsl:variable name="maintenanceContactID" select="string('')"/>
<xsl:variable name="maintenanceContactName" select="string('CINERGI metadata curator')"/>
<xsl:variable name="maintenanceContactEmail" select="string('valentin@sdsc.edu')"/>
<xsl:variable name="currentDateTime">
<xsl:value-of select="datetime:date-time()"/>
</xsl:variable>
<!-- end of configuration variables -->
<!-- here we go..... -->
<xsl:template match="/">
<gmd:MD_Metadata xmlns:gmd="http://www.isotc211.org/2005/gmd"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:gco="http://www.isotc211.org/2005/gco" xmlns:gml="http://www.opengis.net/gml/3.2"
xsi:schemaLocation="http://www.isotc211.org/2005/gmd http://standards.iso.org/ittf/PubliclyAvailableStandards/ISO_19139_Schemas/gmd/gmd.xsd">
<!-- The fileIdentifier identifies the
metadata record, not the described resource which is identified by a DOI.
-->
<xsl:variable name="fileIdentifierPrefix" select="string('urn:dciso:')"/>
<gmd:fileIdentifier>
<gco:CharacterString>
<xsl:choose>
<xsl:when test="string-length($dc-identifier[1]) > 0">
<xsl:value-of
select="concat($fileIdentifierPrefix, string('metadataabout:'), normalize-space(translate($dc-identifier[1], '/:', '--')))"
/>
</xsl:when>
<!-- <xsl:when
test="count($dc-alternateIDs/*[local-name() = 'alternateIdentifier'][@alternateIdentifierType = 'IEDA submission_ID']) > 0">
<xsl:value-of
select="
concat($fileIdentifierPrefix, string('metadataabout:'),
normalize-space(substring-after($dc-alternateIDs/*[local-name() = 'alternateIdentifier'][@alternateIdentifierType = 'IEDA submission_ID']/text(), 'urn:')))"
/>
</xsl:when>-->
<xsl:otherwise>
<xsl:value-of
select="concat($fileIdentifierPrefix, string('metadata:'), normalize-space(translate($dc-title, '/: ,', '----')))"
/>
</xsl:otherwise>
</xsl:choose>
</gco:CharacterString>
</gmd:fileIdentifier>
<gmd:language>
<gmd:LanguageCode codeList="http://www.loc.gov/standards/iso639-2/"
codeListValue="eng">eng</gmd:LanguageCode>
</gmd:language>
<gmd:characterSet>
<gmd:MD_CharacterSetCode
codeList="http://www.isotc211.org/2005/resources/codeList.xml#MD_CharacterSetCode"
codeListValue="utf8"/>
</gmd:characterSet>
<xsl:variable name="MDScopelist"
select="string('http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#MD_ScopeCode')"/>
<xsl:variable name="seriesScope" select="'Collection'"/>
<xsl:variable name="datasetScope"
select="'Dataset|Event|Image|MovingImage|StillImage|Sound|Text|PhysicalObject'"/>
<xsl:variable name="serviceScope" select="'InteractiveResource|Service'"/>
<xsl:variable name="softwareScope" select="'Software'"/>
<xsl:for-each select="//*[local-name() = 'type']">
<gmd:hierarchyLevel>
<gmd:MD_ScopeCode>
<xsl:attribute name="codeList">
<xsl:value-of select="$MDScopelist"/>
</xsl:attribute>
<xsl:attribute name="codeListValue">
<xsl:choose>
<xsl:when test="contains($seriesScope, normalize-space(string(.)))">
<xsl:value-of select="string('series')"/>
</xsl:when>
<xsl:when test="contains($datasetScope, normalize-space(string(.)))">
<xsl:value-of select="string('dataset')"/>
</xsl:when>
<xsl:when test="contains($serviceScope, normalize-space(string(.)))">
<xsl:value-of select="string('service')"/>
</xsl:when>
<xsl:when
test="contains($softwareScope, normalize-space(string(.)))">
<xsl:value-of select="string('software')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="string('dataset')"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:value-of select="normalize-space(string(.))"/>
</gmd:MD_ScopeCode>
</gmd:hierarchyLevel>
</xsl:for-each>
<!-- The contact for the metadata - static value assigned in template at the top of this file; -->
<xsl:call-template name="metadatacontact"/>
<gmd:dateStamp>
<gco:DateTime>
<xsl:value-of select="$currentDateTime"/>
</gco:DateTime>
</gmd:dateStamp>
<gmd:metadataStandardName>
<gco:CharacterString>ISO 19139 Geographic Information - Metadata - Implementation Specification</gco:CharacterString>
</gmd:metadataStandardName>
<gmd:metadataStandardVersion>
<gco:CharacterString>2007</gco:CharacterString>
</gmd:metadataStandardVersion>
<gmd:identificationInfo>
<gmd:MD_DataIdentification>
<gmd:citation>
<gmd:CI_Citation>
<gmd:title>
<gco:CharacterString>
<xsl:value-of select="normalize-space(string($dc-title))"/>
</gco:CharacterString>
</gmd:title>
<xsl:for-each select="//*[local-name() = 'alternative']">
<gmd:alternateTitle>
<gco:CharacterString>
<xsl:value-of select="normalize-space(string(.))"/>
</gco:CharacterString>
</gmd:alternateTitle>
</xsl:for-each>
<xsl:call-template name="resourcedates"/>
<xsl:for-each select="$dc-identifier">
<gmd:identifier>
<gmd:MD_Identifier>
<gmd:code>
<gco:CharacterString>
<xsl:value-of select="normalize-space(string(.))"/>
</gco:CharacterString>
</gmd:code>
</gmd:MD_Identifier>
</gmd:identifier>
</xsl:for-each>
<xsl:call-template name="creators"/>
<xsl:call-template name="contributors"/>
<xsl:for-each select="//*[local-name() = 'publisher']">
<gmd:citedResponsibleParty>
<xsl:call-template name="ci_responsibleparty">
<xsl:with-param name="organisation">
<xsl:value-of select="normalize-space(string(.))"/>
</xsl:with-param>
<xsl:with-param name="role">publisher</xsl:with-param>
</xsl:call-template>
</gmd:citedResponsibleParty>
</xsl:for-each>
<xsl:for-each select="//*[local-name() = 'rightsHolder']">
<gmd:citedResponsibleParty>
<xsl:call-template name="ci_responsibleparty">
<xsl:with-param name="organisation">
<xsl:value-of select="normalize-space(string(.))"/>
</xsl:with-param>
<xsl:with-param name="role">owner</xsl:with-param>
</xsl:call-template>
</gmd:citedResponsibleParty>
</xsl:for-each>
<xsl:if
test="
//*[local-name() = 'audience'] | //*[local-name() = 'mediator']
| //*[local-name() = 'educationLevel']
| //*[local-name() = 'bibliographicCitation']
| //*[local-name() = 'instructionalMethod']
| //*[local-name() = 'extent']">
<gmd:otherCitationDetails>
<gco:CharacterString>
<xsl:for-each
select="
//*[local-name() = 'audience'] | //*[local-name() = 'mediator']
| //*[local-name() = 'educationLevel']
| //*[local-name() = 'bibliographicCitation']
| //*[local-name() = 'instructionalMethod']
| //*[local-name() = 'extent']">
<xsl:value-of
select="concat(local-name(), ': ', normalize-space(string(.)), '; ')"
/>
</xsl:for-each>
</gco:CharacterString>
</gmd:otherCitationDetails>
</xsl:if>
</gmd:CI_Citation>
</gmd:citation>
<gmd:abstract>
<gco:CharacterString>
<xsl:for-each select="//*[local-name() = 'description']">
<xsl:value-of
select="concat('description: ', normalize-space(string(.)))"/>
<xsl:if test="following::*[local-name() = 'description']">
<xsl:text>; </xsl:text>
</xsl:if>
</xsl:for-each>
<xsl:if
test="//*[local-name() = 'abstract'] and //*[local-name() = 'description']">
<xsl:text>; </xsl:text>
</xsl:if>
<xsl:for-each select="//*[local-name() = 'abstract']">
<xsl:value-of
select="concat('abstract: ', normalize-space(string(.)))"/>
<xsl:if test="following::*[local-name() = 'abstract']">
<xsl:text>; </xsl:text>
</xsl:if>
</xsl:for-each>
<xsl:if
test="
(//*[local-name() = 'abstract'] or //*[local-name() = 'description'])
and //*[local-name() = 'tableOfContents']">
<xsl:text>; </xsl:text>
</xsl:if>
<xsl:for-each select="//*[local-name() = 'tableOfContents']">
<xsl:value-of
select="concat('tableOfContents: ', normalize-space(string(.)))"/>
<xsl:if test="following::*[local-name() = 'tableOfContents']">
<xsl:text>; </xsl:text>
</xsl:if>
</xsl:for-each>
</gco:CharacterString>
</gmd:abstract>
<!-- <gmd:status>
<gmd:MD_ProgressCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#MD_ProgressCode"
codeListValue="Complete">Complete</gmd:MD_ProgressCode>
</gmd:status>
-->
<!-- gmd:pointOfContact -->
<xsl:call-template name="datasetcontact"/>
<!-- put dc:accrual stuff in resource maintenance -->
<xsl:if test="//*[contains(local-name(), 'accrual')]">
<gmd:resourceMaintenance>
<gmd:MD_MaintenanceInformation>
<xsl:choose>
<xsl:when test="//*[local-name() = 'accrualPeriodicity']">
<gmd:maintenanceAndUpdateFrequency>
<gmd:MD_MaintenanceFrequencyCode>
<xsl:attribute name="codeList">
<xsl:value-of
select="string('http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#MD_MaintenanceFrequencyCode')"
/>
</xsl:attribute>
<xsl:attribute name="codeListValue">
<xsl:value-of select="string('unknown')"/>
<!-- there might be a mapping from accrualPeriodicity to the
ISO codelist..., but this is quick fix for now to be sure its valid-->
</xsl:attribute>
<xsl:value-of
select="normalize-space(string(//*[local-name() = 'accrualPeriodicity'][1]))"
/>
</gmd:MD_MaintenanceFrequencyCode>
</gmd:maintenanceAndUpdateFrequency>
</xsl:when>
<xsl:otherwise>
<gmd:maintenanceAndUpdateFrequency gco:nilReason="missing"/>
</xsl:otherwise>
</xsl:choose>
<xsl:for-each
select="
//*[local-name() = 'accrualMethod']
| //*[local-name() = 'accrualPolicy']">
<gmd:maintenanceNote>
<gco:CharacterString>
<xsl:value-of
select="concat(local-name(), ': ', normalize-space(string(.)))"
/>
</gco:CharacterString>
</gmd:maintenanceNote>
</xsl:for-each>
</gmd:MD_MaintenanceInformation>
</gmd:resourceMaintenance>
</xsl:if>
<xsl:call-template name="versionandformat"/>
<xsl:call-template name="temporalkeywords"/>
<xsl:call-template name="geolocationplace"/>
<xsl:call-template name="keywords"/>
<xsl:call-template name="license"/>
<xsl:call-template name="relatedResources">
<xsl:with-param name="relres"
select="//*[contains($dcrelation, local-name())]"/>
<!-- pass a set of related identifier nodes -->
</xsl:call-template>
<!-- assume english for now -->
<xsl:choose>
<xsl:when test="//*[local-name() = 'language']">
<xsl:for-each select="//*[local-name() = 'language']">
<gmd:language>
<gco:CharacterString>
<xsl:value-of select="normalize-space(string(.))"/>
</gco:CharacterString>
</gmd:language>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<gmd:language gco:nilReason="missing"/>
</xsl:otherwise>
</xsl:choose>
<gmd:characterSet/>
<gmd:topicCategory/>
<gmd:environmentDescription/>
<!-- handle spatial and temporal extent -->
<xsl:for-each select="//*[local-name() = 'coverage']">
<gmd:extent>
<gmd:EX_Extent>
<gmd:description>
<gco:CharacterString>
<xsl:value-of
select="concat('dc:coverage: ', normalize-space(string(.)))"
/>
</gco:CharacterString>
</gmd:description>
</gmd:EX_Extent>
</gmd:extent>
</xsl:for-each>
<xsl:call-template name="spatialcoverage"/>
<xsl:call-template name="temporalcoverage"/>
</gmd:MD_DataIdentification>
</gmd:identificationInfo>
<gmd:distributionInfo>
<gmd:MD_Distribution>
<gmd:transferOptions>
<gmd:MD_DigitalTransferOptions>
<xsl:call-template name="size"/>
<!-- dc:extent goes here -->
<xsl:for-each select="$dc-identifier">
<xsl:if
test="
starts-with(normalize-space(string(.)), 'doi:')
or starts-with(normalize-space(string(.)), 'http')">
<gmd:onLine>
<gmd:CI_OnlineResource>
<gmd:linkage>
<gmd:URL>
<xsl:choose>
<xsl:when
test="starts-with(normalize-space(string(.)), 'doi:')">
<xsl:value-of
select="concat('https://doi.org/', substring-after(normalize-space(string(.)), 'doi:'))"
/>
</xsl:when>
<xsl:when
test="starts-with(normalize-space(string(.)), 'http')">
<xsl:value-of select="normalize-space(string(.))"
/>
</xsl:when>
</xsl:choose>
</gmd:URL>
</gmd:linkage>
<gmd:protocol>
<gco:CharacterString>WWW:LINK-1.0-http--link</gco:CharacterString>
</gmd:protocol>
<gmd:name>
<gco:CharacterString>Landing Page</gco:CharacterString>
</gmd:name>
<gmd:description>
<gco:CharacterString>
<xsl:value-of
select="normalize-space(string('Link to landing page referenced by identifier'))"/>
</gco:CharacterString>
</gmd:description>
<gmd:function>
<gmd:CI_OnLineFunctionCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_OnLineFunctionCode"
codeListValue="information"
>dc:identifier</gmd:CI_OnLineFunctionCode>
</gmd:function>
</gmd:CI_OnlineResource>
</gmd:onLine>
</xsl:if>
</xsl:for-each>
<xsl:for-each select="//*[local-name() = 'references']">
<xsl:if test="starts-with(normalize-space(string(.)), 'http')">
<gmd:onLine>
<gmd:CI_OnlineResource>
<gmd:linkage>
<gmd:URL>
<xsl:value-of select="normalize-space(string(.))"
/>
</gmd:URL>
</gmd:linkage>
<gmd:protocol>
<gco:CharacterString>WWW:LINK-1.0-http--link</gco:CharacterString>
</gmd:protocol>
<xsl:if test="string-length(normalize-space(@scheme))>0 or
string-length(normalize-space(@dct:scheme))>0">
<gmd:applicationProfile>
<gco:CharacterString>
<xsl:choose>
<xsl:when test="string-length(normalize-space(@scheme))>0">
<xsl:value-of select="normalize-space(@scheme)"/>
</xsl:when>
<xsl:when test="string-length(normalize-space(@dct:scheme))>0">
<xsl:value-of select="normalize-space(@dct:scheme)"/>
</xsl:when>
</xsl:choose>
</gco:CharacterString>
</gmd:applicationProfile>
</xsl:if>
<gmd:name>
<gco:CharacterString>Dublin Core references URL</gco:CharacterString>
</gmd:name>
<gmd:description>
<gco:CharacterString>URL provided in Dublin Core references element</gco:CharacterString>
</gmd:description>
<gmd:function>
<gmd:CI_OnLineFunctionCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_OnLineFunctionCode"
codeListValue="information"
>dct:references</gmd:CI_OnLineFunctionCode>
</gmd:function>
</gmd:CI_OnlineResource>
</gmd:onLine>
</xsl:if>
</xsl:for-each>
<!-- if a medium is specified, interpretationis that its accessed offline. -->
<xsl:if test="//*[local-name() = 'medium']">
<gmd:offLine>
<gmd:MD_Medium>
<gmd:mediumNote>
<gco:CharacterString>
<xsl:for-each select="//*[local-name() = 'medium']">
<xsl:value-of select="normalize-space(string(.))"/>
<xsl:if
test="following::*[local-name() = 'medium']">
<xsl:text>; </xsl:text>
</xsl:if>
</xsl:for-each>
</gco:CharacterString>
</gmd:mediumNote>
</gmd:MD_Medium>
</gmd:offLine>
</xsl:if>
</gmd:MD_DigitalTransferOptions>
</gmd:transferOptions>
</gmd:MD_Distribution>
</gmd:distributionInfo>
<!-- put method descripiton in the lineage statement -->
<xsl:if test="//*[local-name() = 'provenance'] or //*[local-name() = 'source']">
<gmd:dataQualityInfo>
<gmd:DQ_DataQuality>
<gmd:scope gco:nilReason="missing"/>
<gmd:lineage>
<gmd:LI_Lineage>
<xsl:if test="//*[local-name() = 'provenance']">
<gmd:statement>
<gco:CharacterString>
<xsl:for-each select="//*[local-name() = 'provenance']">
<xsl:value-of select="normalize-space(string(.))"/>
<xsl:if
test="following::*[local-name() = 'provenance']">
<xsl:text>; </xsl:text>
</xsl:if>
</xsl:for-each>
</gco:CharacterString>
</gmd:statement>
</xsl:if>
<xsl:for-each select="//*[local-name() = 'source']">
<gmd:source>
<gmd:LI_Source>
<gmd:description>
<gco:CharacterString>
<xsl:value-of select="normalize-space(string(.))"
/>
</gco:CharacterString>
</gmd:description>
</gmd:LI_Source>
</gmd:source>
</xsl:for-each>
</gmd:LI_Lineage>
</gmd:lineage>
</gmd:DQ_DataQuality>
</gmd:dataQualityInfo>
</xsl:if>
<gmd:metadataMaintenance>
<gmd:MD_MaintenanceInformation>
<gmd:maintenanceAndUpdateFrequency gco:nilReason="unknown"/>
<gmd:maintenanceNote>
<gco:CharacterString>
<xsl:value-of
select="concat(string($metaMaintenanceNote), string(' Run on '), string($currentDateTime))"
/>
</gco:CharacterString>
</gmd:maintenanceNote>
<gmd:contact>
<xsl:if test="$maintenanceContactID != ''">
<xsl:attribute name="xlink:href">
<xsl:value-of select="$maintenanceContactID"/>
</xsl:attribute>
</xsl:if>
<gmd:CI_ResponsibleParty>
<gmd:individualName>
<gco:CharacterString>
<xsl:value-of select="$maintenanceContactName"/>
</gco:CharacterString>
</gmd:individualName>
<gmd:contactInfo>
<gmd:CI_Contact>
<gmd:address>
<gmd:CI_Address>
<gmd:electronicMailAddress>
<gco:CharacterString>
<xsl:value-of select="$maintenanceContactEmail"/>
</gco:CharacterString>
</gmd:electronicMailAddress>
</gmd:CI_Address>
</gmd:address>
</gmd:CI_Contact>
</gmd:contactInfo>
<gmd:role>
<gmd:CI_RoleCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_RoleCode"
codeListValue="processor">processor</gmd:CI_RoleCode>
</gmd:role>
</gmd:CI_ResponsibleParty>
</gmd:contact>
</gmd:MD_MaintenanceInformation>
</gmd:metadataMaintenance>
</gmd:MD_Metadata>
</xsl:template>
<!-- retrieves basic reference dates of the resource-->
<xsl:template name="resourcedates">
<!--<xsl:if test="$dc-dates/*[local-name() = 'date' and @dateType = 'Created'] != ''">-->
<!-- dct date types to ISO, ad hoc mapping, maybe there's some 'standard' mapping?
created - creation
valid - publication
available - publication
issued - publication
modified - revision
dateAccepted - publication
dateCopyrighted - publication
dateSubmitted - creation
-->
<xsl:choose>
<xsl:when test="$dc-dates">
<xsl:for-each select="$dc-dates">
<xsl:if test="normalize-space(string(.)) != ''">
<xsl:variable name="inputDate" select="normalize-space(string(.))"/>
<!-- YYYY-MM-DDTHH:MM:SS -->
<xsl:variable name="castableAsISODateTime"
select="
(substring($inputDate, 5, 1) = '-') and
(substring($inputDate, 8, 1) = '-') and
(substring($inputDate, 11, 1) = 'T') and
(substring($inputDate, 14, 1) = ':') and
(substring($inputDate, 17, 1) = ':')"/>
<!-- YYYY-MM-DD -->
<xsl:variable name="castableAsISODate"
select="
(substring($inputDate, 5, 1) = '-') and
(substring($inputDate, 8, 1) = '-') and
string-length($inputDate) = 10"/>
<!-- M/D/YYYY, MM/DD/YYYY, MM/YYYY, YYYY -->
<xsl:variable name="dayVal">
<xsl:choose>
<xsl:when test="string-length($inputDate) > 7">
<xsl:value-of select="substring-before($inputDate, '/')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="string('')"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="monthVal">
<!--select="substring-before(substring-after($inputDate,'/'),'/')"-->
<xsl:choose>
<xsl:when test="string-length(normalize-space($inputDate)) > 7">
<xsl:value-of
select="substring-before(substring-after($inputDate, '/'), '/')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="substring-before($inputDate, '/')"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="yearVal">
<!--select="substring-after(substring-after($inputDate,'/'),'/')"-->
<xsl:choose>
<xsl:when test="string-length(normalize-space($inputDate)) > 7">
<xsl:value-of
select="substring(substring-after(substring-after($inputDate, '/'), '/'), 1, 4)"
/>
</xsl:when>
<xsl:when test="string-length(normalize-space($inputDate)) = 4">
<xsl:value-of select="normalize-space($inputDate)"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="substring(substring-after($inputDate, '/'), 1, 4)"
/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="castableAsMDYDate" select="number($yearVal)"/>
<!-- YYYYMMDD -->
<xsl:variable name="castableAsFDate"
select="string-length($inputDate) <= 8 and number($inputDate)"/>
<gmd:date>
<xsl:if
test="
not($castableAsISODateTime or
$castableAsISODate or
$castableAsFDate or
$castableAsMDYDate)">
<!-- date is in format we don't have parser for -->
<!-- insert the date string in the xlink title so its in the result doc somewhere... -->
<xsl:attribute name="xlink:title">
<xsl:value-of select="concat('can not parse date:', normalize-space(string(.)))"/>
</xsl:attribute>
<xsl:attribute name="gco:nilReason">unknown</xsl:attribute>
</xsl:if>
<gmd:CI_Date>
<gmd:date>
<xsl:choose>
<xsl:when
test="
not($castableAsISODateTime or
$castableAsISODate or
$castableAsFDate or
$castableAsMDYDate)">
<!-- date is in format we don't have parser for -->
<xsl:attribute name="gco:nilReason">
<xsl:value-of select="string('unknown')"/>
</xsl:attribute>
</xsl:when>
<xsl:when test="$castableAsISODateTime">
<gco:DateTime>
<xsl:value-of select="normalize-space($inputDate)"/>
</gco:DateTime>
</xsl:when>
<xsl:when test="$castableAsISODate">
<gco:DateTime>
<xsl:value-of
select="concat(normalize-space($inputDate), 'T12:00:00')"
/>
</gco:DateTime>
</xsl:when>
<xsl:when test="$castableAsFDate">
<gco:DateTime>
<xsl:choose>
<xsl:when
test="string-length(normalize-space(string($inputDate))) = 8">
<xsl:value-of
select="
concat(substring(normalize-space(string($inputDate)), 0, 5), '-',
substring(normalize-space(string($inputDate)), 5, 2), '-',
substring(normalize-space(string($inputDate)), 7, 2),
'T12:00:00')"
/>
</xsl:when>
<xsl:when
test="string-length(normalize-space(string($inputDate))) = 6">
<xsl:value-of
select="
concat(substring(normalize-space(string($inputDate)), 0, 5), '-',
substring(normalize-space(string($inputDate)), 5, 2), '-01T12:00:00')"
/>
</xsl:when>
<xsl:when
test="string-length(normalize-space(string($inputDate))) = 4">
<xsl:value-of
select="concat(substring(normalize-space(string($inputDate)), 0, 5), '-01-01T12:00:00')"
/>
</xsl:when>
</xsl:choose>
</gco:DateTime>
</xsl:when>
<xsl:when test="$castableAsMDYDate">
<gco:DateTime>
<xsl:choose>
<xsl:when
test="number($dayVal) and number($monthVal) and number($yearVal)">
<xsl:value-of
select="
concat($yearVal, '-',
format-number($monthVal, '00'), '-', format-number($dayVal, '00'), 'T12:00:00')"
/>
</xsl:when>
<xsl:when test="number($monthVal) and number($yearVal)">
<xsl:value-of
select="
concat($yearVal, '-',
format-number($monthVal, '00'), '-', '01T12:00:00')"
/>
</xsl:when>
<xsl:when test="number($yearVal)">
<xsl:value-of
select="
concat($yearVal, '-',
'01-01T12:00:00')"
/>
</xsl:when>
</xsl:choose>
</gco:DateTime>
</xsl:when>
<!-- there is no otherwise, should have been caught before getting into this choose -->
</xsl:choose>
</gmd:date>
<gmd:dateType>
<xsl:choose>
<xsl:when test="local-name() = 'created'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="creation">created</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:when test="local-name() = 'valid'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="publication">valid</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:when test="local-name() = 'available'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="publication">available</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:when test="local-name() = 'issued'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="publication">issued</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:when test="local-name() = 'modified'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="revision">modified</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:when test="local-name() = 'dateAccepted'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="publication"
>dateAccepted</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:when test="local-name() = 'dateCopyrighted'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="publication"
>dateCopyrighted</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:when test="local-name() = 'dateSubmitted'">
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="creation">dateSubmitted</gmd:CI_DateTypeCode>
</xsl:when>
<xsl:otherwise>
<gmd:CI_DateTypeCode
codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode"
codeListValue="creation">creation</gmd:CI_DateTypeCode>
</xsl:otherwise>
</xsl:choose>
</gmd:dateType>
</gmd:CI_Date>
</gmd:date>
</xsl:if>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<gmd:date gco:nilReason="missing"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- convert dc authors -->
<xsl:template name="creators">
<xsl:for-each select="$dc-creators">
<gmd:citedResponsibleParty>
<xsl:variable name="httpuri" select="string('')"/>
<xsl:variable name="nameidscheme" select="string('')"/>
<xsl:variable name="email" select="string('')"/>
<xsl:variable name="namestring">
<xsl:value-of select="normalize-space(string(.))"/>
</xsl:variable>
<xsl:call-template name="ci_responsibleparty">
<xsl:with-param name="individual">
<xsl:value-of select="$namestring"/>
</xsl:with-param>
<xsl:with-param name="httpuri">
<xsl:value-of select="$httpuri"/>
</xsl:with-param>
<xsl:with-param name="personidtype">
<xsl:value-of select="$nameidscheme"/>
</xsl:with-param>
<xsl:with-param name="organisation">
<xsl:value-of select=".//*[local-name() = 'affiliation']"/>
</xsl:with-param>
<xsl:with-param name="position"/>
<xsl:with-param name="role">author</xsl:with-param>
<xsl:with-param name="email">
<xsl:value-of select="$email"/>
</xsl:with-param>
</xsl:call-template>
</gmd:citedResponsibleParty>
</xsl:for-each>
</xsl:template>
<!-- convert dc contributors and try to translate the roles-->
<xsl:template name="contributors">
<xsl:for-each select="//*[local-name() = 'contributor']">
<xsl:variable name="dcrole" select="'contributor'"/>
<xsl:variable name="role">
<xsl:choose>
<xsl:when test="$dcrole = 'ContactPerson'">pointOfContact</xsl:when>
<xsl:when test="$dcrole = 'DataCollector'">collaborator</xsl:when>
<xsl:when test="$dcrole = 'DataCurator'">custodian</xsl:when>
<xsl:when test="$dcrole = 'DataManager'">custodian</xsl:when>
<xsl:when test="$dcrole = 'Distributor'">originator</xsl:when>
<xsl:when test="$dcrole = 'Editor'">editor</xsl:when>
<xsl:when test="$dcrole = 'Funder'">funder</xsl:when>
<xsl:when test="$dcrole = 'HostingInstitution'">distributor</xsl:when>
<xsl:when test="$dcrole = 'ProjectLeader'">collaborator</xsl:when>
<xsl:when test="$dcrole = 'ProjectManager'">collaborator</xsl:when>
<xsl:when test="$dcrole = 'ProjectMember'">collaborator</xsl:when>
<xsl:when test="$dcrole = 'ResearchGroup'">collaborator</xsl:when>
<xsl:when test="$dcrole = 'Researcher'">collaborator</xsl:when>
<xsl:when test="$dcrole = 'RightsHolder'">rightsHolder</xsl:when>
<xsl:when test="$dcrole = 'Sponsor'">funder</xsl:when>
<xsl:when test="$dcrole = 'WorkPackageLeader'">collaborator</xsl:when>
<xsl:otherwise>contributor</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<gmd:citedResponsibleParty>
<xsl:variable name="httpuri" select="string('')"/>
<xsl:variable name="nameidscheme" select="string('')"/>
<xsl:variable name="email" select="string('')"/>
<xsl:variable name="contrnamestring">
<xsl:value-of select="normalize-space(string(.))"/>
</xsl:variable>
<xsl:call-template name="ci_responsibleparty">
<xsl:with-param name="individual">
<xsl:value-of select="$contrnamestring"/>
</xsl:with-param>
<xsl:with-param name="httpuri">
<xsl:value-of select="$httpuri"/>
</xsl:with-param>
<xsl:with-param name="personidtype">
<xsl:value-of select="$nameidscheme"/>
</xsl:with-param>
<xsl:with-param name="organisation">
<xsl:value-of select="string('')"/>
</xsl:with-param>
<xsl:with-param name="position">
<xsl:value-of select="$dcrole"/>
</xsl:with-param>
<xsl:with-param name="email">
<xsl:value-of select="$email"/>
</xsl:with-param>
<xsl:with-param name="role" select="$role"/>
</xsl:call-template>
</gmd:citedResponsibleParty>
</xsl:for-each>
</xsl:template>
<!-- retrieves a dataset contact and uses either the contributors with a
matching role "ContactPerson" or "DataCurator" or the first creator in the 'creators' sequence-->
<xsl:template name="datasetcontact">
<xsl:choose>
<xsl:when test="$dc-creators[1]">
<gmd:pointOfContact>
<xsl:variable name="httpuri" select="string('')"/>
<xsl:variable name="nameidscheme" select="string('')"/>
<xsl:if test="$httpuri != ''">
<xsl:attribute name="xlink:href">
<xsl:value-of select="$httpuri"/>
</xsl:attribute>
</xsl:if>
<xsl:variable name="email" select="string('')"/>
<xsl:variable name="namestring"
select="normalize-space(string($dc-creators[1]))"/>
<xsl:call-template name="ci_responsibleparty">
<xsl:with-param name="individual">
<xsl:value-of select="$namestring"/>
</xsl:with-param>
<xsl:with-param name="httpuri">
<xsl:value-of select="$httpuri"/>
</xsl:with-param>
<xsl:with-param name="personidtype">
<xsl:value-of select="$nameidscheme"/>
</xsl:with-param>
<xsl:with-param name="organisation">
<xsl:value-of select=".//*[local-name() = 'affiliation']"/>
</xsl:with-param>
<xsl:with-param name="position"/>
<xsl:with-param name="role">pointOfContact</xsl:with-param>
</xsl:call-template>
</gmd:pointOfContact>
</xsl:when>
<xsl:otherwise>
<gmd:pointOfContact gco:nilReason="missing"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- A helper function to serialize basic person/affiliation information.
There are several ways to model a person ID (https://geo-ide.noaa.gov/wiki/index.php?title=ISO_Researcher_ID).
All approaches are based on URLs - currently only ORCID seems to support URLs.
The ID of persons should also be put as "xlink:href" attribute into the parent element. -->
<xsl:template name="ci_responsibleparty">
<xsl:param name="individual"/>
<xsl:param name="httpuri"/>
<xsl:param name="personidtype"/>
<xsl:param name="organisation"/>
<xsl:param name="position"/>
<xsl:param name="role"/>
<xsl:param name="email"/>
<gmd:CI_ResponsibleParty>
<xsl:if test="$individual != ''">
<gmd:individualName>
<gco:CharacterString>
<xsl:value-of select="$individual"/>
</gco:CharacterString>
</gmd:individualName>
</xsl:if>
<xsl:if test="$organisation != ''">