How can i prevent that fzf open files inside NERDtree buffer? #453

heliohead · 2015-12-21T17:43:19Z

How can i prevent that fzf open files inside neotree buffer?
I am always do that, find files when neotree buffer is on focus :(

thanks

junegunn · 2015-12-22T15:31:52Z

Hmm, you'll probably have to use a custom mapping that moves the focus if the cursor is on that window. You mean nerdtree, right? Something like this:

nnoremap <silent> <expr> <Leader><Leader> (expand('%') =~ 'NERD_tree' ? "\<c-w>\<c-w>" : '').":FZF\<cr>"

heliohead · 2015-12-22T23:08:33Z

OH Yeah, i mean nerdtree, neotree is a emacs thing :p,
This map works like a charm :) 🏅 🎖
Thank you so much! and also thanks for the great job of your plugins and themes i love it 💫 🤘👍 .

Closing issue in 4...3...2...

mrleolink · 2016-04-22T15:34:49Z

Sorry, your command doesn't work for me.
I'm using newest version of both NerdTree and FZF, this problem still happens...

nnoremap <silent> <expr> <Leader><Leader> (expand('%') =~ 'NERD_tree' ? "\<c-w>\<c-w>" : '').":FZF\<cr>"

junegunn · 2016-04-22T18:20:12Z

@mrleolink Works for me. It's probably something in your configuration; some plugin or your own autocmd. Disable everything but fzf and nertree and see if the problem persists.

mrleolink · 2016-04-23T03:52:50Z

@junegunn Ok, so I tried to disable everything but the problem still persists.

I'm using neovim, this is my init.vim

execute pathogen#infect()
autocmd StdinReadPre * let s:std_in=1
autocmd VimEnter * if argc() == 0 && !exists("s:std_in") | NERDTree | endif

"fzf: https://github.com/junegunn/fzf
set rtp+=$FZF_HOME
map <c-p> :FZF<CR>
autocmd! FileType fzf tnoremap <buffer> <leader>q <c-p>
nnoremap <silent> <expr> <Leader><Leader> (expand('%') =~ 'NERD_tree' ? "\<c-w>\<c-w>" : '').":FZF\<cr>"

As you can see, I'm using pathogen to load nerdtree. I don't have anything else in my bundle folder.

junegunn · 2016-04-23T05:01:57Z

I suspect you don't fully understand the lines. The suggested line is a mapping of its own and not a global configuration so it does not affect <c-p> binding you have above. Change <leader><leader> to <c-p>.

mrleolink · 2016-04-23T05:20:54Z

It works!!!
Thank you 👍

dkarter · 2018-01-01T02:54:13Z

For anyone still looking for a solution I created the following function and put it in my .vimrc, it will also check the number of buffers and if you open vim like this vim . it will allow you to use your FZF mapping to open a file instead of the nerdtree browser:

function! FZFOpen(command_str)
  if (expand('%') =~# 'NERD_tree' && winnr('$') > 1)
    exe "normal! \<c-w>\<c-w>"
  endif
  exe 'normal! ' . a:command_str . "\<cr>"
endfunction

nnoremap <silent> <C-b> :call FZFOpen(':Buffers')<CR>
nnoremap <silent> <C-g>g :call FZFOpen(':Ag')<CR>
nnoremap <silent> <C-g>c :call FZFOpen(':Commands')<CR>
nnoremap <silent> <C-g>l :call FZFOpen(':BLines')<CR>
nnoremap <silent> <C-p> :call FZFOpen(':Files')<CR>

jeromedalbert · 2018-02-17T19:49:52Z

My comment has a bigger scope than this issue, but it is still related and this might interest some people. I currently have a more advanced setup that prevents opening any file in NERDTree when NERDtree is focused:

files opened with FZF
files opened with mappings, for example my VIMRC or the project README
files opened with :edit
etc.

Plus, if you change your mind and exit FZF, you still have focus on the original NERDTree. You don't need to <c-w><c-w> back, and you don't need wrapper functions.

Here is the code:

let g:fzf_layout = { 'window': 'let g:launching_fzf = 1 | keepalt topleft 100split enew' }

autocmd FileType nerdtree let t:nerdtree_winnr = bufwinnr('%')
autocmd BufWinEnter * call PreventBuffersInNERDTree()

function! PreventBuffersInNERDTree()
  if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree'
    \ && exists('t:nerdtree_winnr') && bufwinnr('%') == t:nerdtree_winnr
    \ && &buftype == '' && !exists('g:launching_fzf')
    let bufnum = bufnr('%')
    close
    exe 'b ' . bufnum
  endif
  if exists('g:launching_fzf') | unlet g:launching_fzf | endif
endfunction

It's kind of hacky because I do "code injection" by adding the g:launching_fzf variable inside the layout configuration. There may be a more elegant solution but in the meantime it works and I didn't have to change the FZF plugin source code.

Update ack mapping to avoid opening files in the NERDTree window Copied from junegunn/fzf#453 Hacky, but does the job. It would be nice to tidy this up and find a more general solution that will work with CtrlP, Ack, MRU and so on.

r-glebov · 2019-03-25T08:24:55Z

let g:fzf_layout = { 'window': 'let g:launching_fzf = 1 | keepalt topleft 100split enew' }

autocmd FileType nerdtree let t:nerdtree_winnr = bufwinnr('%')
autocmd BufWinEnter * call PreventBuffersInNERDTree()

function! PreventBuffersInNERDTree()
  if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree'
    \ && exists('t:nerdtree_winnr') && bufwinnr('%') == t:nerdtree_winnr
    \ && &buftype == '' && !exists('g:launching_fzf')
    let bufnum = bufnr('%')
    close
    exe 'b ' . bufnum
  endif
  if exists('g:launching_fzf') | unlet g:launching_fzf | endif
endfunction

Does this solution still works correctly for anybody?
Have problems with using it:

Error detected while processing function PreventBuffersInNERDTree:
line    5:
E444: Cannot close last window

First is a <leader><Leader> shortcut that switches buffers before opening FZF file. Second is a treatment within NERDTree itself. It closes NERDTree before opening file. More info here: junegunn/fzf#453 (comment)

danielgatis · 2019-07-20T20:08:21Z

try this:

au BufEnter * if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree' && winnr('$') > 1 | b# | exe "normal! \<c-w>\<c-w>" | :blast | endif

chrisjune · 2019-08-28T06:59:16Z

try this:

au BufEnter * if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree' && winnr('$') > 1 | b# | exe "normal! \<c-w>\<c-w>" | :blast | endif

Thanks!, it's all I wanted

outaTiME · 2019-10-18T00:30:57Z

try this:

au BufEnter * if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree' && winnr('$') > 1 | b# | exe "normal! \<c-w>\<c-w>" | :blast | endif

@danielgatis weird things happen when running with neovim 0.4, this automatic command still working?

Original layout without fzf command:

After :Files command, nerdtree at bottom, fzf command at top lef and empty buffer at top right:

(everything broken at this point)

wookayin · 2020-01-23T18:58:44Z

For a future reference: if you are using vim-nerdtree-tabs plugin and want fzf to open in another window (rather than inside the 'pinned' NERDTree buffer), the following would work:

if exists('t:NERDTreeBufName') && bufname('%') == t:NERDTreeBufName
  wincmd w   " move the focus outside nerdtree
endif

Note that in this case fzf will open files in the same buffer if it is not a pinned NERDTree buffer (e.g. e .).

dreamos82 · 2020-02-09T11:28:30Z

Just to add my 2 cents, i used @jeromedalbert solution and worked pretty well for me, the only thing i didn't liked was that it was closing the nerdtree buffer, so i tried to update it in order to keep it open even when i jump to a file.

Here is my solution:

autocmd FileType nerdtree let t:nerdtree_winnr = bufwinnr('%')
autocmd BufWinEnter * call PreventBuffersInNERDTree()

function! PreventBuffersInNERDTree()
  if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree'
    \ && exists('t:nerdtree_winnr') && bufwinnr('%') == t:nerdtree_winnr
    \ && &buftype == '' && !exists('g:launching_fzf')
    let bufnum = bufnr('%')
    close
    exe 'b ' . bufnum
    NERDTree
  endif
  if exists('g:launching_fzf') | unlet g:launching_fzf | endif
endfunction

So basically i just reopened it when the new buffer open in the correct window.
Hope this helps!

mangelozzi · 2020-09-29T19:40:34Z

I really liked @dkarter's solution, I "improved/customised" it a little, I often have nerdtree on the left, and quickfix window below, so I would like to move a window to the right and up if the buffer is not modifiable or NERDTree or a quickfix window:

" Prevent FZF commands from opening in none modifiable buffers
function! FZFOpen(cmd)
    " If more than 1 window, and buffer is not modifiable or file type is
    " NERD tree or Quickfix type
    if winnr('$') > 1 && (!&modifiable || &ft == 'nerdtree' || &ft == 'qf')
        " Move one window to the right, then up
        wincmd l
        wincmd k
    endif
    exe a:cmd
endfunction

" FZF in Open buffers
nnoremap <silent> <leader><leader> :call FZFOpen(":Buffers")<CR>

" FZF Search for Files
nnoremap <silent> <leader>f :call FZFOpen(":Files")<CR>

" FZF Search for Files in home dir
nnoremap <silent> <leader>~ :call FZFOpen(":Files ~")<CR>

" FZF Search for previous opened Files
nnoremap <silent> <leader>zh :call FZFOpen(":History")<CR>

ghost-lth · 2020-11-09T03:50:21Z

try this:

au BufEnter * if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree' && winnr('$') > 1 | b# | exe "normal! \<c-w>\<c-w>" | :blast | endif

Thanks!, it's all I wanted too

jkoz · 2020-11-11T04:51:23Z

I like danielgatis solution; however if i look for a file which have already in the buffer. It didn't bring it up

LuisCusihuaman · 2020-11-21T19:41:28Z

try this:

au BufEnter * if bufname('#') =~ 'NERD_tree' && bufname('%') !~ 'NERD_tree' && winnr('$') > 1 | b# | exe "normal! \<c-w>\<c-w>" | :blast | endif

Works for me, thanks!!!! 🤟

junegunn/fzf#453 (comment)

Rican7 · 2021-09-16T04:57:20Z

I also liked @dkarter's and @mangelozzi's solutions, but refined it even more-so:

" Function to prevent FZF commands from opening in functional buffers
"
" See: https://github.com/junegunn/fzf/issues/453
" TODO: Remove once this workaround is no longer necessary.
function! FZFOpen(cmd)
    " Define the functional buffer types that we want to not clobber
    let functional_buf_types = ['quickfix', 'help', 'nofile', 'terminal']

    " If more than 1 window, and buffer type is not one of the functional types
    if winnr('$') > 1 && (index(functional_buf_types, &bt) >= 0)
        " Find all 'normal' (not functional) buffer windows
        let norm_wins = filter(range(1, winnr('$')),
                    \ 'index(functional_buf_types, getbufvar(winbufnr(v:val), "&bt")) == -1')

        " Grab the first one that we can use
        let norm_win = !empty(norm_wins) ? norm_wins[0] : 0

        " Move to that window
        exe norm_win . 'winc w'
    endif

    " Execute the passed command
    exe a:cmd
endfunction

" Map CTRL+P to FZF
nmap <C-P> :call FZFOpen(':FZF')<CR>

(source: https://github.com/Rican7/dotfiles/blob/5e58b3f3839f2f06e7b04d904871dc78c97a09d2/.vim/plugin/fzf.vim#L49-L76)

In fact, I really think that this code should live within fzf. As much of this I actually took from ctrlp.vim, which has this ability/feature built-in.

Thanks to @jonegunn: junegunn/fzf#453 (comment)

alps2006 · 2023-05-07T06:53:03Z

I use coc-explorer as my file navigator, this snippet can resolve my problem.

    " 1st cond: Previous buffer name match pattern `coc-explorer`
    " 2st cond: Excluding when :FZF execute with split window
    " 3st cond: Current buffer name dismatch pattern `coc-explorer`
    " next operation: 
    " 1. Go to previous buffer by `b#` on explorer window
    " 2. Switching to another window by `wincmd w` 
    " 3. Go to last buffer on new window
    au BufEnter * if bufname('#') =~ 'coc-explorer' && bufname('%') != '' && bufname('%') !~ 'coc-explorer' && winnr('$') > 1 | b# | wincmd w | blast | endif

If using NERDtree, replacing the coc-explorer to NERD_tree.

au BufEnter * if bufname('#') =~ 'NERD_tree' && bufname('%') != '' && bufname('%') !~ 'NERD_tree' && winnr('$') > 1 | b# | wincmd w | blast | endif

First is a <leader><Leader> shortcut that switches buffers before opening FZF file. Second is a treatment within NERDTree itself. It closes NERDTree before opening file. More info here: junegunn/fzf#453 (comment)

junegunn added the neovim label Dec 22, 2015

junegunn added the question label Dec 22, 2015

heliohead closed this as completed Dec 22, 2015

junegunn changed the title ~~How can i prevent that fzf open files inside neotree buffer?~~ How can i prevent that fzf open files inside NERDtree buffer? Jan 8, 2018

arunvelsriram mentioned this issue Feb 4, 2018

Prevent fzf from opening files inside NERDTree's split thecasualcoder/neovim-dotfiles#8

Merged

izelnakri mentioned this issue Dec 24, 2018

Don't open files in specific buffers - NERDtree / Neovim Terminal etc junegunn/fzf.vim#326

Closed

9 tasks

amitlevy21 mentioned this issue Jun 22, 2020

Sticky Buffers neovim/neovim#12517

Closed

amitlevy21 mentioned this issue Jul 12, 2020

Sticky Buffers vim/vim#6445

Closed

bpingris mentioned this issue Aug 6, 2020

expand returns an empty string ms-jpq/chadtree#41

Closed

macintacos mentioned this issue Sep 11, 2020

Ignore NERDTree window and others liuchengxu/vim-clap#139

Closed

raycon mentioned this issue Jan 5, 2021

neovim raycon/til#50

Open

scebotari66 added a commit to scebotari66/dotfiles that referenced this issue Jul 1, 2021

Fix search results showing in nerdtree window

a4a788b

junegunn/fzf#453 (comment)

matoous mentioned this issue Sep 5, 2021

question: Can the notification window be exempt from selecting a window? rcarriga/nvim-notify#18

Closed

ggteixeira added a commit to ggteixeira/dotfiles that referenced this issue Jan 31, 2022

Updates mapping to avoid opening new window inside nerdtree buffer

534e367

Thanks to @jonegunn: junegunn/fzf#453 (comment)

mmrwoods mentioned this issue Feb 12, 2022

<CR> in a quickfix-window would not reuse a visible HELP buffer vim/vim#516

Open

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

How can i prevent that fzf open files inside NERDtree buffer? #453

How can i prevent that fzf open files inside NERDtree buffer? #453

heliohead commented Dec 21, 2015

junegunn commented Dec 22, 2015

heliohead commented Dec 22, 2015

mrleolink commented Apr 22, 2016

junegunn commented Apr 22, 2016

mrleolink commented Apr 23, 2016

junegunn commented Apr 23, 2016

mrleolink commented Apr 23, 2016

dkarter commented Jan 1, 2018 •

edited

Loading

jeromedalbert commented Feb 17, 2018 •

edited

Loading

r-glebov commented Mar 25, 2019 •

edited

Loading

danielgatis commented Jul 20, 2019 •

edited

Loading

chrisjune commented Aug 28, 2019

outaTiME commented Oct 18, 2019 •

edited

Loading

wookayin commented Jan 23, 2020

dreamos82 commented Feb 9, 2020 •

edited

Loading

mangelozzi commented Sep 29, 2020 •

edited

Loading

ghost-lth commented Nov 9, 2020

jkoz commented Nov 11, 2020

LuisCusihuaman commented Nov 21, 2020

Rican7 commented Sep 16, 2021

alps2006 commented May 7, 2023

How can i prevent that fzf open files inside NERDtree buffer? #453

How can i prevent that fzf open files inside NERDtree buffer? #453

Comments

heliohead commented Dec 21, 2015

junegunn commented Dec 22, 2015

heliohead commented Dec 22, 2015

mrleolink commented Apr 22, 2016

junegunn commented Apr 22, 2016

mrleolink commented Apr 23, 2016

junegunn commented Apr 23, 2016

mrleolink commented Apr 23, 2016

dkarter commented Jan 1, 2018 • edited Loading

jeromedalbert commented Feb 17, 2018 • edited Loading

r-glebov commented Mar 25, 2019 • edited Loading

danielgatis commented Jul 20, 2019 • edited Loading

chrisjune commented Aug 28, 2019

outaTiME commented Oct 18, 2019 • edited Loading

wookayin commented Jan 23, 2020

dreamos82 commented Feb 9, 2020 • edited Loading

mangelozzi commented Sep 29, 2020 • edited Loading

ghost-lth commented Nov 9, 2020

jkoz commented Nov 11, 2020

LuisCusihuaman commented Nov 21, 2020

Rican7 commented Sep 16, 2021

alps2006 commented May 7, 2023

dkarter commented Jan 1, 2018 •

edited

Loading

jeromedalbert commented Feb 17, 2018 •

edited

Loading

r-glebov commented Mar 25, 2019 •

edited

Loading

danielgatis commented Jul 20, 2019 •

edited

Loading

outaTiME commented Oct 18, 2019 •

edited

Loading

dreamos82 commented Feb 9, 2020 •

edited

Loading

mangelozzi commented Sep 29, 2020 •

edited

Loading