AI - Add automatic NVG equip/unequip

addons/ai/XEH_PREP.hpp

@@ -1,3 +1,4 @@
+PREP(assignNVG);
 PREP(drawCuratorGarrisonPathing);
 PREP(garrison);
 PREP(garrisonMove);

addons/ai/XEH_postInit.sqf

@@ -68,3 +68,8 @@
     params ["_unit", "_mode"];
     _unit enableGunLights _mode;
 }] call CBA_fnc_addEventHandler;
+
+
+if (isServer) then {
+    call FUNC(assignNVG);
+};

addons/ai/XEH_preInit.sqf

@@ -6,4 +6,6 @@ PREP_RECOMPILE_START;
 #include "XEH_PREP.hpp"
 PREP_RECOMPILE_END;
 
+#include "initSettings.sqf"
+
 ADDON = true;

addons/ai/functions/fnc_assignNVG.sqf

@@ -0,0 +1,45 @@
+#include "script_component.hpp"
+/*
+ * Author: Jonpas
+ * Assigns AI first found NVG in their inventory during night time and unassigns it during day time.
+ * Calls itself periodically.
+ *
+ * Arguments:
+ * None
+
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [] call ace_ai_fnc_assignNVG
+ *
+ * Public: No
+ */
+
+if (!GVAR(assignNVG)) exitWith {};
+
+private _equip = sunOrMoon < 1 || moonIntensity > 0.8;
+
+{
+    private _unit = _x;
+    if (alive _unit && !isPlayer _unit) then {
+        private _nvg = hmd _unit;
+
+        if (_equip) then {
+            if (_nvg == "") then {
+                private _items = [_unit, false, true, true, true, false, false] call CBA_fnc_uniqueUnitItems; // backpack, vest, uniform
+                {
+                    if (getText (configFile >> "CfgWeapons" >> _x >> "simulation") == "NVGoggles") exitWith {
+                        _unit assignItem _x;
+                    };
+                } forEach _items;
+            };
+        } else {
+            if (_nvg != "" && {currentVisionMode _unit == 0} && {_unit canAdd _nvg}) then {
+                _unit unassignItem _nvg;
+            };
+        };
+    };
+} forEach allUnits;
+
+[FUNC(assignNVG), 300] call CBA_fnc_waitAndExecute;

addons/ai/initSettings.sqf

@@ -0,0 +1,10 @@
+private _category = format ["ACE %1", localize LSTRING(DisplayName)];
+
+[
+    QGVAR(assignNVG), "CHECKBOX",
+    [LSTRING(AssignNVG_DisplayName), LSTRING(AssignNVG_Description)],
+    _category,
+    false,
+    1,
+    FUNC(assignNVG)
+] call CBA_fnc_addSetting;

addons/ai/stringtable.xml

@@ -1,6 +1,9 @@
 <?xml version="1.0" encoding="utf-8"?>
 <Project name="ACE">
     <Package name="AI">
+        <Key ID="STR_ACE_AI_DisplayName">
+            <English>AI</English>
+        </Key>
         <Key ID="STR_ACE_AI_GarrisonInvalidPosition">
             <English>Invalid position provided.</English>
             <German>Ungültige Position</German>
@@ -65,5 +68,11 @@
             <Czech>Nenalezena žádná budova.</Czech>
             <Turkish>Bir yapı bulunamadı</Turkish>
         </Key>
+        <Key ID="STR_ACE_AI_AssignNVG_DisplayName">
+            <English>Assign NVG</English>
+        </Key>
+        <Key ID="STR_ACE_AI_AssignNVG_Description">
+            <English>Assigns NVG in AI's inventory during night time and unassigns it during day time.</English>
+        </Key>
     </Package>
 </Project>