View Distance Module

AUTHORS.txt

@@ -93,3 +93,4 @@ Bla1337
 nikolauska <nikolauska1@gmail.com>
 adam3adam <br.ada@seznam.cz>
 Professor <lukas.trneny@wo.cz> 
+Winter <simon@agius-muscat.net>

addons/viewdistance/$PBOPREFIX$

@@ -0,0 +1 @@
+z\ace\addons\viewdistance

addons/viewdistance/ACE_Settings.hpp

@@ -0,0 +1,42 @@
+class ACE_Settings {
+    class GVAR(viewDistanceOnFoot) {
+        typeName = "SCALAR";
+        isClientSettable = 1;
+        value = 11; // index, NOT value // Can set it to client's actual viewdistance in the init function once ACE_Settings supports numbers (if ever).
+        values[] = {"1500","2000","2500","3000","3500","4000","5000","6000","7000","8000","9000","10000"}; // Values also need to be changed in functions/fnc_returnValue.sqf
+        displayName = "Client View Distance (On Foot)";
+        description = "Changes in game view distance when the player is on foot.";
+    };
+    class GVAR(viewDistanceLandVehicle) {
+        typeName = "SCALAR";
+        isClientSettable = 1;
+        value = 11; // index, NOT value
+        values[] = {"1500","2000","2500","3000","3500","4000","5000","6000","7000","8000","9000","10000"}; // Values also need to be changed in functions/fnc_returnValue.sqf
+        displayName = "Client View Distance (Land Vehicle)";
+        description = "Changes in game view distance when the player is in a land vehicle.";
+    };
+    class GVAR(viewDistanceAirVehicle) {
+        typeName = "SCALAR";
+        isClientSettable = 1;
+        value = 11; // index, NOT value
+        values[] = {"1500","2000","2500","3000","3500","4000","5000","6000","7000","8000","9000","10000"}; // Values also need to be changed in functions/fnc_returnValue.sqf
+        displayName = "Client View Distance (Air Vehicle)";
+        description = "Changes in game view distance when the player is in an air vehicle.";
+    };
+    class GVAR(limitViewDistance) {
+        typeName = "SCALAR";
+        value = 10000; // Value, NOT index. 10000 is the maximum in A3
+        displayName = "View Distance Limit";
+        description = "Limit for client's view distance set here and can overridden by module";
+    };
+    class GVAR(objectViewDistanceCoeff) {
+        typeName = "SCALAR";
+        isClientSettable = 1;
+        value = 0; // index. Actual coefficient is given by functions/fnc_returnObjectCoeff.sqf
+        values[] = {"Off","Very Low","Low","Medium","High","Very High"};
+        displayName = "Dynamic Object View Distance";
+        description = "Sets the object view distance as a coefficient of the view distance.";
+    };
+};
+
+// To do: include string table style displayName & description.

addons/viewdistance/CfgEventHandlers.hpp

@@ -0,0 +1,12 @@
+
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preInit));
+    };
+};
+
+class Extended_PostInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_postInit));
+    };
+};

addons/viewdistance/CfgVehicles.hpp

@@ -0,0 +1,20 @@
+class CfgVehicles {
+    class ACE_Module;
+    class GVAR(ModuleSettings) : ACE_Module {
+        author = "$STR_ACE_Common_ACETeam";
+        category = "ACE";
+        function = QUOTE(DFUNC(initModule));
+        displayName = "View Distance Limiter";
+        scope = 2;
+        isGlobal = 1;
+        //icon = ""; // needs an icon
+        class Arguments {
+            class moduleViewDistanceLimit {
+                displayName = "View Distance Limit";
+                description = "Sets the limit for how high clients can raise their view distance (<= 10000)";
+                typeName = "NUMBER";
+                defaultValue = 10000;
+            };
+        };
+    };
+};

addons/viewdistance/XEH_postInit.sqf

@@ -0,0 +1,27 @@
+#include "script_component.hpp"
+
+if (!hasInterface) exitWith {};
+
+if (viewDistance > GVAR(limitViewDistance)) then {
+    setViewDistance GVAR(limitViewDistance); // force the view distance down to the limit.
+    setObjectViewDistance (0.8 * GVAR(limitViewDistance));
+} else {
+    [true] call FUNC(adaptViewDistance); // adapt view distance in the beginning according to whether client is on foot or vehicle.
+};
+
+// Set the EH which waits for any of the view distance settings to be changed, avoids the player having to enter or leave a vehicle for the changes to have effect.
+["SettingChanged",{
+    if ((_this select 0  == QGVAR(viewDistanceOnFoot)) || (_this select 0  == QGVAR(viewDistanceLandVehicle)) || (_this select 0  == QGVAR(viewDistanceAirVehicle))) then {
+        [true] call FUNC(adaptViewDistance);
+    };
+},true] call ace_common_fnc_addEventHandler;
+
+// Set the EH which waits for the Object View Distance coefficient to be changed, so that the effect is show immediately
+["SettingChanged",{
+    if (_this select 0  == QGVAR(objectViewDistanceCoeff)) then {
+        [true] call FUNC(adaptViewDistance);
+    };
+},true] call ace_common_fnc_addEventHandler;
+
+// Set the EH which waits for a vehicle change to automatically swap to On Foot/In Land Vehicle/In Air Vehicle
+["playerVehicleChanged",{[false] call FUNC(adaptViewDistance)},true] call ace_common_fnc_addEventHandler;

addons/viewdistance/XEH_preInit.sqf

@@ -0,0 +1,11 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+PREP(initModule);
+PREP(returnValue);
+PREP(returnObjectCoeff);
+PREP(changeViewDistance);
+PREP(adaptViewDistance);
+
+ADDON = true;

addons/viewdistance/config.cpp

@@ -0,0 +1,17 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        units[] = {};
+        weapons[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"ace_common"};
+        author[] = {"Winter"};
+        authorUrl = "https://github.com/Winter259";
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "ACE_Settings.hpp"
+#include "CfgVehicles.hpp"

addons/viewdistance/functions/fnc_adaptViewDistance.sqf

@@ -0,0 +1,37 @@
+/*
+ * Author: Winter
+ * Sets the player's current view distance according to whether s/he is on foot, in a land vehicle or in an air vehicle.
+ * 
+ *
+ * Arguments:
+ * 0: Show Prompt <BOOL>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [] call ace_viewdistance_fnc_adaptViewDistance;
+ *
+ * Public: No
+ */
+
+#include "script_component.hpp"
+
+PARAMS_1(_show_prompt);
+
+private["_land_vehicle","_air_vehicle"];
+
+_land_vehicle = (vehicle ACE_player) isKindOf "LandVehicle";
+_air_vehicle = (vehicle ACE_player) isKindOf "Air";
+
+if (!_land_vehicle && !_air_vehicle) exitWith {
+    [GVAR(viewDistanceOnFoot),_show_prompt] call FUNC(changeViewDistance);
+};
+
+if (_land_vehicle) exitWith {
+    [GVAR(viewDistanceLandVehicle),_show_prompt] call FUNC(changeViewDistance);
+};
+
+if (_air_vehicle) exitWith {
+    [GVAR(viewDistanceAirVehicle),_show_prompt] call FUNC(changeViewDistance);
+};

addons/viewdistance/functions/fnc_changeViewDistance.sqf

@@ -0,0 +1,48 @@
+/*
+ * Author: Winter
+ * Sets the player's current view distance according to allowed values.
+ * 
+ *
+ * Arguments:
+ * 0: View Distance setting INDEX <SCALAR>
+ * 1: Show Prompt <BOOL>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [] call ace_viewdistance_fnc_changeViewDistance;
+ *
+ * Public: No
+ */
+
+#include "script_component.hpp"
+
+private ["_text","_new_view_distance","_view_distance_limit","_object_view_distance_coeff"];
+
+PARAMS_2(_index_requested,_show_prompt);
+
+_new_view_distance = [_index_requested] call FUNC(returnValue); // changes the setting index into an actual view distance value
+_object_view_distance_coeff = [GVAR(objectViewDistanceCoeff)] call FUNC(returnObjectCoeff); // changes the setting index into a coefficient.
+_view_distance_limit = GVAR(limitViewDistance); // Grab the limit
+
+if (_new_view_distance <= _view_distance_limit) then {
+    if (_show_prompt) then {
+        _text = parseText format ["<t align='center'>View Distance: %1<br />Object View Distance Coefficient: %2</t>",str(_new_view_distance),str(_object_view_distance_coeff)];
+        [_text,2] call EFUNC(common,displayTextStructured);
+    };
+    setViewDistance _new_view_distance;
+    if (_object_view_distance_coeff > 0) then {
+        setObjectViewDistance (_object_view_distance_coeff * _new_view_distance);
+    };
+}
+else {
+     if (_show_prompt) then {
+        _text = parseText format ["<t align='center'>That option is invalid! The limit is: %1<br />Object View Distance Coefficient: %2</t>",str(_view_distance_limit),str(_object_view_distance_coeff)];
+        [_text,2] call EFUNC(common,displayTextStructured);
+    };
+    setViewDistance _view_distance_limit;
+    if (_object_view_distance_coeff > 0) then {
+        setObjectViewDistance (_object_view_distance_coeff * _view_distance_limit);
+    };
+};

addons/viewdistance/functions/fnc_initModule.sqf

@@ -0,0 +1,28 @@
+/*
+ * Author: Winter
+ * Initialises the view distance limiter module
+ * 
+ *
+ * Arguments:
+ * 0: logic <OBJECT>
+ * 1: Synchronised Units <ARRAY>
+ * 2: Module Activated <BOOL>
+ *
+ * Return Value:
+ * None
+ * 
+ */
+
+#include "script_component.hpp"
+
+if (!isServer) exitWith {};
+
+PARAMS_3(_logic,_units,_activated);
+
+if (!_activated) exitWith {
+    diag_log text "[ACE]: View Distance Limit Module is placed but NOT active.";
+};
+
+[_logic, QGVAR(limitViewDistance),"moduleViewDistanceLimit"] call EFUNC(common,readSettingFromModule);
+
+diag_log format ["[ACE]: View Distance Limit Module Initialized. Limit set by module: %1",GVAR(limitViewDistance)];

addons/viewdistance/functions/fnc_returnObjectCoeff.sqf

@@ -0,0 +1,34 @@
+/*
+ * Author: Winter
+ * Returns the object view distance coefficient according to the given index
+ * 
+ *
+ * Arguments:
+ * 0: Object View Distance setting Index <SCALAR>
+ *
+ * Return Value:
+ * Object View Distance <SCALAR>
+ *
+ * Example:
+ * [2] call ace_viewdistance_fnc_returnObjectCoeff;
+ *
+ * Public: No
+ */
+
+#include "script_component.hpp"
+
+PARAMS_1(_index);
+
+private ["_return"];
+
+_return = switch (_index) do {
+    case 0: {0.00}; // Off
+    case 1: {0.20}; // Very Low
+    case 2: {0.40}; // Low
+    case 3: {0.60}; // Medium
+    case 4: {0.80}; // High
+    case 5: {1.00}; // Very High
+    default {0.50}; // something broke if this returns
+};
+
+_return;

addons/viewdistance/functions/fnc_returnValue.sqf

@@ -0,0 +1,40 @@
+/*
+ * Author: Winter
+ * Returns the view distance value according to the given index
+ * 
+ *
+ * Arguments:
+ * 0: View Distance Index <SCALAR>
+ *
+ * Return Value:
+ * View Distance <SCALAR>
+ *
+ * Example:
+ * [2] call ace_viewdistance_fnc_returnViewDistanceValue;
+ *
+ * Public: No
+ */
+
+#include "script_component.hpp"
+
+PARAMS_1(_index);
+
+private ["_return"];
+
+_return = switch (_index) do {
+    case 0:   {1500};
+    case 1:   {2000};
+    case 2:   {2500};
+    case 3:   {3000};
+    case 4:   {3500};
+    case 5:   {4000};
+    case 6:   {5000};
+    case 7:   {6000};
+    case 8:   {7000};
+    case 9:   {8000};
+    case 10:  {9000};
+    case 11:  {10000};
+    default   {1000};
+};
+
+_return;

addons/viewdistance/functions/script_component.hpp

@@ -0,0 +1 @@
+#include "\z\ace\addons\viewdistance\script_component.hpp"

addons/viewdistance/script_component.hpp

@@ -0,0 +1,12 @@
+#define COMPONENT viewdistance
+#include "\z\ace\addons\main\script_mod.hpp"
+
+#ifdef DEBUG_ENABLED_VIEWDISTANCE
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_VIEWDISTANCE
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_VIEWDISTANCE
+#endif
+
+#include "\z\ace\addons\main\script_macros.hpp"