Medical Damage - Add alternate armor penetration

addons/medical_damage/ACE_Medical_Injuries.hpp

@@ -80,6 +80,9 @@ class ACE_Medical_Injuries {
             // bullets only create multiple wounds when the damage is very high
             thresholds[] = {{20, 10}, {4.5, 2}, {3, 1}, {0, 1}};
             selectionSpecific = 1;
+            class woundHandlers: woundHandlers {
+                GVAR(armorPenetration) = QFUNC(woundsHandlerArmorPenetration);
+            };
 
             class Avulsion {
                 // at damage, weight. between points, weight is interpolated then wound is chosen by weighted random.

addons/medical_damage/XEH_PREP.hpp

@@ -1,11 +1,13 @@
 PREP(debug_explosiveTest);
 PREP(determineIfFatal);
+PREP(getAmmoData);
 PREP(getTypeOfDamage);
 PREP(handleIncapacitation);
 PREP(interpolatePoints);
 PREP(parseConfigForInjuries);
 PREP(parseWoundHandlersCfg);
 PREP(woundReceived);
+PREP(woundsHandlerArmorPenetration);
 PREP(woundsHandlerBase);
 PREP(woundsHandlerBurning);
 PREP(woundsHandlerVehiclecrash);

addons/medical_damage/XEH_preInit.sqf

@@ -10,6 +10,9 @@ PREP_RECOMPILE_END;
 
 call FUNC(parseConfigForInjuries);
 
+// Used for armor penetration calculation
+GVAR(ammoCache) = createHashMap;
+
 /*
 addMissionEventHandler ["Loaded",{
     INFO("Mission Loaded - Reloading medical configs for extension");

addons/medical_damage/functions/fnc_getAmmoData.sqf

@@ -0,0 +1,30 @@
+#include "..\script_component.hpp"
+/*
+ * Author: LinkIsGrim
+ * Returns base damage value, penetration factor, and expected muzzle velocity of a given round, either from a cache or by reading the ammo config.
+ *
+ * Arguments:
+ * 0: Ammo <STRING>
+ *
+ * Return Value:
+ * Base damage value, penetration factor, muzzle velocity <ARRAY of NUMBER>
+ *
+ * Example:
+ * ["B_556x45_Ball"] call ace_medical_engine_fnc_getAmmoData
+ *
+ * Public: No
+ */
+// Baseline penetrability used for armor penetration calculation, see (https://community.bistudio.com/wiki/CfgAmmo_Config_Reference#caliber)
+#define ARMOR_PENETRABILITY 0.015
+
+params ["_ammo"];
+
+GVAR(ammoCache) getOrDefaultCall [_ammo, {
+    TRACE_1("Cache miss",_ammo);
+    private _ammoConfig = configFile >> "CfgAmmo" >> _ammo;
+    private _hit = getNumber (_ammoConfig >> "hit");
+    private _caliber = (getNumber (_ammoConfig >> "caliber"));
+    private _typicalSpeed = getNumber (_ammoConfig >> "typicalSpeed");
+    private _penFactor = _caliber * ARMOR_PENETRABILITY;
+    [_hit, _penFactor, _typicalSpeed] // return
+}, true] // return

addons/medical_damage/functions/fnc_woundReceived.sqf

@@ -25,8 +25,7 @@ private _typeOfDamage = _ammo call FUNC(getTypeOfDamage);
 if (_typeOfDamage in GVAR(damageTypeDetails)) then {
     (GVAR(damageTypeDetails) get _typeOfDamage) params ["", "", "_woundHandlers"];
 
-    private _damageData = [_unit, _allDamages, _typeOfDamage];
-
+    private _damageData = [_unit, _allDamages, _typeOfDamage, _ammo];
     {
         _damageData = _damageData call _x;
         TRACE_1("Wound handler returned",_damageData);

addons/medical_damage/functions/fnc_woundsHandlerArmorPenetration.sqf

@@ -0,0 +1,84 @@
+#include "..\script_component.hpp"
+/*
+ * Author: LinkIsGrim
+ * Custom wounds handler for armor penetration. Calculates damage based on round material penetration and unit armor
+ *
+ * Arguments:
+ * 0: Unit That Was Hit <OBJECT>
+ * 1: Damage done to each body part <ARRAY>
+ * 2: Type of the damage done <STRING>
+ * 3: Projectile classname <STRING> (default: "")
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [player, [[0.5, "Body", 1]], "bullet"] call ace_medical_damage_fnc_woundsHandlerArmorPenetration
+ *
+ * Public: No
+ */
+
+// armor 2 with passthrough 0.8
+#define SCALED_UNPROTECTED_VALUE 4
+#define ENGINE_DAMAGE_INDEX 0
+
+// This gets close to vanilla values on FMJ ammo
+#define DAMAGE_SCALING_FACTOR 10
+
+// Based off #9216 armor values for vanilla vests
+#define ARMOR_LEVEL_1_CAP 12
+#define ARMOR_LEVEL_2_CAP 14
+#define ARMOR_LEVEL_3_CAP 16
+#define ARMOR_LEVEL_4_CAP 20
+
+params ["_unit", "_allDamages", "_typeOfDamage", ["_ammo", ""]];
+TRACE_3("woundsHandlerArmorPenetration",_unit,_allDamages,_typeOfDamage);
+
+if !(EGVAR(medical,alternateArmorPenetration) && {_ammo isNotEqualTo ""}) exitWith {_this};
+
+private _damageData = (_allDamages select 0); // selection specific
+_damageData params ["_engineDamage", "", "_realDamage"];
+
+private _armor = (_realDamage/_engineDamage) - SCALED_UNPROTECTED_VALUE;
+// There's no need to calculate penetration if there is no armor to begin with, vanilla damage handling is good enough in this case
+if (_armor <= 0) exitWith {
+    _this // return
+};
+
+// Armor RHA equivalent, non-linear, ref \a3\Data_F\Penetration\armour_plate/thin/medium/heavy.bisurf
+// Divided by 2 to keep inline with vanilla caliber values
+// Excedent armor over the cap gets added as a small bonus to thickness
+private _armorThickness = _armor/2;
+switch (true) do {
+    case (_armor >= ARMOR_LEVEL_4_CAP): {
+        _armorThickness = 55 - (ARMOR_LEVEL_4_CAP - _armor);
+    };
+    case (_armor >= ARMOR_LEVEL_3_CAP): {
+        _armorThickness = 40 - (ARMOR_LEVEL_3_CAP - _armor);
+    };
+    case (_armor >= ARMOR_LEVEL_2_CAP): {
+        _armorThickness = 15 - (ARMOR_LEVEL_2_CAP - _armor);
+    };
+    case (_armor >= ARMOR_LEVEL_1_CAP): {
+        _armorThickness = 6 - (ARMOR_LEVEL_1_CAP - _armor);
+    };
+};
+
+// See (https://community.bistudio.com/wiki/CfgAmmo_Config_Reference#caliber),
+// _penFactor is ammo "caliber" * RHA penetrability, armor plates according to BI are just made of RHA with different thickness
+([_ammo] call FUNC(getAmmoData)) params ["_hit", "_penFactor", "_typicalSpeed"];
+
+// Impact damage is hit * (impactSpeed / typicalSpeed): https://community.bistudio.com/wiki/CfgAmmo_Config_Reference#typicalSpeed
+// Impact damage is already lowered by engine based on hit angle, so speed and therefore penetration are also naturally lowered
+private _impactSpeed = (_realDamage/_hit) * _typicalSpeed;
+
+private _penDepth = _penFactor * _impactSpeed;
+
+// We want to base damage on the round's energy and armor penetration exclusively, so we'll use the config value to get damage
+// There's only so much damage a round can do, limited by its energy
+private _finalDamage = (_hit * ((_penDepth/_armorThickness) min 1)) / DAMAGE_SCALING_FACTOR;
+_damageData set [ENGINE_DAMAGE_INDEX, _finalDamage];
+
+TRACE_3("Armor penetration handled, passing damage",_finalDamage,_damageData,_allDamages);
+
+_this // return

addons/medical_damage/initSettings.inc.sqf

@@ -1,3 +1,12 @@
+[
+    QEGVAR(medical,alternateArmorPenetration),
+    "CHECKBOX",
+    [LSTRING(AlternateArmorPenetration_DisplayName), LSTRING(AlternateArmorPenetration_Description)],
+    ELSTRING(medical,Category),
+    true,
+    true
+] call CBA_fnc_addSetting;
+
 [
     QEGVAR(medical,fatalDamageSource),
     "LIST",

addons/medical_damage/stringtable.xml

@@ -863,5 +863,11 @@
             <Russian>Использовать урон конечностям</Russian>
             <Japanese>手足のダメージを使用</Japanese>
         </Key>
+        <Key ID="STR_ACE_Medical_Damage_AlternateArmorPenetration_DisplayName">
+            <English>Use Alternate Armor Penetration</English>
+        </Key>
+        <Key ID="STR_ACE_Medical_Damage_AlternateArmorPenetration_Description">
+            <English>Controls whether ammo material penetration ("caliber") is taken into account for damage handling.</English>
+        </Key>
     </Package>
 </Project>

docs/wiki/framework/medical-framework.md

@@ -224,6 +224,7 @@ Custom wound handlers should follow the same spec as the built-in handler:
 | 0  | Unit that was hit | Object | Required |
 | 1  | Array of damage dealt to each body part | Array | Required |
 | 2  | Type of damage | String | Required |
+| 3  | Ammo | String | Optional |
 | **R** | Parameters to be passed to the next handler in the list, e.g. `_this` or a modified copy of it. Return `[]` to prevent further handling. | Array | Required |
 
 The damage elements are sorted in descending order according to how much damage was dealt to each body part _before armor was taken into account_, but the actual damage values are _after armor_.