RFC: setindex for mutable collections

base/array.jl

@@ -834,6 +834,41 @@ function setindex!(A::Array{T}, X::Array{T}, c::Colon) where T
     return A
 end
 
+"""
+    setindex(collection, value, key...)
+
+Create a new collection with the element/elements of the location specified by `key`
+replaced with `value`(s).
+
+# Implementation
+
+`setindex(collection, value, key...)` must have the property such that
+
+```julia
+y1 = setindex(x, value, key...)
+
+y2 = copy′(x)
+@assert convert.(eltype(y2), x) == y2
+
+y2[key...] = value
+@assert convert.(eltype(y2), y1) == y2
+```
+
+with a suitable definition of `copy′` such that `y2[key...] = value` succeeds.
+
+`setindex` should support more combinations of arguments by widening collection
+type as required.
+"""
+function setindex end
+
+function setindex(xs::AbstractArray, v, I...)
+    T = promote_type(eltype(xs), typeof(v))
+    ys = similar(xs, T)
+    copy!(ys, xs)
+    ys[I...] = v
+    return ys
+end
+
 # efficiently grow an array
 
 _growbeg!(a::Vector, delta::Integer) =

base/dict.jl

@@ -391,6 +391,15 @@ function setindex!(h::Dict{K,V}, v0, key::K) where V where K
     return h
 end
 
+function setindex(d0::Dict, v, k)
+    K = promote_type(keytype(d0), typeof(k))
+    V = promote_type(valtype(d0), typeof(v))
+    d = Dict{K, V}()
+    copy!(d, d0)
+    d[k] = v
+    return d
+end
+
 """
     get!(collection, key, default)
 

test/arrayops.jl

@@ -2651,6 +2651,14 @@ end
 # Throws ArgumentError for negative dimensions in Array
 @test_throws ArgumentError fill('a', -10)
 
+@testset "setindex" begin
+    ==ₜ(_, _) = false
+    ==ₜ(x::T, y::T) where T = x == y
+
+    @test Base.setindex(Int[1, 2], 3.0, 2) ==ₜ [1.0, 3.0]
+    @test Base.setindex(Int[1, 2, 3], :two, 2) ==ₜ [1, :two, 3]
+end
+
 @testset "Issue 33919" begin
     A = Array[rand(2, 3), rand(3, 1)]
     B = Array[rand(2, 2), rand(1, 4)]

test/dict.jl

@@ -1072,3 +1072,15 @@ end
         @test testdict[:b] == 1
     end
 end
+
+@testset "setindex" begin
+    ==ₜ(_, _) = false
+    ==ₜ(x::T, y::T) where T = x == y
+
+    @test Base.setindex(Dict(:a=>1, :b=>2), 10, :a) ==ₜ
+        Dict(:a=>10, :b=>2)
+    @test Base.setindex(Dict(:a=>1, :b=>2), 3, "c") ==ₜ
+        Dict(:a=>1, :b=>2, "c"=>3)
+    @test Base.setindex(Dict(:a=>1, :b=>2), 3.0, :c) ==ₜ
+        Dict(:a=>1.0, :b=>2.0, :c=>3.0)
+end