Fix #437, deprecate OS task ID and add replacement API for PSP exceptions

CMakeLists.txt

@@ -48,13 +48,39 @@
 cmake_minimum_required(VERSION 2.8.12)
 project(OSAL C)
 
+# Read the default compile-time configuration, and update with
+# any mission/project specific options in the OSAL_CONFIGURATION_FILE
+include("${OSAL_SOURCE_DIR}/default_config.cmake")
+
+# The user-specified file is optional, but in case the value is defined but the
+# file does not exist, this should be treated as an error.
+if (DEFINED OSAL_CONFIGURATION_FILE)
+    include(${OSAL_CONFIGURATION_FILE})
+endif (DEFINED OSAL_CONFIGURATION_FILE)
+
+# Use the supplied configuration to generate the osconfig.h file
+# which can be referenced by the code.  This will be stored in the top level
+# "inc" directory of the binary output directory
+file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/inc")
+configure_file(
+    "${OSAL_SOURCE_DIR}/osconfig.h.in"
+    "${OSAL_BINARY_DIR}/osconfig.gen"
+    @ONLY
+)
+
+# Only copy the osconfig.h into place if different from the existing file
+# This avoids unnecessarily rebuilding all code in case cmake was re-run
+# and but generated the same file.
+execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
+    "${OSAL_BINARY_DIR}/osconfig.gen"
+    "${CMAKE_BINARY_DIR}/inc/osconfig.h"
+)
 
 # The initial set of directories that define the OSAL API
 # This is used to initialize the interface include directory property of external targets
 set(OSAL_API_INCLUDE_DIRECTORIES
     "${OSAL_SOURCE_DIR}/src/os/inc"
     "${CMAKE_BINARY_DIR}/inc"
-    ${OSAL_INCLUDEDIR}
 )
 include_directories(${OSAL_API_INCLUDE_DIRECTORIES})
 
@@ -97,7 +123,7 @@ message(STATUS "BSP Selection: ${OSAL_SYSTEM_BSPTYPE}")
 # an OBJECT target named "osal_${OSAL_SYSTEM_BSPTYPE}_impl"
 add_subdirectory(src/bsp/${OSAL_SYSTEM_BSPTYPE} ${OSAL_SYSTEM_BSPTYPE}_impl)
 target_include_directories(osal_${OSAL_SYSTEM_BSPTYPE}_impl PRIVATE
-    ${OSAL_SOURCE_DIR}/src/bsp/shared
+    ${OSAL_SOURCE_DIR}/src/bsp/shared/inc
 )
 
 # Confirm that the selected OS is compatible with the selected BSP.
@@ -138,17 +164,22 @@ endif (OSAL_BSP_INCLUDE_DIRECTORIES)
 
 # Define the external "osal_bsp" static library target
 add_library(osal_bsp STATIC
-	src/bsp/shared/osapi-bsp.c
-	src/bsp/shared/bsp_default_app_run.c
-	src/bsp/shared/bsp_default_app_startup.c
-	src/bsp/shared/bsp_default_symtab.c
+	src/bsp/shared/src/osapi-bsp.c
+	src/bsp/shared/src/bsp_default_app_run.c
+	src/bsp/shared/src/bsp_default_app_startup.c
+	src/bsp/shared/src/bsp_default_symtab.c
     $<TARGET_OBJECTS:osal_${OSAL_SYSTEM_BSPTYPE}_impl>
 )
 
 target_include_directories(osal_bsp INTERFACE
     ${OSAL_API_INCLUDE_DIRECTORIES}
 )
 
+target_include_directories(osal_bsp PRIVATE
+    ${OSAL_SOURCE_DIR}/src/bsp/shared/inc
+)
+
+
 #
 # Step 2:
 # Build the OSAL layer
@@ -174,43 +205,68 @@ add_subdirectory(src/os/${OSAL_SYSTEM_OSTYPE} ${OSAL_SYSTEM_OSTYPE}_impl)
 # are referenced in implementation OSAL modules, but should _NOT_
 # be referenced outside the OSAL code
 target_include_directories(osal_${OSAL_SYSTEM_OSTYPE}_impl PRIVATE
-    ${OSAL_SOURCE_DIR}/src/os/shared
-    ${OSAL_SOURCE_DIR}/src/bsp/shared
+    ${OSAL_SOURCE_DIR}/src/os/shared/inc
+    ${OSAL_SOURCE_DIR}/src/bsp/shared/inc
+)
+
+set(OSAL_SRCLIST
+    src/os/shared/src/osapi-binsem.c
+    src/os/shared/src/osapi-clock.c
+    src/os/shared/src/osapi-common.c
+    src/os/shared/src/osapi-countsem.c
+    src/os/shared/src/osapi-dir.c
+    src/os/shared/src/osapi-errors.c
+    src/os/shared/src/osapi-file.c
+    src/os/shared/src/osapi-filesys.c
+    src/os/shared/src/osapi-heap.c
+    src/os/shared/src/osapi-idmap.c
+    src/os/shared/src/osapi-module.c
+    src/os/shared/src/osapi-mutex.c
+    src/os/shared/src/osapi-network.c
+    src/os/shared/src/osapi-printf.c
+    src/os/shared/src/osapi-queue.c
+    src/os/shared/src/osapi-select.c
+    src/os/shared/src/osapi-shell.c
+    src/os/shared/src/osapi-sockets.c
+    src/os/shared/src/osapi-task.c
+    src/os/shared/src/osapi-timebase.c
+    src/os/shared/src/osapi-time.c
 )
 
+if (OSAL_CONFIG_DEBUG_PRINTF)
+    list(APPEND OSAL_SRCLIST
+        src/os/shared/src/osapi-debug.c
+    )
+endif (OSAL_CONFIG_DEBUG_PRINTF)
+
+
+# The FPU and interrupt modules are deprecated.
+# If the "OMIT_DEPRECATED" switch is set, then these are not built.
+if (NOT OMIT_DEPRECATED)
+    list(APPEND OSAL_SRCLIST
+        src/os/shared/src/osapi-fpu.c
+        src/os/shared/src/osapi-interrupts.c
+    )
+endif (NOT OMIT_DEPRECATED)
+
+
 # Define the external "osal" static library target
 # This is a combination of the generic parts with the low level
 # system-specific parts
 add_library(osal STATIC
-	src/os/shared/osapi-binsem.c
-	src/os/shared/osapi-clock.c
-	src/os/shared/osapi-common.c
-	src/os/shared/osapi-countsem.c
-	src/os/shared/osapi-dir.c
-	src/os/shared/osapi-errors.c
-	src/os/shared/osapi-file.c
-	src/os/shared/osapi-filesys.c
-	src/os/shared/osapi-fpu.c
-	src/os/shared/osapi-heap.c
-	src/os/shared/osapi-idmap.c
-	src/os/shared/osapi-interrupts.c
-	src/os/shared/osapi-module.c
-	src/os/shared/osapi-mutex.c
-	src/os/shared/osapi-network.c
-	src/os/shared/osapi-printf.c
-	src/os/shared/osapi-queue.c
-	src/os/shared/osapi-select.c
-	src/os/shared/osapi-sockets.c
-	src/os/shared/osapi-task.c
-	src/os/shared/osapi-timebase.c
-	src/os/shared/osapi-time.c
+    ${OSAL_SRCLIST}
     $<TARGET_OBJECTS:osal_${OSAL_SYSTEM_OSTYPE}_impl>
 )
 
 target_include_directories(osal INTERFACE
     ${OSAL_API_INCLUDE_DIRECTORIES}
 )
 
+target_include_directories(osal PRIVATE
+    ${OSAL_SOURCE_DIR}/src/os/shared/inc
+    ${OSAL_SOURCE_DIR}/src/bsp/shared/inc
+)
+
 # Link the OSAL with the BSP
 target_link_libraries(osal osal_bsp)
 

default_config.cmake

@@ -0,0 +1,224 @@
+#
+# 
+#    Copyright (c) 2020, United States government as represented by the
+#    administrator of the National Aeronautics Space Administration.
+#    All rights reserved. This software was created at NASA Goddard
+#    Space Flight Center pursuant to government contracts.
+# 
+#    This is governed by the NASA Open Source Agreement and may be used,
+#    distributed and modified only according to the terms of that agreement.
+# 
+#
+
+##########################################################################
+#
+# Default configuration options for OSAL
+#
+# This file specifies the default values for various compile-time options
+# supported by OSAL.  These options can be further tuned by the specific
+# OSAL and BSP selection, as well as the user application.
+#
+# NOTE:
+# The defaults in this file should _not_ be directly modified for tuning.
+#
+# Instead, use the "OSAL_CONFIGURATION_FILE" CMake variable to define
+# a custom file which can override/modify the configuration for the items
+# which require tuning.
+#
+##########################################################################
+
+
+##############################################################
+# Code/Feature Selection Options for the OSAL implementation
+##############################################################
+
+
+# OSAL_CONFIG_INCLUDE_NETWORK
+# ----------------------------------
+#
+# Whether to include the Network API
+#
+# If set TRUE, the the socket abstraction (if applicable on the platform)
+# will be included.  If set FALSE, then all calls to the network API will
+# return OS_ERR_NOT_IMPLEMENTED.
+#
+# This can be set FALSE for platforms which do not have a network or
+# IP stack available, or to save code space if the application does
+# not use network resources.
+#
+set(OSAL_CONFIG_INCLUDE_NETWORK                 TRUE)
+
+
+#
+# OSAL_CONFIG_INCLUDE_DYNAMIC_LOADER
+# ----------------------------------
+#
+# Whether to include the capability of loading dynamic code objects
+#
+# This is normally set TRUE to support modularized applications on
+# platforms which have this capability.
+#
+# For deployments which are always statically linked, this may be set
+# FALSE for a smaller library size and reduced linking requirements.
+#
+set(OSAL_CONFIG_INCLUDE_DYNAMIC_LOADER          TRUE)
+
+
+#
+# OSAL_CONFIG_INCLUDE_STATIC_LOADER
+# ----------------------------------
+#
+# Whether to include a compatibility "loader" for statically-linked objects
+#
+# This feature allows applications normally written for dynamic module loading
+# operate transparently in a static link environment.  If this is set TRUE,
+# then the application must supply an object named "OS_STATIC_SYMBOL_TABLE" that
+# contains the names and addresses of statically-linked symbols that should
+# be known to the lookup/load functions.
+#
+# Note that modules "loaded" using this abstraction are still assigned a
+# module ID and still require a slot in the module table even though
+# no actual runtime loading is performed (see OSAL_CONFIG_MAX_MODULES).
+#
+set(OSAL_CONFIG_INCLUDE_STATIC_LOADER           TRUE)
+
+#
+# OSAL_CONFIG_INCLUDE_SHELL
+# ----------------------------------
+#
+# Whether to include features which utilize the operating system shell.
+#
+# Remote Shell commands can be very powerful tool for remotely diagnosing
+# and mitigating runtime issues in the field, but also have significant
+# security implications.  If this is set to "false" then shell functionality
+# is disabled and OSAL functions which invoke the shell will return
+# OS_ERR_NOT_IMPLEMENTED.
+#
+set(OSAL_CONFIG_INCLUDE_SHELL                   FALSE)
+
+
+#
+# OSAL_CONFIG_DEBUG_PERMISSIVE_MODE
+# ----------------------------------
+#
+# The OSAL_CONFIG_DEBUG_PERMISSIVE_MODE option controls how privileged operations
+# are handled by the OSAL in the event that the user does not have sufficient permission.
+# In particular this applies to task priorities and message queues.
+#
+# If set FALSE, then all permissions are enforced, and a failure due to lack of permission
+# will cause a failure of the overall operation, which is passed back to the application.
+#
+# If set to TRUE, this will treat some errors non-fatal and enable a graceful fallback,
+# allowing the overall operation to complete in a reduced form.  This makes the
+# OSAL library compatible with a non-root (normal user mode) environment.
+#
+# In the PC-Linux/Posix build, this means:
+#  - A message queue deeper than the maximum system limit will be silently truncated
+#    to the maximum system limit (no error).
+#  - If the user does not have permission to create elevated priority tasks, then the tasks will
+#    be created at the default priority (no error).
+#
+set(OSAL_CONFIG_DEBUG_PERMISSIVE_MODE           FALSE)
+
+#
+# OSAL_CONFIG_DEBUG_PRINTF
+# ----------------------------------
+#
+# Controls inclusion of OS_DEBUG statements in the code
+#
+# If set FALSE, all OS_DEBUG statements are compiled out.
+#
+# If set TRUE, all the "OS_DEBUG" statements will be compiled in and displayed
+# on the debug console.  The statements may still be suppressed at runtime.
+#
+set(OSAL_CONFIG_DEBUG_PRINTF                    FALSE)
+
+
+#############################################
+# Resource Limits for the OS API
+#############################################
+
+# The maximum number of concurrently-running tasks to support
+set(OSAL_CONFIG_MAX_TASKS               64)
+
+# The maximum number of queues to support
+set(OSAL_CONFIG_MAX_QUEUES              64)
+
+# The maximum number of counting semaphores to support
+set(OSAL_CONFIG_MAX_COUNT_SEMAPHORES    20)
+
+# The maximum number of binary semaphores to support
+set(OSAL_CONFIG_MAX_BIN_SEMAPHORES      20)
+
+# The maximum number of mutexes to support
+set(OSAL_CONFIG_MAX_MUTEXES             20)
+
+# The maximum number of loadable modules to support
+# Note that emulating module loading for statically-linked objects also
+# requires a slot in this table, as it still assigns an OSAL ID.
+set(OSAL_CONFIG_MAX_MODULES             20)
+
+# The maximum number of time base objects (reference for timers)
+set(OSAL_CONFIG_MAX_TIMEBASES           5)
+
+# The maximum number of user timers / app callbacks that can be registered
+set(OSAL_CONFIG_MAX_TIMERS              10)
+
+# The maximum number of concurrently open file descriptors to support
+set(OSAL_CONFIG_MAX_NUM_OPEN_FILES      50)
+
+# The maximum number of concurrently open directory descriptors to support
+set(OSAL_CONFIG_MAX_NUM_OPEN_DIRS       4)
+
+# The maximum number of file systems that can be managed by OSAL
+set(OSAL_CONFIG_MAX_FILE_SYSTEMS        14)
+
+# The maximum length for a file name, including any extension
+# (This does not include the directory part)
+set(OSAL_CONFIG_MAX_FILE_NAME           20)
+
+# Maximum length for an virtual path name (virtual directory + file)
+set(OSAL_CONFIG_MAX_PATH_LEN            64)
+
+# Maximum length allowed for a object (task,queue....) name
+set(OSAL_CONFIG_MAX_API_NAME            20)
+
+# Maximum length of a symbol name for OS_SymbolLookup()
+set(OSAL_CONFIG_MAX_SYM_LEN             64)
+
+# Maximum length of a network socket address
+# This is only relevant if network support is included, and the
+# required length depends on the address families in use
+set(OSAL_CONFIG_SOCKADDR_MAX_LEN        28)
+
+# Maximum length of a single message produced by OS_printf()
+set(OSAL_CONFIG_PRINTF_BUFFER_SIZE      172)
+
+# Maximum number of OS_printf() messages that will be buffered
+set(OSAL_CONFIG_PRINTF_BUFFER_DEPTH     100)
+
+# Priority level of a console output helper task
+#
+# Set logically low (high number) to maximize performance.
+#   - Messages from OS_printf() may show on the console with some delay
+#     but should have minimal impact to real time tasks.
+#
+# Set logically high (low number) for debugging
+#   - Messages from OS_printf() will have more timely output, but may
+#     adversely impact real time tasks.
+set(OSAL_CONFIG_UTILITYTASK_PRIORITY    245)
+
+# Stack size of console output task.
+#
+# This applies to RTOS layers with precise stack control,
+# normally not necessary to change this unless the task implementation
+# changes.
+set(OSAL_CONFIG_UTILITYTASK_STACK_SIZE  2048)
+
+# The size of a command that can be passed to the underlying OS
+set(OSAL_CONFIG_MAX_CMD_LEN             1000)
+
+# The maximum depth of an OSAL message queue.
+# On some implementations this may affect the overall OSAL memory footprint
+# so it may be beneficial to set this limit accordingly.
+set(OSAL_CONFIG_QUEUE_MAX_DEPTH         50)