Medical Feedback - Set volume and radio usage based current unit

[Whigital]

When merged this pull request will:

• Set players volume based on unconscious state

Fix #7528

[kymckay]

I don't think this is such a simple fix as assumed here because the unconscious state of the local machine can change without hitting the setUnconsciousState function (for example, upon death or upon unit switching).

See:

ACE3/addons/medical_feedback/XEH_postInit.sqf

Lines 35 to 92 in 5a4487f

	["ace_unconscious", {
	params ["_unit", "_unconscious"];
	if (_unit != ACE_player) exitWith {};
	TRACE_1("player unconscious eh",_unconscious);
	if (_unconscious && {cameraView == "GUNNER"} && {(vehicle _unit) != _unit} && {cameraOn == vehicle _unit}) then {
	TRACE_2("exiting gunner view",cameraOn,cameraView);
	ACE_player switchCamera "INTERNAL";
	};
	// Toggle unconscious player's ability to talk in radio addons
	if (["task_force_radio"] call EFUNC(common,isModLoaded)) then {
	_unit setVariable ["tf_voiceVolume", [1, 0] select _unconscious, true];
	_unit setVariable ["tf_unable_to_use_radio", _unconscious]; // Only used locally
	};
	if (["acre_main"] call EFUNC(common,isModLoaded)) then {
	_unit setVariable ["acre_sys_core_isDisabled", _unconscious, true];
	};
	// Greatly reduce player's hearing ability while unconscious (affects radio addons)
	[QUOTE(ADDON), VOL_UNCONSCIOUS, _unconscious] call EFUNC(common,setHearingCapability);
	[true] call FUNC(handleEffects);
	["unconscious", _unconscious] call EFUNC(common,setDisableUserInputStatus);
	}] call CBA_fnc_addEventHandler;
	// Reset volume upon death for spectators
	[QEGVAR(medical,death), {
	params ["_unit"];
	if (_unit != ACE_player) exitWith {};
	if (["task_force_radio"] call EFUNC(common,isModLoaded)) then {
	_unit setVariable ["tf_voiceVolume", 1, true];
	_unit setVariable ["tf_unable_to_use_radio", false];
	};
	if (["acre_main"] call EFUNC(common,isModLoaded)) then {
	_unit setVariable ["acre_sys_core_isDisabled", false, true];
	};
	[QUOTE(ADDON), 1, false] call EFUNC(common,setHearingCapability);
	}] call CBA_fnc_addEventHandler;
	// Update effects to match new unit's current status (this also handles respawn)
	["unit", {
	params ["_new"];
	private _status = IS_UNCONSCIOUS(_new);
	if (["task_force_radio"] call EFUNC(common,isModLoaded)) then {
	_new setVariable ["tf_voiceVolume", [1, 0] select _status, true];
	_new setVariable ["tf_unable_to_use_radio", _status];
	};
	if (["acre_main"] call EFUNC(common,isModLoaded)) then {
	_new setVariable ["acre_sys_core_isDisabled", _status, true];
	};
	[QUOTE(ADDON), VOL_UNCONSCIOUS, _status] call EFUNC(common,setHearingCapability);
	[true] call FUNC(handleEffects);
	["unconscious", _status] call EFUNC(common,setDisableUserInputStatus);
	}] call CBA_fnc_addPlayerEventHandler;

[Whigital]

Moving the EFUNC(common,setVolume) call from ace_medical_status_fnc_setUnconsciousState -> medical_feedback/XEH_postInit (ace_unconscious EH and unit playerEH) should suffice ?

From what i can see, the only place the event gets raised is at the end of ace_medical_status_fnc_setUnconsciousState.

Volume gets restored upon respawn, so might not be necessary on ace_medical_death event ?

ACE3/addons/common/functions/fnc_resetAllDefaults.sqf

Line 24 in 5a4487f

[true] call FUNC(setVolume);

[kymckay]

@Whigital I would include on death because death does not always immediately lead to respawn and could be filled with other systems (most commonly spectator time).

However, on death it would only apply when the _unit == player since setVolume updates the player's sound specifically (and death of any ACE_player !== player results in a unit change back to player which triggers the unit event).

In fact, it should probably be clarified how TFAR and ACRE handle the unit variables that function is setting (always on player), I would assume that they only apply for that unit and those addons aren't just using player as a storage vessel. If they are unit specific then that function would be much more useful for us here if you could pass in a unit parameter.

[jonpas]

ACRE uses a similar system to ace_player.

[kymckay]

Figured as much, then the way I would fix this is add an option parameter to the common function to pass in a unit, and just update all three events in feedback postInit to call that function and pass in the unit if it's ace_player

[Whigital]

• Update ace_common_fnc_setVolume with something like

params [
    ["_setVolume", false],
    ["_unit", player]
];

• Update the setvar's in ace_common_fnc_setVolume with _unit instead of player.

• Update medical_feedback/XEH_postInit with [<true|false>, _unit] call EFUNC(common,setVolume) for ace_unconscious and ace_medical_deathevents (checks for ACE_player alredy there).

• For the unit EH in medical_feedback/XEH_postInit, check for ACE_player.

if (_new == ACE_player) then {
    [<true|false>, _new] call EFUNC(common,setVolume)
};

[kymckay]

That sound right 👍

Only thing is the "unit" event _new is ACE_player by definition so no need to check that. Also note you can replace the existing lines which set TFAR and ACRE variables in all those EHs.

[Whigital]

Beautify the setVolume function and get rid of the if statement ?

private _vol = ([MUTED_LEVEL, NORMAL_LEVEL] select _setVolume);
private _voice = ([NO_SOUND, NORMAL_LEVEL] select _setVolume);

2 fadeSound _vol;

//TFAR
_unit setVariable ["tf_voiceVolume", _voice , true];
_unit setVariable ["tf_globalVolume", _vol];
_unit setVariable ["tf_unable_to_use_radio", !_setVolume];

// ACRE2
if (!isNil "acre_api_fnc_setGlobalVolume") then { [_vol^0.33] call acre_api_fnc_setGlobalVolume; };
_unit setVariable ["acre_sys_core_isDisabled", !_setVolume, true];

[kymckay]

Feel free to do so, current changes look correct to me

I also notice we're calling the setHearingCapability function which looks like it has some overlap with this setVolume function (both interact with fadeSound, tf_globalVolume and acre_api_fnc_setGlobalVolume).

This area of the code could probably use some cleanup (would avoid that for this PR and just focus on the fix, just noting for other ace devs).

[Whigital]

Roger. Will keep the changes in this PR to just fixing the issue at hand.

[Whigital]

Think i'll leave this PR as is. Will verify functionality and report back.

[Whigital]

Toggling unconscious lowers volume and disables the use of ACRE radio without issues.

Not been able to test in MP, but should work the same, considering the code removed from the EH's now run in ace_common_fnc_setVolume instead.