Interaction - Add actions based on animations

addons/interaction/CfgVehicles.hpp

@@ -345,7 +345,15 @@ class CfgVehicles {
         };
     };
 
-    class Car_F: Car{};
+    class Car_F: Car {};
+    class Offroad_01_base_F: Car_F {
+        class GVAR(anims) {
+            class HideBackpacks {
+                position[] = {{-1.15,-1.15,-0.2}, {1.1,-1.15,-0.2}, {1.1,-2.5,-0.2}};
+                item[] = {"B_TacticalPack_blk", "B_TacticalPack_blk", "B_Carryall_khk", "B_Carryall_khk"};
+            };
+        };
+    };
     class Quadbike_01_base_F: Car_F {
         class ACE_Actions: ACE_Actions {
             class ACE_MainActions: ACE_MainActions {
@@ -379,6 +387,39 @@ class CfgVehicles {
         };
     };
 
+    class Wheeled_APC_F;
+    class APC_Wheeled_01_base_F: Wheeled_APC_F {
+        class GVAR(anims) {
+            class showBags {
+                phase = 0;
+                //selection = "vhc_bags";
+                position[] = {{-0.685,-2.863,0.218}, {0.685,-2.863,0.218}};
+                item[] = {"B_Carryall_cbr", "B_Carryall_cbr"};
+            };
+        };
+    };
+    class APC_Wheeled_02_base_F: Wheeled_APC_F {
+        class GVAR(anims);
+    };
+    class APC_Wheeled_02_base_v2_F: APC_Wheeled_02_base_F {
+        class GVAR(anims): GVAR(anims) {
+            class showBags {
+                phase = 0;
+                selection = "vhc_bags";
+                item = "B_Carryall_cbr";
+            };
+        };
+    };
+    class APC_Wheeled_03_base_F: Wheeled_APC_F {
+        class GVAR(anims) {
+            class showBags {
+                phase = 0;
+                selection = "vhc_bags";
+                item[] = {"B_Carryall_cbr", "B_Carryall_cbr"};
+            };
+        };
+    };
+
     class Tank: LandVehicle {
         class ACE_Actions {
             class ACE_MainActions {
@@ -406,6 +447,77 @@ class CfgVehicles {
             };
         };
     };
+    class Tank_F;
+    class LT_01_base_F: Tank_F {
+        class GVAR(anims) {
+            class showBags {
+                phase = 0;
+                selection = "vhc_bags";
+                item = "B_Carryall_cbr";
+            };
+            class showBags2: showBags {
+                selection = "vhc_bags2";
+            };
+        };
+    };
+
+    class APC_Tracked_01_base_F: Tank_F {
+        class GVAR(anims);
+    };
+    class B_APC_Tracked_01_base_F: APC_Tracked_01_base_F {
+        class GVAR(anims):GVAR(anims) {
+            class showBags {
+                phase = 0;
+                selection = "vhc_bags";
+                item[] = {"B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr"};
+            };
+        };
+    };
+    class B_APC_Tracked_01_CRV_F: B_APC_Tracked_01_base_F {
+        class GVAR(anims): GVAR(anims) {
+            class showBags: showBags {
+                item[] = {"B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr"};
+            };
+        };
+    };
+
+    class APC_Tracked_02_base_F: Tank_F {
+        class GVAR(anims);
+    };
+    class O_APC_Tracked_02_base_F: APC_Tracked_02_base_F {};
+    class O_APC_Tracked_02_cannon_F: O_APC_Tracked_02_base_F {
+        class GVAR(anims): GVAR(anims) {
+            class showBags {
+                phase = 0;
+                selection = "vhc_bags";
+                item[] = {"B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr"};
+            };
+        };
+    };
+
+    class APC_Tracked_03_base_F: Tank_F {
+        class GVAR(anims) {
+            class showBags {
+                phase = 0;
+                selection = "vhc_bags";
+                item[] = {"B_Carryall_cbr", "B_Carryall_cbr"};
+            };
+        };
+    };
+
+    class MBT_01_base_F: Tank_F {
+        class GVAR(anims);
+    };
+    class B_MBT_01_base_F: MBT_01_base_F {};
+    class B_MBT_01_cannon_F: B_MBT_01_base_F {
+        class GVAR(anims): GVAR(anims) {
+            class showBags {
+                phase = 0;
+                selection = "vhc_bags";
+                item[] = {"B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr", "B_Carryall_cbr"};
+            };
+        };
+    };
 
     class Motorcycle: LandVehicle {
         class ACE_Actions {

addons/interaction/XEH_PREP.hpp

@@ -43,4 +43,5 @@ PREP(canPush);
 PREP(push);
 
 PREP(canFlip);
+PREP(switchAnimActions);
 PREP(switchLamp);

addons/interaction/XEH_preInit.sqf

@@ -6,4 +6,6 @@ PREP_RECOMPILE_START;
 #include "XEH_PREP.hpp"
 PREP_RECOMPILE_END;
 
+#include "initSettings.sqf"
+
 ADDON = true;

addons/interaction/functions/fnc_switchAnimActions.sqf

@@ -0,0 +1,141 @@
+/*
+ * Author: Dystopian
+ * Controls animation based interactions state.
+ *
+ * Arguments:
+ * 0: Enabled <BOOL>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * true call ace_interaction_fnc_switchAnimActions
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+params ["_enabled"];
+
+if (!_enabled || {!isNil QGVAR(animActionsInitialized)}) exitWith {};
+
+private _statement = {
+    params ["_target", "_player", "_params"];
+    _params params ["_anim", "_phase", "_duration"];
+    TRACE_5("statement",_target,_player,_anim,_phase,_duration);
+    [
+        _duration,
+        [_target, _player, _anim, _phase],
+        {
+            (_this select 0) params ["_target", "_player", "_anim", "_phase"];
+            scopeName "main";
+            private _items = _target getVariable [
+                format [QGVAR(animsItem_%1), _anim],
+                [configFile >> "CfgVehicles" >> typeOf _target >> QGVAR(anims) >> _anim >> "item"] call BIS_fnc_getCfgData
+            ];
+            if (!isNil "_items") then {
+                if (_items isEqualType "") then {_items = [_items]};
+                private _emptyPosAGL = [_target, _items select 0, _player] call EFUNC(common,findUnloadPosition);
+                if (_emptyPosAGL isEqualTo []) then {
+                    [localize ELSTRING(common,NoRoomToUnload)] call EFUNC(common,displayTextStructured);
+                    breakOut "main";
+                };
+                private ["_weaponHolder"];
+                {
+                    switch true do {
+                        case (1 == getNumber (configFile >> "CfgVehicles" >> _x >> "isBackpack")): {
+                            if (isNil "_weaponHolder") then {
+                                _weaponHolder = createVehicle ["GroundWeaponHolder", _emptyPosAGL, [], 0, "CAN_COLLIDE"];
+                            };
+                            _weaponHolder addBackpackCargoGlobal [_x, 1];
+                        };
+                        case (getNumber (configfile >> "CfgWeapons" >> _x >> "type") in [4096,131072]): {
+                            if (isNil "_weaponHolder") then {
+                                _weaponHolder = createVehicle ["GroundWeaponHolder", _emptyPosAGL, [], 0, "CAN_COLLIDE"];
+                            };
+                            _weaponHolder addItemCargoGlobal [_x, 1];
+                        };
+                        default {
+                            createVehicle [_x, _emptyPosAGL];
+                        };
+                    };
+                } forEach _items;
+            };
+            _target animate [_anim, _phase, true];
+        },
+        {},
+        nil,
+        {
+            (_this select 0) params ["_target", "", "_anim", "_phase"];
+            _target animationPhase _anim != _phase
+        },
+        ["isNotSwimming"]
+    ] call EFUNC(common,progressBar);
+};
+
+private _condition = {
+    params ["_target", "_player", "_params"];
+    _params params ["_anim", "_phase"];
+    private _vehicleConfig = configFile >> "CfgVehicles" >> typeOf _target;
+    private _animConfig = _vehicleConfig >> "AnimationSources" >> _anim;
+
+    GVAR(animActionsEnabled)
+    && {isClass _animConfig}
+    && {0 != [_animConfig >> "scope", "number", 1] call CBA_fnc_getConfigEntry}
+    && {0 != [_vehicleConfig >> QGVAR(anims) >> _anim >> "enabled", "number", 1] call CBA_fnc_getConfigEntry}
+    && {_target animationPhase _anim != _phase}
+    && {[_player, _target, ["isNotSwimming"]] call EFUNC(common,canInteractWith)}
+};
+
+{
+    if (isClass (_x >> QGVAR(anims))) then {
+        private _vehicleConfig = _x;
+        private _vehicle = configName _vehicleConfig;
+        {
+            scopeName "animLoop";
+            private _anim = configName _x;
+            private _animConfigParent = inheritsFrom _vehicleConfig >> QGVAR(anims) >> _anim;
+            if (
+                !isClass _animConfigParent
+                || {_x != _animConfigParent && {0 == [_animConfigParent >> "inherit", "number", 1] call CBA_fnc_getConfigEntry}}
+            ) then {
+                private _positions = [_x >> "position"] call BIS_fnc_getCfgData;
+                if (!isNil "_positions") then {
+                    if (_positions isEqualType "") then {
+                        _positions = [compile format [
+                            QUOTE(call compile getText (configFile >> 'CfgVehicles' >> typeOf _target >> QQGVAR(anims) >> '%1' >> 'position')),
+                            _anim
+                        ]];
+                    };
+                } else {
+                    if ("" == getText (_x >> "selection")) then {
+                        ERROR_2("No action position for vehicle %1 anim %2",_vehicle,_anim);
+                        breakTo "animLoop";
+                    };
+                    _positions = [compile format [
+                        QUOTE(_target selectionPosition getText (configFile >> 'CfgVehicles' >> typeOf _target >> QQGVAR(anims) >> '%1' >> 'selection')),
+                        _anim
+                    ]];
+                };
+
+                private _phase = [_x >> "phase", "number", 1] call CBA_fnc_getConfigEntry;
+                private _name = [_x >> "name", "text", localize "str_a3_cfgactions_unmountitem0"] call CBA_fnc_getConfigEntry;
+                private _icon = [_x >> "icon", "text", "\A3\ui_f\data\igui\cfg\actions\take_ca.paa"] call CBA_fnc_getConfigEntry;
+                private _duration = [_x >> "duration", "number", 10] call CBA_fnc_getConfigEntry;
+                private _inherit = 0 != [_x >> "inherit", "number", 1] call CBA_fnc_getConfigEntry;
+                {
+                    private _action = [
+                        format ["%1%2", _anim, _forEachIndex],
+                        _name, _icon, _statement, _condition, {},
+                        [_anim, _phase, _duration],
+                        _x
+                    ] call EFUNC(interact_menu,createAction);
+                    [_vehicle, 0, [], _action, _inherit] call EFUNC(interact_menu,addActionToClass);
+                    TRACE_3("",_vehicle,_anim,_x);
+                } forEach _positions;
+            };
+        } forEach ('true' configClasses (_x >> QGVAR(anims)));
+    };
+} forEach ('true' configClasses (configFile >> "CfgVehicles"));
+
+GVAR(animActionsInitialized) = true;

addons/interaction/initSettings.sqf

@@ -0,0 +1,9 @@
+[
+    QGVAR(animActionsEnabled),
+    "CHECKBOX",
+    LSTRING(SettingAnimActionsName),
+    format ["ACE %1", localize LSTRING(DisplayName)],
+    true,
+    true,
+    LINKFUNC(switchAnimActions)
+] call CBA_settings_fnc_init;

addons/interaction/stringtable.xml

@@ -1091,5 +1091,9 @@
             <Chinese>拿出屍體</Chinese>
             <Chinesesimp>拿出尸体</Chinesesimp>
         </Key>
+        <Key ID="STR_ACE_Interaction_SettingAnimActionsName">
+            <English>Interaction with animations</English>
+            <Russian>Взаимодействие с анимациями</Russian>
+        </Key>
     </Package>
 </Project>

addons/refuel/CfgVehicles.hpp

@@ -208,6 +208,18 @@ class CfgVehicles {
         // Patria = LAV
         GVAR(fuelCapacity) = 269;
     };
+    class APC_Wheeled_02_base_F: Wheeled_APC_F {
+        class EGVAR(interaction,anims);
+    };
+    class APC_Wheeled_02_base_v2_F: APC_Wheeled_02_base_F {
+        class EGVAR(interaction,anims): EGVAR(interaction,anims) {
+            class showCanisters {
+                phase = 0;
+                position[] = {{-1.188,-3.87,-0.769}, {1.638,-3.87,-0.769}};
+                item[] = {"Land_CanisterFuel_F", "Land_CanisterFuel_F", "Land_CanisterFuel_F", "Land_CanisterFuel_F"};
+            };
+        };
+    };
 
     class Truck_F: Car_F {
         GVAR(fuelCapacity) = 400;
@@ -285,12 +297,14 @@ class CfgVehicles {
     class MBT_01_base_F: Tank_F {
         // Merkava IV
         GVAR(fuelCapacity) = 1400;
+        class EGVAR(interaction,anims);
     };
 
     class MBT_02_base_F: Tank_F {
         // T100 Black Eagle
         // Assuming T80
         GVAR(fuelCapacity) = 1100;
+        class EGVAR(interaction,anims);
     };
 
     class MBT_03_base_F: Tank_F {
@@ -301,11 +315,27 @@ class CfgVehicles {
     class MBT_01_arty_base_F: MBT_01_base_F {
         // Assuming similar 2S3
         GVAR(fuelCapacity) = 830;
+
+        class EGVAR(interaction,anims): EGVAR(interaction,anims) {
+            class showCanisters {
+                phase = 0;
+                position[] = {{-2,-1.95,-1}, {2,-1.95,-1}, {1.7,-4.898,-0.4}};
+                item[] = {"Land_CanisterFuel_F", "Land_CanisterFuel_F", "Land_CanisterFuel_F", "Land_CanisterFuel_F", "Land_CanisterFuel_F", "Land_CanisterFuel_F", "Land_CanisterFuel_F"};
+            };
+        };
     };
 
     class MBT_02_arty_base_F: MBT_02_base_F {
         // Assuming similar 2S3
         GVAR(fuelCapacity) = 830;
+
+        class EGVAR(interaction,anims): EGVAR(interaction,anims) {
+            class showCanisters {
+                phase = 0;
+                position[] = {{1.7,-4.8,-0.5}};
+                item = "Land_CanisterFuel_F";
+            };
+        };
     };
 
     class Heli_Light_02_base_F: Helicopter_Base_H {