Test typescript types using tsd.

This does not yet have full coverage over all of the types in peg.d.ts;
I want to see if this approach seems viable to the typescript experts.

examples/fizzbuzz.peggy

@@ -0,0 +1,44 @@
+/*
+This grammar aims to have one of every Peggy syntax.
+It parses the output of a fizz-buzz (https://en.wikipedia.org/wiki/Fizz_buzz)
+program (plus a few extensions) for correctness.
+*/
+{{
+const NUMS = [3, 5];
+}}
+{
+let currentNumber = (options.start == null) ? 1 : options.start|0;
+}
+
+top = c:count* { return c.filter(fb => fb) }
+
+count
+  = end_comment "\n" { return }
+  / comment "\n" { return }
+  / comment? fb:line (comment / end_comment)? "\n" {
+    currentNumber++;
+    return fb;
+  }
+
+comment "comment"
+  = _ "/*" (!"*/" .)* "*/" _
+
+end_comment
+  = _ "//" [^\n]+
+
+line
+  = @n:number &{ return (n === currentNumber) && NUMS.every(d => n % d) }
+  / fizzbuzz
+  / fizz
+  / buzz
+
+fizzbuzz = f:fizz _ b:buzz { return f + b }
+fizz = @"fizz"i !{ return currentNumber % 3 }
+buzz = @"buzz"i !{ return currentNumber % 5 }
+
+// Arbitrary requirement needing &
+number "number without trailing comment"
+  = "0x" n:$[0-9a-f]i+ &"\n" { return parseInt(n, 16) }
+  / n:$[0-9]+ &"\n" { return parseInt(n, 10) }
+
+_ = $[ \t]*

jest.config.js

@@ -0,0 +1,16 @@
+"use strict";
+
+module.exports = {
+  "collectCoverage": true,
+  "coverageReporters": ["lcov"],
+  "roots": [
+    "<rootDir>/test"
+  ],
+  "testMatch": [
+    "**/*.spec.js",
+    "**/*.test-d.ts"
+  ],
+  "transform": {
+    "^.+\\.ts$": "ts-jest",
+  }
+};

lib/peg.d.ts

@@ -197,7 +197,7 @@ declare namespace ast {
     ignoreCase: boolean;
   }
 
-  /** Matches any UTF-16 character in the input, but doesn't match the empty string. */
+  /** Matches any UTF-16 code unit in the input, but doesn't match the empty string. */
   interface Any extends Node<"any"> {}
 }
 
@@ -342,7 +342,7 @@ export namespace parser {
     | OtherExpectation;
 
   /** Thrown if the grammar contains a syntax error. */
-  class SyntaxError implements Error {
+  class SyntaxError extends Error {
     /** Location where error was originated. */
     location: LocationRange;
     /**