Extensions - Replace ace_parse_imagepath with SQF regexFind

[PabstMirror]

slower than the extension, but a lot simpler

[jonpas]

How much slower? Does it matter in this use case since it's interact menu?

[PabstMirror]

1.31926 ms for 10x - Original SQF (Can sorta understand why I thought we needed an extension)
"<img image='\A3\Ui_f\data\IGUI\Cfg\Actions\open_door_ca.paa' size='2.5' />" call originalSqfFrom2015;

0.0094 ms for 10x - callExtension
"ace_parse_imagepath" callExtension "<img image='\A3\Ui_f\data\IGUI\Cfg\Actions\open_door_ca.paa' size='2.5' />";

0.0532 ms for 10x - new regex
(("<img image='\A3\Ui_f\data\IGUI\Cfg\Actions\open_door_ca.paa' size='2.5' />" regexFind ["[\w\-\\]+.paa",0]) param [0, [""]]) select 0;

0.0565 ms for 10x - "modern" SQF
"<img image='\A3\Ui_f\data\IGUI\Cfg\Actions\open_door_ca.paa' size='2.5' />" call modernSQF;

originalSqfFrom2015 = {
    params ["_actionDisplayNameDefault"];
    _iconImage = ""; 
    _endIndex = _actionDisplayNameDefault find ".paa'"; 
    if (_endIndex == -1) exitWith { "" }; 
    _startIndex = _endIndex - 1; 
    _endIndex = _endIndex + 4; 
    while {(_startIndex > 0) && {_iconImage == ""}} do { 
        if ((_actionDisplayNameDefault select [_startIndex, 1]) == "'") then { 
            _startIndex = _startIndex + 1; 
            _iconImage = _actionDisplayNameDefault select [_startIndex, (_endIndex - _startIndex)]; 
        }; 
        _startIndex = _startIndex - 1; 
    }; 
    _iconImage
};

yuck, no wonder it was so slow

better sqf would also be fine, something like

{
    params ["_input"]; 
    private _end = _input find ".paa'"; 
    if (_end == -1) exitWith { "" }; 
    private _startSub = reverse (_input select [0, _end]); 
    private _start = _end - (_startSub find "'"); 
    _input select [_start, (_end - _start + 4)]
}

[jonpas]

Awesome! Always nice to see optimizations with some numbers!

[dedmen]

Btw Arma 2.06 has regex.

[jonpas]

Never mind, I forgot we are on 2.04 and not 2.06 yet. 🤕