Add meson support & use for cross-compilation of releases

.gitignore

@@ -2,6 +2,7 @@
 /lib/
 /bin/
 /dist/
+/builddir/
 /.crystal/
 /.shards/
 *.dwarf

meson.build

@@ -0,0 +1,80 @@
+project('mstrap',
+  'c',
+  meson_version : '>= 0.57.0',
+  license : 'MIT',
+  version : '0.4.0',
+  default_options : [
+    'default_library=static'
+  ]
+)
+
+cc = meson.get_compiler('c')
+crystal = find_program('crystal', required : true)
+shards = find_program('shards', required : true)
+
+libcrypto = dependency('libcrypto', version : '>= 1.1.1')
+libevent = dependency('libevent', version : '>= 2.1.2')
+libgc = dependency('bdw-gc', version : '>= 8.0.4' )
+libm = cc.find_library('m', required : false)
+libpcre = dependency('libpcre', version : '>= 8.37')
+libssl = dependency('libssl', version : '>= 1.1.1')
+readline = dependency('readline')
+zlib = dependency('zlib')
+thread_dep = dependency('threads')
+
+target_arch = host_machine.cpu_family()
+target_system = host_machine.system()
+target_triple = target_arch + '-unknown-' + target_system
+
+if target_system == 'linux'
+  # TODO: musl
+  target_triple += '-gnu'
+endif
+
+if run_command(shards, 'check').returncode() != 0
+  run_command(shards, 'install', '--frozen', check : true)
+endif
+
+crystal_path = run_command(
+  crystal, 'env', 'CRYSTAL_PATH',
+  check : true
+).stdout().strip()
+env = environment({
+  'CRYSTAL_PATH': crystal_path
+})
+env.prepend('CRYSTAL_PATH', join_paths(meson.project_source_root(), 'lib'))
+
+mstrap_o = custom_target(
+  'mstrap.o',
+  build_always_stale : true,
+  command : [
+    crystal,
+    'build',
+    '--cross-compile',
+    '--target',
+    target_triple,
+    '-o',
+    'mstrap',
+    '@INPUT@'
+  ],
+  depend_files : [files('shard.lock')],
+  env : env,
+  input : [files('src/cli.cr')],
+  output : ['mstrap.o']
+)
+
+executable(
+  'mstrap',
+  mstrap_o,
+  dependencies : [
+    libcrypto,
+    libevent,
+    libgc,
+    libm,
+    libpcre,
+    libssl,
+    readline,
+    zlib,
+    thread_dep
+  ],
+)

subprojects/openssl.wrap

@@ -0,0 +1,14 @@
+[wrap-file]
+directory = openssl-1.1.1l
+source_url = https://www.openssl.org/source/openssl-1.1.1l.tar.gz
+source_filename = openssl-1.1.1l.tar.gz
+source_hash = 0b7a3e5e59c34827fe0c3a74b7ec8baef302b98fa80088d7f9153aa16fa76bd1
+patch_filename = openssl_1.1.1l-2_patch.zip
+patch_url = https://wrapdb.mesonbuild.com/v2/openssl_1.1.1l-2/get_patch
+patch_hash = 852521fb016fa2deee8ebf9ffeeee0292c6de86a03c775cf72ac04e86f9f177e
+
+[provide]
+libcrypto = libcrypto_dep
+libssl = libssl_dep
+openssl = openssl_dep
+