build.gradle

buildscript {
    ext {
        springBootVersion = '1.3.5.RELEASE'
        dockerPluginVersion = '2.6.5'
    }

    repositories {
        jcenter()
    }

    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}"
        classpath "com.bmuschko:gradle-docker-plugin:${dockerPluginVersion}"

        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.2'
        classpath "io.spring.gradle:dependency-management-plugin:0.5.0.RELEASE"
        classpath 'com.netflix.nebula:gradle-extra-configurations-plugin:2.2.+'
    }
}


allprojects {
    group = 'info.developerblog.spring.thrift'
    version = '1.0.0.RC1'

    repositories {
        jcenter()
    }

    apply plugin: 'idea'
    apply plugin: "io.spring.dependency-management"
    apply plugin: 'provided-base'
    apply plugin: 'java'

    dependencyManagement {
        imports {
            mavenBom 'org.springframework.cloud:spring-cloud-dependencies:Brixton.SR1'
        }

        dependencies {
            dependencySet(group:'org.springframework.boot', version: '1.3.5.RELEASE') {
                entry "spring-boot-starter-web"
                entry "spring-boot-starter-test"
                entry "spring-boot-starter-actuator"
            }

            dependency 'org.projectlombok:lombok:1.16.2'
            dependency 'ru.aatarasoff.thrift:api-gateway-core:0.2.1'
            dependency 'org.apache.thrift:libthrift:0.9.2'
            dependency 'info.developerblog.spring.thrift:spring-thrift-starter:1.0.0.RC2'
        }
    }



     task resolveAllDependencies {
         doLast {
             configurations.all { it.resolve() }
         }
     }
}

subprojects {

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    test {
        reports {
            junitXml.enabled = true
            html.enabled = true
        }
    }

    dependencies {
        provided "org.projectlombok:lombok"

        testCompile "org.springframework.boot:spring-boot-starter-test"
    }
}