Overheating - Fix issues from release

addons/overheating/XEH_PREP.hpp

@@ -6,6 +6,7 @@ PREP(canCheckSpareBarrelsTemperatures);
 PREP(checkSpareBarrelsTemperatures);
 PREP(checkTemperature);
 PREP(clearJam);
+PREP(cookoffWeapon);
 PREP(coolWeaponWithItem);
 PREP(coolWeaponWithWaterSource);
 PREP(displayTemperature);

addons/overheating/functions/fnc_calculateCooling.sqf

@@ -19,9 +19,12 @@
 
 params ["_temperature", "_barrelMass", "_totalTime"];
 
-if (_temperature < 1) exitWith {0};
+// The lowest temperaure a weapon can reach is the ambient air temperature.
+private _ambientTemperature = ambientTemperature select 0;
+
 // If a long time passed since the last shot, there's no need to calculate anything; the weapon should be cool
-if (_totalTime > 1800) exitWith {0};
+if (_totalTime > 1800) exitWith {_ambientTemperature};
+if (_temperature <= _ambientTemperature) exitWith {_ambientTemperature};
 
 //AR-15 (0.00570m bullet diameter) (barrel diameter usually 0.75" or 0.008255m radius)
 //Steel Denisty = 7850 m^3 / kg
@@ -51,15 +54,15 @@ while {true} do {
         _convectionRate * _barrelSurface * _temperature
         // Radiative cooling
         + 0.4 * 5.67e-8 * _barrelSurface * ((_temperature + 273.15) ^ 4 - 273.15 ^ 4)
-    ) * _deltaTime / (_barrelMass * 466);
+    ) * GVAR(coolingCoef) * _deltaTime / (_barrelMass * 466);
 
-    if (_temperature < 1) exitWith {0};
+    if (_temperature <= _ambientTemperature) exitWith {_ambientTemperature};
 
     if (isNil "_temperature") exitWith {
         diag_log text format ["[ACE] ERROR: _totalTime = %1; _time = %2; _deltaTime = %3;", _totalTime, _time, _deltaTime];
         0
     };
 
     _time = _time + _deltaTime;
-    if (_time >= _totalTime) exitWith { _temperature max 0 };
+    if (_time >= _totalTime) exitWith {_temperature max _ambientTemperature};
 };

addons/overheating/functions/fnc_cookoffWeapon.sqf

@@ -0,0 +1,66 @@
+#include "script_component.hpp"
+/*
+ * Author: drofseh
+ * Cookoff loaded round.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ * 1: Weapon <STRING>
+ * 2: Is Weapon Jammed <BOOL>
+ * 3: Type of Jam <STRING>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [player, currentWeapon player, true, "Fire"] call ace_overheating_fnc_cookoffWeapon
+ *
+ * Public: No
+ */
+
+params ["_unit", "_weapon", "_canUnjam", "_jamType"];
+TRACE_4("params",_unit,_weapon,_canUnjam,_jamType);
+
+// a weapon with a failure to fire or dud type jam will be unjammed from cooking off
+// this is first so that the fired event from the cookoff can also cause a jam
+if (_canUnjam && {_jamType in ["Fire","Dud"]}) then {
+    [_unit, currentMuzzle _unit, true] call FUNC(clearJam);
+
+    // clearJam will remove a dud round, but so will the forced fire, so give back the lost round and shoot it
+    if (_jamType isEqualTo "Dud") then {
+        _unit setAmmo [_weapon, (_unit ammo _weapon) + 1];
+    };
+};
+
+// get valid mode and muzzle for the main weapon, we don't want the cookoff to come from an underbarrel launcher
+([_weapon] call FUNC(getWeaponData)) params ["", "", "", "_modes", "_muzzle", "_reloadTime"];
+
+// get an appropriate firemode and muzzle, cache the current muzzle
+// trying to match firemodes and switching back to the cached muzzle will hide the change from the player and prevent unexpected mode/muzzle changes (going from full auto to semi auto, or from underbarrel GL to rifle for example)
+private _muzzleCache = currentMuzzle _unit;
+private _mode = currentWeaponMode _unit;
+if !(_mode in _modes) then {
+    _mode = _modes select 0;
+};
+
+// delay cookoff to ensure any previous animation from a fired event is finished
+[
+    {
+        params ["_unit", "_muzzleCache", "_mode", "_muzzle"];
+
+        // fire the cookoff
+        _unit forceWeaponFire [_muzzle, _mode];
+
+        // switch back to the cached muzzle if required
+        if (_muzzle != _muzzleCache) then {
+            _unit selectWeapon _muzzleCache;
+        };
+
+        [
+            [localize LSTRING(WeaponCookedOff)],
+            true // allows the hint to be overwritten by another hint, such as a jam or another cookoff
+        ] call CBA_fnc_notify;
+    },
+    [_unit, _muzzleCache, _mode, _muzzle],
+    _reloadTime
+] call CBA_fnc_waitAndExecute;

addons/overheating/functions/fnc_coolWeaponWithItem.sqf

@@ -95,4 +95,4 @@ private _fnc_condition = {
     {}, //_fnc_onFailure,
     _consumeText,
     _fnc_condition
-] call EFUNC(common,progressBar);
+] call EFUNC(common,progressBar);

addons/overheating/functions/fnc_jamWeapon.sqf

@@ -51,7 +51,9 @@ if (_jamTypesAllowed isEqualTo []) then {
     };
 };
 
-_unit setVariable [format [QGVAR(%1_jamType), _weapon], selectRandomWeighted _jamTypesAllowed];
+private _jamType = selectRandomWeighted _jamTypesAllowed;
+_unit setVariable [format [QGVAR(%1_jamType), _weapon], _jamType];
+
 
 // Stop current burst
 _unit setAmmo [_weapon, 0];
@@ -72,7 +74,7 @@ if (_weapon == primaryWeapon _unit) then {
 // only display the hint once, after you try to shoot an already jammed weapon
 GVAR(knowAboutJam) = false;
 
-["ace_weaponJammed", [_unit,_weapon]] call CBA_fnc_localEvent;
+["ace_weaponJammed", [_unit, _weapon, _jamType]] call CBA_fnc_localEvent;
 
 if (_unit getVariable [QGVAR(JammingActionID), -1] == -1) then {
 

addons/overheating/functions/fnc_overheat.sqf

@@ -28,7 +28,7 @@ BEGIN_COUNTER(overheat);
 // Get bullet parameters
 private _energyIncrement = GVAR(cacheAmmoData) getVariable _ammo;
 if (isNil "_energyIncrement") then {
-    _bulletMass = getNumber (configFile >> "CfgAmmo" >> _ammo >> "ACE_BulletMass");
+    private _bulletMass = getNumber (configFile >> "CfgAmmo" >> _ammo >> "ACE_BulletMass");
     if (_bulletMass == 0) then {
         // If the bullet mass is not configured, estimate it
         _bulletMass = 3.4334 + 0.5171 * (getNumber (configFile >> "CfgAmmo" >> _ammo >> "hit") + getNumber (configFile >> "CfgAmmo" >> _ammo >> "caliber"));
@@ -38,7 +38,7 @@ if (isNil "_energyIncrement") then {
     // Ref: https://en.wikipedia.org/wiki/Physics_of_firearms
     // Muzzle Engergy = 1/2 * m * v^2 = (1/2 * 0.001 g/kg * bulletMass (grams) * v^2)
     // Multiple by 3 becase we only calc every 3rd bullet: (3 * 1/2 * 0.001) = 0.0015
-    _energyIncrement = 0.0015 * _bulletMass * (vectorMagnitudeSqr velocity _projectile);
+    _energyIncrement = GVAR(heatCoef) * 0.0015 * _bulletMass * (vectorMagnitudeSqr velocity _projectile);
 
     GVAR(cacheAmmoData) setVariable [_ammo, _energyIncrement];
 };
@@ -54,9 +54,11 @@ private _silencer = switch (_weapon) do {
 if (_silencer != "") then {
     private _silencerCoef = GVAR(cacheSilencerData) getVariable _silencer;
     if (isNil "_silencerCoef") then {
-        _silencerCoef = 1 +
-                        (1 - getNumber (configFile >> "CfgWeapons" >> _silencer >> "ItemInfo" >> "AmmoCoef" >> "audibleFire")) +
-                        (1 - getNumber (configFile >> "CfgWeapons" >> _silencer >> "ItemInfo" >> "AmmoCoef" >> "visibleFire"));
+        _silencerCoef = 1 + (
+            1 - getNumber (configFile >> "CfgWeapons" >> _silencer >> "ItemInfo" >> "AmmoCoef" >> "audibleFire")
+        ) + (
+            1 - getNumber (configFile >> "CfgWeapons" >> _silencer >> "ItemInfo" >> "AmmoCoef" >> "visibleFire")
+        );
         GVAR(cacheSilencerData) setVariable [_silencer, _silencerCoef];
     };
     _energyIncrement = _energyIncrement * _silencerCoef;

addons/overheating/functions/fnc_updateAmmoTemperature.sqf

@@ -22,21 +22,23 @@ TRACE_3("params",_unit,_weapon,_barrelTemperature);
 
 private _closedBolt = getNumber (configFile >> "CfgWeapons" >> _weapon >> QGVAR(closedBolt));
 private _canUnjam = [_unit] call FUNC(canUnjam);
+private _jamType = _unit getVariable [format [QGVAR(%1_jamType), _weapon], "None"];
 
 // Skip if no ammo in chamber
 if (
     _unit ammo _weapon < 1
     // closed bolt, and jammed and type not failure to fire
-    || {_closedBolt == 1 && {_canUnjam} && {!(_unit getVariable [format [QGVAR(%1_jamType), _weapon], "None"] in ["Fire","Dud"])}}
+    || {_closedBolt == 1 && {_canUnjam} && {!(_jamType in ["Fire","Dud"])}}
     // open bolt, and not jammed, or jammed and type not failure to fire
-    || {_closedBolt == 0 && {!_canUnjam || {_canUnjam && {!(_unit getVariable [format [QGVAR(%1_jamType), _weapon], "None"] in ["Fire","Dud"])}}}}
+    || {_closedBolt == 0 && {!_canUnjam || {_canUnjam && {!(_jamType in ["Fire","Dud"])}}}}
 ) exitWith {
-    _unit setVariable [format [QGVAR(%1_ammoTemp), _weapon], 0];
-    0
+    private _ambientTemperature = ambientTemperature select 0;
+    _unit setVariable [format [QGVAR(%1_ammoTemp), _weapon], _ambientTemperature];
+    _ambientTemperature
 };
 
 private _ammoTempVarName = format [QGVAR(%1_ammoTemp), _weapon];
-private _ammoTemperature = _unit getVariable [_ammoTempVarName, 0];
+private _ammoTemperature = _unit getVariable [_ammoTempVarName, ambientTemperature select 0];
 
 // heat or cool the ammo
 if (_ammoTemperature < _barrelTemperature) then {
@@ -47,58 +49,12 @@ if (_ammoTemperature < _barrelTemperature) then {
     _ammoTemperature = _barrelTemperature;
 };
 
-// check for cook off
+// cookoff if too hot
 if (_ammoTemperature > (GUNPOWDER_IGNITION_TEMP * GVAR(cookoffCoef))) then {
+    [_unit, _weapon, _canUnjam, _jamType] call ace_overheating_fnc_cookoffWeapon;
 
-    // a weapon with a failure to fire or dud type jam will be unjammed from cooking off
-    // this is first so that the fired event from the cookoff can also cause a jam
-    private _jamType = _unit getVariable [format [QGVAR(%1_jamType), _weapon], "None"];
-    if (_canUnjam && {_jamType in ["Fire","Dud"]}) then {
-
-        [_unit, currentMuzzle _unit, true] call FUNC(clearJam);
-
-        // clearJam will remove a dud round, but so will the forced fire, so give back the lost round and shoot it
-        if (_jamType isEqualTo "Dud") then {
-            private _ammo = _unit ammo _weapon;
-            _unit setAmmo [_weapon, _ammo + 1];
-        };
-    };
-
-    // get valid mode and muzzle for the main weapon, we don't want the cookoff to come from an underbarrel launcher
-    ([_weapon] call FUNC(getWeaponData)) params ["", "", "", "_modes", "_muzzle", "_reloadTime"];
-
-    // get an appropriate firemode and muzzle, cache the current muzzle
-    // trying to match firemodes and switching back to the cached muzzle will hide the change from the player and prevent unexpected mode/muzzle changes (going from full auto to semi auto, or from underbarrel GL to rifle for example)
-    private _muzzleCache = currentMuzzle _unit;
-    private _mode = currentWeaponMode _unit;
-    if !(_mode in _modes) then {
-        _mode = _modes select 0;
-    };
-
-    // delay cookoff to ensure any previous animation from a fired event is finished
-    [
-        {
-            params ["_unit", "_muzzleCache", "_mode", "_muzzle"];
-
-            // fire the cookoff 
-            _unit forceWeaponFire [_muzzle, _mode];
-
-            // switch back to the cached muzzle if required
-            if (_muzzle != _muzzleCache) then {
-                _unit selectWeapon _muzzleCache;
-            };
-
-            [
-                [localize LSTRING(WeaponCookedOff)],
-                true // allows the hint to be overwritten by another hint, such as a jam or another cookoff
-            ] call CBA_fnc_notify;
-        },
-        [_unit, _muzzleCache, _mode, _muzzle],
-        _reloadTime
-    ] call CBA_fnc_waitAndExecute;
-
-    // if the cookoff happened then the next round should start at 0
-    _ammoTemperature = 0;
+    // since a cookoff happened then the next round should start at the ambient temperature.
+    _ammoTemperature = ambientTemperature select 0;
 };
 
 _unit setVariable [_ammoTempVarName, _ammoTemperature];

addons/overheating/functions/fnc_updateAmmoTemperatureThread.sqf

@@ -15,6 +15,11 @@
  * Public: No
  */
 
+// If the ace_overheating_cookoffCoef setting is set to 0 mid mission we want to exit right away or it will immediate cause all player weapons to cook off.
+if (GVAR(cookoffCoef) isEqualTo 0) exitWith {
+    WARNING_1("'%1' has been set to 0 mid mission. Changing this setting requires mission restart.",GVAR(cookoffCoef));
+};
+
 private _currentWeapon = currentWeapon ACE_player;
 if ((_currentWeapon != "") && {_currentWeapon == primaryWeapon ACE_player || {_currentWeapon == handgunWeapon ACE_player}}) then {
     private _temperature = ACE_player getVariable [format [QGVAR(%1_temp), _currentWeapon], 0];

addons/overheating/functions/fnc_updateTemperature.sqf

@@ -35,7 +35,7 @@ _temperature = [_temperature, _barrelMass, CBA_missionTime - _lastTime] call FUN
 TRACE_1("cooledTo",_temperature);
 // Calculate heating
 // Steel Heat Capacity = 466 J/(Kg.K)
-_temperature = _temperature + _heatIncrement * GVAR(heatCoef) / (_barrelMass * 466);
+_temperature = _temperature + _heatIncrement / (_barrelMass * 466);
 
 // Publish the temperature variable
 [_unit, _tempVarName, _temperature, TEMP_TOLERANCE] call EFUNC(common,setApproximateVariablePublic);

addons/overheating/initSettings.sqf

@@ -15,7 +15,19 @@ private _category = format ["ACE %1", localize LSTRING(DisplayName)];
     [LSTRING(heatCoef_displayName), LSTRING(heatCoef_description)],
     _category,
     [0, 5, 1, 2],
-    1
+    1,
+    {},
+    true
+] call CBA_fnc_addSetting;
+
+[
+    QGVAR(coolingCoef), "SLIDER",
+    [LSTRING(coolingCoef_displayName), LSTRING(coolingCoef_description)],
+    _category,
+    [0, 5, 1, 2],
+    1,
+    {},
+    true
 ] call CBA_fnc_addSetting;
 
 [

addons/overheating/stringtable.xml

@@ -60,6 +60,12 @@
             <Russian>Коэффициент количества тепла, выделяемого оружием за выстрел. \nБольшие значения увеличивают нагрев.</Russian>
             <Polish>Współczynnik wpływający na ilość ciepła generowanego przez broń przy każdym strzale.</Polish>
         </Key>
+        <Key ID="STR_ACE_Overheating_coolingCoef_displayName">
+            <English>Cooling Coefficient</English>
+        </Key>
+        <Key ID="STR_ACE_Overheating_coolingCoef_description">
+            <English>Coefficient for how quickly a weapon cools down.\nHigher value increases cooling speed.</English>
+        </Key>
         <Key ID="STR_ACE_Overheating_DisplayTextOnJam_displayName">
             <English>Display Text on Jam</English>
             <German>Zeige Text bei Ladehemmung</German>
@@ -266,7 +272,7 @@
             <English>Unjam on Barrel Swap</English>
             <Japanese>銃身交換で弾詰まり解消</Japanese>
             <French>Désenrayer l'arme au changement de canon</French>
-            <Russian>Замена ствола устраняет заклинивание оружия.</Russian> 
+            <Russian>Замена ствола устраняет заклинивание оружия.</Russian>
             <Polish>Usuń zacięcie przy wymianie lufy</Polish>
         </Key>
         <Key ID="STR_ACE_Overheating_unJamOnSwapBarrel_description">

docs/wiki/feature/overheating.md

@@ -53,12 +53,11 @@ Jams can be cleared in the following ways:
 - Select `Equipment`.
 - Select `Check weapon temperature`.
 
-**NOTE** When the bar is half full (yellow) it means the barrel is around 500°c.
-Your weapon will be even more prone to jams, and it'll get worse if you don't let the barrel cool down or swap it.
+**NOTE** Each section on the bar represents 100°c. When the bar reaches 2 sections weapons can start to cookoff. When it is half full (yellow) it means the barrel is around 500°c. Your weapon will be even more prone to jams, and it'll get worse if you don't let the barrel cool down or swap it.
 
 ### 2.4 Cooling your weapon
 
-- Weapons and spare barrels will cool off over time.
+- Weapons and spare barrels will cool off over time, down to the ambient temperature in the mission.
 - Cooling speed of weapons in increased in windy or rainy weather, and when swimming.
 - If ACE Field Rations is loaded then weapons can be cooled with canteens, water bottles, or other beverage items. This does not require the Field Rations system to be enabled.
 - If ACE Field Rations is enabled then weapons can also be cooled with the same water sources used to refill canteens and water bottles.