Allow the CMake project to use system-wide installed dependencies

.editorconfig

@@ -0,0 +1,10 @@
+# See https://editorconfig.org/ for more info :)
+
+[*]
+indent_style = space
+indent_size = 2
+trim_trailing_whitespace = true
+insert_final_newline = true
+
+[*.py]
+indent_size = 4

src/CMakeLists.txt

@@ -16,6 +16,12 @@ if(CCACHE_FOUND)
     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
 endif(CCACHE_FOUND)
 
+option(USE_SYSTEM_ASSIMP "Use system Assimp instead of a bundled submodule" OFF)
+option(USE_SYSTEM_EIGEN "Use system Eigen instead of a bundled submodule" OFF)
+option(USE_SYSTEM_MAGNUM "Use system Magnum instead of a bundled submodule" OFF)
+option(USE_SYSTEM_PYBIND11 "Use system Pybind11 instead of a bundled submodule" OFF)
+option(USE_SYSTEM_RAPIDJSON "Use system RapidJSON instead of a bundled submodule" OFF)
+
 set(BUILD_GUI_VIEWERS OFF CACHE BOOL "BUILD_GUI_VIEWERS")
 
 # set(CMAKE_BUILD_TYPE Debug)

src/cmake/FindEGL.cmake

@@ -0,0 +1,85 @@
+#.rst:
+# Find EGL
+# --------
+#
+# Finds the EGL library. This module defines:
+#
+#  EGL_FOUND            - True if EGL library is found
+#  EGL::EGL             - EGL imported target
+#
+# Additionally these variables are defined for internal usage:
+#
+#  EGL_LIBRARY          - EGL library
+#  EGL_INCLUDE_DIR      - Include dir
+#
+
+#
+#   This file is part of Magnum.
+#
+#   Copyright © 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019
+#             Vladimír Vondruš <mosra@centrum.cz>
+#
+#   Permission is hereby granted, free of charge, to any person obtaining a
+#   copy of this software and associated documentation files (the "Software"),
+#   to deal in the Software without restriction, including without limitation
+#   the rights to use, copy, modify, merge, publish, distribute, sublicense,
+#   and/or sell copies of the Software, and to permit persons to whom the
+#   Software is furnished to do so, subject to the following conditions:
+#
+#   The above copyright notice and this permission notice shall be included
+#   in all copies or substantial portions of the Software.
+#
+#   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+#   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+#   FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+#   THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+#   LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+#   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+#   DEALINGS IN THE SOFTWARE.
+#
+
+# Library
+if(NOT CORRADE_TARGET_EMSCRIPTEN)
+    find_library(EGL_LIBRARY NAMES
+        EGL
+
+        # ANGLE (CMake doesn't search for lib prefix on Windows)
+        libEGL
+
+        # On iOS a part of OpenGLES
+        OpenGLES)
+    set(EGL_LIBRARY_NEEDED EGL_LIBRARY)
+endif()
+
+# Include dir
+find_path(EGL_INCLUDE_DIR NAMES
+    EGL/egl.h
+
+    # iOS
+    EAGL.h)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(EGL DEFAULT_MSG
+    ${EGL_LIBRARY_NEEDED}
+    EGL_INCLUDE_DIR)
+
+if(NOT TARGET EGL::EGL)
+    if(EGL_LIBRARY_NEEDED)
+        # Work around BUGGY framework support on macOS
+        # http://public.kitware.com/pipermail/cmake/2016-April/063179.html
+        if(APPLE AND ${EGL_LIBRARY} MATCHES "\\.framework$")
+            add_library(EGL::EGL INTERFACE IMPORTED)
+            set_property(TARGET EGL::EGL APPEND PROPERTY
+                INTERFACE_LINK_LIBRARIES ${EGL_LIBRARY})
+        else()
+            add_library(EGL::EGL UNKNOWN IMPORTED)
+            set_property(TARGET EGL::EGL PROPERTY
+                IMPORTED_LOCATION ${EGL_LIBRARY})
+        endif()
+    else()
+        add_library(EGL::EGL INTERFACE IMPORTED)
+    endif()
+
+    set_target_properties(EGL::EGL PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES ${EGL_INCLUDE_DIR})
+endif()

src/cmake/FindGLFW.cmake

@@ -0,0 +1,94 @@
+#.rst:
+# Find GLFW
+# ---------
+#
+# Finds the GLFW library using its cmake config if that exists, otherwise
+# falls back to finding it manually. This module defines:
+#
+#  GLFW_FOUND               - True if GLFW library is found
+#  GLFW::GLFW               - GLFW imported target
+#
+# Additionally, in case the config was not found, these variables are defined
+# for internal usage:
+#
+#  GLFW_LIBRARY             - GLFW library
+#  GLFW_INCLUDE_DIR         - Root include dir
+#
+
+#
+#   This file is part of Magnum.
+#
+#   Copyright © 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019
+#             Vladimír Vondruš <mosra@centrum.cz>
+#   Copyright © 2016 Jonathan Hale <squareys@googlemail.com>
+#
+#   Permission is hereby granted, free of charge, to any person obtaining a
+#   copy of this software and associated documentation files (the "Software"),
+#   to deal in the Software without restriction, including without limitation
+#   the rights to use, copy, modify, merge, publish, distribute, sublicense,
+#   and/or sell copies of the Software, and to permit persons to whom the
+#   Software is furnished to do so, subject to the following conditions:
+#
+#   The above copyright notice and this permission notice shall be included
+#   in all copies or substantial portions of the Software.
+#
+#   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+#   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+#   FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+#   THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+#   LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+#   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+#   DEALINGS IN THE SOFTWARE.
+#
+
+# GLFW installs cmake package config files to shared/ folder which handles
+# dependencies in case GLFW is built statically. Try to find first, quietly, so
+# it doesn't print loud messages when it's not found, since that's okay.
+find_package(glfw3 CONFIG QUIET)
+
+if(TARGET glfw)
+    if(NOT TARGET GLFW::GLFW)
+        # Aliases of (global) targets are only supported in CMake 3.11, so we
+        # work around it by this. This is easier than fetching all possible
+        # properties (which are impossible to track of) and then attempting to
+        # rebuild them into a new target.
+        add_library(GLFW::GLFW INTERFACE IMPORTED)
+        set_target_properties(GLFW::GLFW PROPERTIES INTERFACE_LINK_LIBRARIES glfw)
+    endif()
+
+    # Just to make FPHSA print some meaningful location, nothing else
+    get_target_property(_GLFW_INTERFACE_INCLUDE_DIRECTORIES glfw INTERFACE_INCLUDE_DIRECTORIES)
+    include(FindPackageHandleStandardArgs)
+    find_package_handle_standard_args("GLFW" DEFAULT_MSG
+        _GLFW_INTERFACE_INCLUDE_DIRECTORIES)
+    return()
+endif()
+
+# In case no config file was found, try manually finding the library.
+find_library(GLFW_LIBRARY NAMES glfw glfw3)
+
+# Include dir
+find_path(GLFW_INCLUDE_DIR
+    NAMES GLFW/glfw3.h)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args("GLFW" DEFAULT_MSG
+    GLFW_LIBRARY
+    GLFW_INCLUDE_DIR)
+
+if(NOT TARGET GLFW::GLFW)
+    add_library(GLFW::GLFW UNKNOWN IMPORTED)
+
+    # Work around BUGGY framework support on macOS
+    # https://cmake.org/Bug/view.php?id=14105
+    if(CORRADE_TARGET_APPLE AND ${GLFW_LIBRARY} MATCHES "\\.framework$")
+        set_property(TARGET GLFW::GLFW PROPERTY IMPORTED_LOCATION ${GLFW_LIBRARY}/GLFW)
+    else()
+        set_property(TARGET GLFW::GLFW PROPERTY IMPORTED_LOCATION ${GLFW_LIBRARY})
+    endif()
+
+    set_property(TARGET GLFW::GLFW PROPERTY
+        INTERFACE_INCLUDE_DIRECTORIES ${GLFW_INCLUDE_DIR})
+endif()
+
+mark_as_advanced(GLFW_LIBRARY GLFW_INCLUDE_DIR)