-
Notifications
You must be signed in to change notification settings - Fork 0
/
email.pas
205 lines (179 loc) · 6.94 KB
/
email.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
{ --------------------------------------------------------------------------
godaemon
Email notification unit
Copyright (c) Michael Nixon 2015.
Please see the LICENSE file for licensing information.
-------------------------------------------------------------------------- }
{ --------------------------------------------------------------------------
-------------------------------------------------------------------------- }
unit email;
interface
uses baseunix, unix, unixutil, sockets, sysutils, classes, logger;
{ Non-class functions and procedures }
function SendEmail(recipient, subject, body: ansistring): boolean;
procedure SendEmailForTaskRestart(failcount, faillimit, failtimespan: longint);
procedure SendEmailForTaskCompleteFailure;
function EmailDetailedInformation: ansistring;
procedure SendEmailToList(receipients, subject, body: ansistring);
function EmailLogTail: ansistring;
{ --------------------------------------------------------------------------
-------------------------------------------------------------------------- }
implementation
uses settings, strutils, process, btime;
{ --------------------------------------------------------------------------
Email body text: Return the last few lines of the task log
-------------------------------------------------------------------------- }
function EmailLogTail: ansistring;
var
strings: tstringlist;
i: longint;
s: ansistring;
begin
strings := _logger.TailLog(_settings.logTailCount);
if assigned(strings) then begin
s := '';
for i := strings.count - 1 downto 0 do begin
s := s + strings.Strings[i] + #10;
end;
result := '===== Last ' + inttostr(_settings.logTailCount) + ' lines of task log output =====' + #10#10 + s;
end else begin
result := '***** UNABLE TO READ LAST LOG OUTPUT *****' + #10;
end;
end;
{ --------------------------------------------------------------------------
Send an email to a list of receipients.
<receipients> is a comma seperated list of email addresses.
-------------------------------------------------------------------------- }
procedure SendEmailToList(receipients, subject, body: ansistring);
const
funcname = 'SendEmailToList(): ';
var
oneAddress: ansistring;
s: ansistring;
i: longint;
begin
s := trim(receipients);
if length(s) = 0 then begin
_logger.Log(funcname + 'Receipient list empty?');
exit;
end;
repeat
i := pos(',', s);
if i > 0 then begin
if i > 1 then begin
oneAddress := copy(s, 1, i - 1);
end else begin
oneAddress := '';
end;
if i < length(s) then begin
s := copy(s, i + 1, length(s) - i);
end else begin
s := '';
end;
end else begin
oneAddress := s;
s := '';
end;
if oneAddress <> '' then begin
SendEmail(oneAddress, subject, body);
end;
until (i = 0) or (s = '');
end;
{ --------------------------------------------------------------------------
Send an email, because the task is being restarted.
<failcount> is the number of times the task has failed in the time span
<faillimit> is the maximum number of times the task is allowed to fail in
the time span before godaemon gives up
<failtimespan> is the time span used to calculating failure limits (the
time between the first and last failure) in seconds
-------------------------------------------------------------------------- }
procedure SendEmailForTaskRestart(failcount, faillimit, failtimespan: longint);
begin
SendEmailToList(_settings.emailAddress,
'[' + _settings.daemonName + '] - GoDaemon WARNING: Task was restarted',
'***** GoDaemon Notification *****' + #10#10 +
'The task "' + _settings.daemonName + '" has failed. GoDaemon will ' +
'restart the task.' + #10#10 +
EmailDetailedInformation +
'Failure count (current timespan): ' + inttostr(failcount) + #10 +
'Failure limit: ' + inttostr(faillimit) + #10 +
'Time span: ' + inttostr(failtimespan) + ' seconds' + #10 + #10 +
EmailLogTail
);
end;
{ --------------------------------------------------------------------------
Send an email, because the task has failed and is not going to be
restarted as it has failed too many times.
-------------------------------------------------------------------------- }
procedure SendEmailForTaskCompleteFailure;
begin
SendEmailToList(_settings.emailAddress,
'[' + _settings.daemonName + '] - GoDaemon CRITICAL: Task has failed',
'***** GoDaemon CRITICAL Notification *****' + #10#10 +
'The task "' + _settings.daemonName + '" has failed too many times. ' +
'GoDaemon will not restart the task. Diagnose the problem and then ' +
'manually start the task.' + #10#10 +
EmailDetailedInformation + #10 + #10 + EmailLogTail
);
end;
{ --------------------------------------------------------------------------
Email body text: Generate the detailed information section.
-------------------------------------------------------------------------- }
function EmailDetailedInformation: ansistring;
begin
result :=
'===== Detailed information =====' + #10#10 +
'Task name: ' + _settings.daemonName + #10 +
'Time: ' + timestring(unixtimeint) + #10;
end;
{ --------------------------------------------------------------------------
Send an email to <recipient> with subject <subject> and the body text
containing <bosy>. Uses the system mail program.
Returns true if the email was successfully handled to the system email
program for delivery, or false if the system mail program could not be
invoked or returned an error status.
-------------------------------------------------------------------------- }
function SendEmail(recipient, subject, body: ansistring): boolean;
const
emailprogram = '/usr/bin/mail';
funcname = 'SendEmail(): ';
emailtimeout = 100;
var
emailtask: tprocess;
timer: longint;
begin
_logger.Log(funcname + 'Sending email to ' + recipient + ' - subject: ' + subject);
if not fileexists(emailprogram) then begin
_logger.Log(funcname + 'Can''t find the system email program: ' + emailprogram);
result := false;
exit;
end;
{ Create mail process }
emailtask := tprocess.Create(nil);
emailtask.Options := [poUsePipes, poStderrToOutPut];
emailtask.Executable := emailprogram;
emailtask.InheritHandles := false;
emailtask.Parameters.Add('-s');
emailtask.Parameters.Add(subject);
emailtask.Parameters.Add(recipient);
emailtask.Execute;
{ Pass in email body (mail will read from stdin) }
emailtask.Input.Write(body[1], length(body));
{ Close stdin so that mail knows we don't want to send any more }
emailtask.CloseInput;
timer := 0;
while emailtask.Running do begin
sleep(100);
inc(timer);
if timer > emailtimeout then begin
emailtask.Terminate(1);
_logger.Log(funcname + 'Error: Timed out executing mail process');
result := false;
exit;
end;
end;
emailtask.Free;
_logger.Log(funcname + 'Sent email successfully.');
result := true;
end;
end.